media-gfx/imagemagick: Bump to versions 6.9.9.33 and 7.0.7.21

Package-Manager: Portage-2.3.19, Repoman-2.3.6

3 files changed, 372 insertions, 0 deletions

diff --git a/media-gfx/imagemagick/Manifest b/media-gfx/imagemagick/Manifest
index 1107b7b1987c..89f447df4fc5 100644
--- a/media-gfx/imagemagick/Manifest
+++ b/media-gfx/imagemagick/Manifest
@@ -4,10 +4,12 @@ DIST ImageMagick-6.9.9-20.tar.xz 8994128 BLAKE2B fb52396956b6e34320e82f34f832735
 DIST ImageMagick-6.9.9-23.tar.xz 8795632 BLAKE2B c3a2ece7897961b191b1090384c0872422af80903d0447a0b67f06d45062d60f12903a30a00d28bedc33a6c0b74f38bfe043a113613f0bfb5b1608b972ce8e2a SHA512 9160e0f6606c6ea011e9e47a11f092735456be60d6d039b9cf73c055c046ce89f05d096bdc3d37f87e2d6e36cd8dc9adf233b42bb9ad7d14aa03f13c7a1b6c03
 DIST ImageMagick-6.9.9-26.tar.xz 8799740 BLAKE2B 6d781ef8b0285390cfef0544b26c8b4779a7bfdfb18ba9064eaa1b47edc19e98080e53ea073fe95f11dde52b910ecdff7c3a27efe6163a4b4855cc8db358a66c SHA512 e132deae4d14ccc179300841681c1ec83f90fe9ac8e2ce1f07af5642497be44ce017ec1e007964d307c32ecb733081bd2172e4f3113e5acea31c5783b1126e89
 DIST ImageMagick-6.9.9-31.tar.xz 8819864 BLAKE2B f6cdb19bff58a0b318a9af78f3fa429137cc4e79bbe075f9c6444204ce8a4324dde5792ab7232e6898a4993ad558c514a143c14469370de822038d1d669fdffa SHA512 85cbe4e4991a08a5c11c01b4276525fa1d63bcef9a9814fee1f8ede3a5ed432da8d3d84965ed75105723948d07ad879f7cf07d5121f0d624df9275dd4e41cb8f
+DIST ImageMagick-6.9.9-33.tar.xz 8833416 BLAKE2B 06d0d30a8a20a0f5f3aa938f1d54326acbbfbdec95b6de5b311996f9a3c9698054cd3b60a224ac47b68f35d4541c8a4ddbe96ba87c91b2ee7255e7660a806f1e SHA512 5edbb508d18f9f80be2630bc4f7682b325a189cffa3b8ced337ce932f5f39f4517307afb190df8ebf588e7338d4779fc23a660eb0294e2411aaa90b59327dd80
 DIST ImageMagick-6.9.9-9.tar.xz 8797832 BLAKE2B 453102e0db6bf51c10e43b54d6fc35acaac4de193cdb0cc1f8448f70708739628e9e97ef310e9deb8d3967318d17f29344c1b9c6dc1c7437e39b4f42f23b5dd3 SHA512 d024f753e1bf234e38736935f38a9bf82969ca77130059383f9d1871a39f68d7678a546d2786d57d602744e2008909df3f2ab08e1207b4c97c0952e7b03876d8
 DIST ImageMagick-7.0.6-9.tar.xz 8550004 BLAKE2B 2ca6cb995bdbdb16188c8cfa1fe328cccfe604341331413dc35950bc115f8a76af21f2f07cc3384da460a03d3de97484e1293507d30fea4571ee8f064f536757 SHA512 5756d2605cbfbd876765372e954aeefdcdf60f1ee364ce40c3302f8958c510e6f0ecf47a3ee3c264eaaade1504bdae068118eb2cb96d418237f7f53da94a6c11
 DIST ImageMagick-7.0.7-11.tar.xz 8626180 BLAKE2B cb43c167227632dbcb96575d2f4845cb80a40f4490be240aa8020993033e23f42ba9f600ba37751cce66dc51237b209be965115fbed20329f046a8ca014accdf SHA512 089c8516ca66845c6b8e6b365815ef1806fc97c785f75c06ed62241d7b6255387ee8f9004b1bcc0a6d03b7aa397d8e25131ca2aadc9255cc1e2368d73f774551
 DIST ImageMagick-7.0.7-14.tar.xz 8617500 BLAKE2B 72d6a1319ec299e9717b68cef29c08817999dd9f2fffa5ee80aded6cb03c87c17859dc6d74cc48a63205c28f27ae5781cf55589a07bdda3b54528b489141f05f SHA512 c4b15ffe64bddb8da8e1ab04e6c41c46c9120d224a09225e76f5624250b31aea84bff37c712ad5cdea3faa8f2242054bfa3f33456468d68e14e7f4d85a88de6f
 DIST ImageMagick-7.0.7-19.tar.xz 8546416 BLAKE2B 6750dba45f7971f7a7e74ac7ae3ec94732a2bd31f638afac8a91abd595e81aadca1372ddb46dcc3bf2dcb258ececfa69a8e8ad5ff753930462d46804863c0f4e SHA512 656520f719a375c837b2ddebb7e5920e9c06a9f81f3529b8a7c405958ca75f7464790ff931b7a32e104ef500570e71ff80d3dfb7c5cf777b2a5ad8207fde7928
+DIST ImageMagick-7.0.7-21.tar.xz 8539076 BLAKE2B 93333c4608dfa027a25bd68a7c4ced5c5144fe5981529503d444e166eeb6f02a7c73f18e0667a0d6ed2346cbcd10c67d1ded2af4cd22c2515a1e17ee57fec433 SHA512 1bbdeb1a67f2057f2c17cee4d0cdd5d9d5304f961b4a5e45c05ac797e941cda9eb73795c273c9b2fd4f3ec6a84e84570c6c91f667a8ae0fbd6c3e1e2b6bb54ce
 DIST ImageMagick-7.0.7-6.tar.xz 8556160 BLAKE2B 3450c4c7e3804b0dcf7659a7ca0f11f6d1225c577b33216e10f6feeaa817412839ce613fdcae2175beace4cf844f880379899c1ad4914ff6df25fe2817fd0572 SHA512 9dff09a29b94f0de8ede82473820860f812edf3fc8edb0d1f8daa21c127d3e7831047f33ab22c407f2803a03561b690a52525672da837bbab1a1255156b4e6ff
 DIST ImageMagick-7.0.7-8.tar.xz 8797060 BLAKE2B a1a4278c375047fed7e59fdb9fa2a9526e2fc14136a669a0d148f78e5b308244de0ddd5c4b79e8e2214e4c91d39ae25531581868a2832ad91189a34460b5b5ad SHA512 0852df3bc996032a713ce6dc274cc36c3818c1c8304223de391e58bce8230aa12ac9778b4b28278c0ab4e42f2a7b4094052a5e4e6e4208329848948237fb41d2
diff --git a/media-gfx/imagemagick/imagemagick-6.9.9.33.ebuild b/media-gfx/imagemagick/imagemagick-6.9.9.33.ebuild
new file mode 100644
index 000000000000..cee94bf466d0
--- /dev/null
+++ b/media-gfx/imagemagick/imagemagick-6.9.9.33.ebuild
@@ -0,0 +1,185 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils flag-o-matic libtool multilib toolchain-funcs versionator
+
+MY_P=ImageMagick-$(replace_version_separator 3 '-')
+
+DESCRIPTION="A collection of tools and libraries for many image formats"
+HOMEPAGE="http://www.imagemagick.org/"
+SRC_URI="mirror://${PN}/${MY_P}.tar.xz"
+
+LICENSE="imagemagick"
+SLOT="0/${PV}"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="bzip2 corefonts cxx djvu fftw fontconfig fpx graphviz hdri jbig jpeg jpeg2k lcms lqr lzma opencl openexr openmp pango perl png postscript q32 q8 raw static-libs svg test tiff truetype webp wmf X xml zlib"
+
+RESTRICT="perl? ( userpriv )"
+
+RDEPEND="
+	dev-libs/libltdl:0
+	bzip2? ( app-arch/bzip2 )
+	corefonts? ( media-fonts/corefonts )
+	djvu? ( app-text/djvu )
+	fftw? ( sci-libs/fftw:3.0 )
+	fontconfig? ( media-libs/fontconfig )
+	fpx? ( >=media-libs/libfpx-1.3.0-r1 )
+	graphviz? ( media-gfx/graphviz )
+	jbig? ( >=media-libs/jbigkit-2:= )
+	jpeg? ( virtual/jpeg:0 )
+	jpeg2k? ( >=media-libs/openjpeg-2.1.0:2 )
+	lcms? ( media-libs/lcms:2= )
+	lqr? ( media-libs/liblqr )
+	opencl? ( virtual/opencl )
+	openexr? ( media-libs/openexr:0= )
+	pango? ( x11-libs/pango )
+	perl? ( >=dev-lang/perl-5.8.8:0= )
+	png? ( media-libs/libpng:0= )
+	postscript? ( app-text/ghostscript-gpl )
+	raw? ( media-gfx/ufraw )
+	svg? ( gnome-base/librsvg )
+	tiff? ( media-libs/tiff:0= )
+	truetype? (
+		media-fonts/urw-fonts
+		>=media-libs/freetype-2
+		)
+	webp? ( media-libs/libwebp:0= )
+	wmf? ( media-libs/libwmf )
+	X? (
+		x11-libs/libICE
+		x11-libs/libSM
+		x11-libs/libXext
+		x11-libs/libXt
+		)
+	xml? ( dev-libs/libxml2:= )
+	lzma? ( app-arch/xz-utils )
+	zlib? ( sys-libs/zlib:= )"
+DEPEND="${RDEPEND}
+	!media-gfx/graphicsmagick[imagemagick]
+	virtual/pkgconfig
+	X? ( x11-proto/xextproto )"
+
+REQUIRED_USE="corefonts? ( truetype )
+	test? ( corefonts )"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	local mesa_cards ati_cards nvidia_cards render_cards
+	default
+
+	elibtoolize # for Darwin modules
+
+	# For testsuite, see https://bugs.gentoo.org/show_bug.cgi?id=500580#c3
+	shopt -s nullglob
+	ati_cards=$(echo -n /dev/ati/card* | sed 's/ /:/g')
+	if test -n "${ati_cards}"; then
+		addpredict "${ati_cards}"
+	fi
+	mesa_cards=$(echo -n /dev/dri/card* | sed 's/ /:/g')
+	if test -n "${mesa_cards}"; then
+		addpredict "${mesa_cards}"
+	fi
+	nvidia_cards=$(echo -n /dev/nvidia** | sed 's/ /:/g')
+	if test -n "${nvidia_cards}"; then
+		addpredict "${nvidia_cards}"
+	fi
+	render_cards=$(echo -n /dev/dri/renderD128* | sed 's/ /:/g')
+	if test -n "${render_cards}"; then
+		addpredict "${render_cards}"
+	fi
+	shopt -u nullglob
+	addpredict /dev/nvidiactl
+}
+
+src_configure() {
+	local depth=16
+	use q8 && depth=8
+	use q32 && depth=32
+
+	local openmp=disable
+	use openmp && { tc-has-openmp && openmp=enable; }
+
+	[[ ${CHOST} == *-solaris* ]] && append-ldflags -lnsl -lsocket
+
+	local myeconfargs=(
+		$(use_enable static-libs static)
+		$(use_enable hdri)
+		$(use_enable opencl)
+		--with-threads
+		--with-modules
+		--with-quantum-depth=${depth}
+		$(use_with cxx magick-plus-plus)
+		$(use_with perl)
+		--with-perl-options='INSTALLDIRS=vendor'
+		--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts
+		$(use_with bzip2 bzlib)
+		$(use_with X x)
+		$(use_with zlib)
+		--without-autotrace
+		$(use_with postscript dps)
+		$(use_with djvu)
+		--with-dejavu-font-dir="${EPREFIX}"/usr/share/fonts/dejavu
+		$(use_with fftw)
+		$(use_with fpx)
+		$(use_with fontconfig)
+		$(use_with truetype freetype)
+		$(use_with postscript gslib)
+		$(use_with graphviz gvc)
+		$(use_with jbig)
+		$(use_with jpeg)
+		$(use_with jpeg2k openjp2)
+		$(use_with lcms)
+		$(use_with lqr)
+		$(use_with lzma)
+		$(use_with openexr)
+		$(use_with pango)
+		$(use_with png)
+		$(use_with svg rsvg)
+		$(use_with tiff)
+		$(use_with webp)
+		$(use_with corefonts windows-font-dir "${EPREFIX}"/usr/share/fonts/corefonts)
+		$(use_with wmf)
+		$(use_with xml)
+		--${openmp}-openmp
+		--with-gcc-arch=no-automagic
+	)
+	CONFIG_SHELL=$(type -P bash) econf "${myeconfargs[@]}"
+}
+
+src_test() {
+	LD_LIBRARY_PATH="${S}/coders/.libs:${S}/filters/.libs:${S}/Magick++/lib/.libs:${S}/magick/.libs:${S}/wand/.libs" \
+	emake check
+}
+
+src_install() {
+	# Ensure documentation installation files and paths with each release!
+	emake \
+		DESTDIR="${D}" \
+		DOCUMENTATION_PATH="${EPREFIX}"/usr/share/doc/${PF}/html \
+		install
+
+	rm -f "${ED}"/usr/share/doc/${PF}/html/{ChangeLog,LICENSE,NEWS.txt}
+	dodoc {AUTHORS,README}.txt ChangeLog
+
+	if use perl; then
+		find "${ED}" -type f -name perllocal.pod -exec rm -f {} +
+		find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} +
+	fi
+
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
+
+	if use opencl; then
+		cat <<-EOF > "${T}"/99${PN}
+		SANDBOX_PREDICT="/dev/nvidiactl:/dev/nvidia-uvm:/dev/ati/card:/dev/dri/card:/dev/dri/renderD128"
+		EOF
+
+		insinto /etc/sandbox.d
+		doins "${T}"/99${PN} #472766
+	fi
+
+	insinto /usr/share/${PN}
+	doins config/*icm
+}
diff --git a/media-gfx/imagemagick/imagemagick-7.0.7.21.ebuild b/media-gfx/imagemagick/imagemagick-7.0.7.21.ebuild
new file mode 100644
index 000000000000..6d4dff609a64
--- /dev/null
+++ b/media-gfx/imagemagick/imagemagick-7.0.7.21.ebuild
@@ -0,0 +1,185 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils flag-o-matic libtool multilib toolchain-funcs versionator
+
+MY_P=ImageMagick-$(replace_version_separator 3 '-')
+
+DESCRIPTION="A collection of tools and libraries for many image formats"
+HOMEPAGE="http://www.imagemagick.org/"
+SRC_URI="mirror://${PN}/${MY_P}.tar.xz"
+
+LICENSE="imagemagick"
+SLOT="0/${PV}"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="bzip2 corefonts cxx djvu fftw fontconfig fpx graphviz hdri jbig jpeg jpeg2k lcms lqr lzma opencl openexr openmp pango perl png postscript q32 q8 raw static-libs svg test tiff truetype webp wmf X xml zlib"
+
+RESTRICT="perl? ( userpriv )"
+
+RDEPEND="
+	dev-libs/libltdl:0
+	bzip2? ( app-arch/bzip2 )
+	corefonts? ( media-fonts/corefonts )
+	djvu? ( app-text/djvu )
+	fftw? ( sci-libs/fftw:3.0 )
+	fontconfig? ( media-libs/fontconfig )
+	fpx? ( >=media-libs/libfpx-1.3.0-r1 )
+	graphviz? ( media-gfx/graphviz )
+	jbig? ( >=media-libs/jbigkit-2:= )
+	jpeg? ( virtual/jpeg:0 )
+	jpeg2k? ( >=media-libs/openjpeg-2.1.0:2 )
+	lcms? ( media-libs/lcms:2= )
+	lqr? ( media-libs/liblqr )
+	opencl? ( virtual/opencl )
+	openexr? ( media-libs/openexr:0= )
+	pango? ( x11-libs/pango )
+	perl? ( >=dev-lang/perl-5.8.8:0= )
+	png? ( media-libs/libpng:0= )
+	postscript? ( app-text/ghostscript-gpl )
+	raw? ( media-gfx/ufraw )
+	svg? ( gnome-base/librsvg )
+	tiff? ( media-libs/tiff:0= )
+	truetype? (
+		media-fonts/urw-fonts
+		>=media-libs/freetype-2
+		)
+	webp? ( media-libs/libwebp:0= )
+	wmf? ( media-libs/libwmf )
+	X? (
+		x11-libs/libICE
+		x11-libs/libSM
+		x11-libs/libXext
+		x11-libs/libXt
+		)
+	xml? ( dev-libs/libxml2:= )
+	lzma? ( app-arch/xz-utils )
+	zlib? ( sys-libs/zlib:= )"
+DEPEND="${RDEPEND}
+	!media-gfx/graphicsmagick[imagemagick]
+	virtual/pkgconfig
+	X? ( x11-proto/xextproto )"
+
+REQUIRED_USE="corefonts? ( truetype )
+	test? ( corefonts )"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	local ati_cards mesa_cards nvidia_cards render_cards
+	default
+
+	elibtoolize # for Darwin modules
+
+	# For testsuite, see https://bugs.gentoo.org/show_bug.cgi?id=500580#c3
+	shopt -s nullglob
+	ati_cards=$(echo -n /dev/ati/card* | sed 's/ /:/g')
+	if test -n "${ati_cards}"; then
+		addpredict "${ati_cards}"
+	fi
+	mesa_cards=$(echo -n /dev/dri/card* | sed 's/ /:/g')
+	if test -n "${mesa_cards}"; then
+		addpredict "${mesa_cards}"
+	fi
+	nvidia_cards=$(echo -n /dev/nvidia* | sed 's/ /:/g')
+	if test -n "${nvidia_cards}"; then
+		addpredict "${nvidia_cards}"
+	fi
+	render_cards=$(echo -n /dev/dri/renderD128* | sed 's/ /:/g')
+	if test -n "${render_cards}"; then
+		addpredict "${render_cards}"
+	fi
+	shopt -u nullglob
+	addpredict /dev/nvidiactl
+}
+
+src_configure() {
+	local depth=16
+	use q8 && depth=8
+	use q32 && depth=32
+
+	local openmp=disable
+	use openmp && { tc-has-openmp && openmp=enable; }
+
+	[[ ${CHOST} == *-solaris* ]] && append-ldflags -lnsl -lsocket
+
+	local myeconfargs=(
+		$(use_enable static-libs static)
+		$(use_enable hdri)
+		$(use_enable opencl)
+		--with-threads
+		--with-modules
+		--with-quantum-depth=${depth}
+		$(use_with cxx magick-plus-plus)
+		$(use_with perl)
+		--with-perl-options='INSTALLDIRS=vendor'
+		--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts
+		$(use_with bzip2 bzlib)
+		$(use_with X x)
+		$(use_with zlib)
+		--without-autotrace
+		$(use_with postscript dps)
+		$(use_with djvu)
+		--with-dejavu-font-dir="${EPREFIX}"/usr/share/fonts/dejavu
+		$(use_with fftw)
+		$(use_with fpx)
+		$(use_with fontconfig)
+		$(use_with truetype freetype)
+		$(use_with postscript gslib)
+		$(use_with graphviz gvc)
+		$(use_with jbig)
+		$(use_with jpeg)
+		$(use_with jpeg2k openjp2)
+		$(use_with lcms)
+		$(use_with lqr)
+		$(use_with lzma)
+		$(use_with openexr)
+		$(use_with pango)
+		$(use_with png)
+		$(use_with svg rsvg)
+		$(use_with tiff)
+		$(use_with webp)
+		$(use_with corefonts windows-font-dir "${EPREFIX}"/usr/share/fonts/corefonts)
+		$(use_with wmf)
+		$(use_with xml)
+		--${openmp}-openmp
+		--with-gcc-arch=no-automagic
+	)
+	CONFIG_SHELL=$(type -P bash) econf "${myeconfargs[@]}"
+}
+
+src_test() {
+	LD_LIBRARY_PATH="${S}/coders/.libs:${S}/filters/.libs:${S}/Magick++/lib/.libs:${S}/magick/.libs:${S}/wand/.libs" \
+	emake check
+}
+
+src_install() {
+	# Ensure documentation installation files and paths with each release!
+	emake \
+		DESTDIR="${D}" \
+		DOCUMENTATION_PATH="${EPREFIX}"/usr/share/doc/${PF}/html \
+		install
+
+	rm -f "${ED}"/usr/share/doc/${PF}/html/{ChangeLog,LICENSE,NEWS.txt}
+	dodoc {AUTHORS,README}.txt ChangeLog
+
+	if use perl; then
+		find "${ED}" -type f -name perllocal.pod -exec rm -f {} +
+		find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} +
+	fi
+
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
+
+	if use opencl; then
+		cat <<-EOF > "${T}"/99${PN}
+		SANDBOX_PREDICT="/dev/nvidiactl:/dev/nvidia-uvm:/dev/ati/card:/dev/dri/card:/dev/dri/renderD128"
+		EOF
+
+		insinto /etc/sandbox.d
+		doins "${T}"/99${PN} #472766
+	fi
+
+	insinto /usr/share/${PN}
+	doins config/*icm
+}