mate-base/mate-settings-daemon: 1.12.x vbump, add gtk3, import from project repo

Package-Manager: portage-2.3.0

3 files changed, 78 insertions, 0 deletions

diff --git a/mate-base/mate-settings-daemon/Manifest b/mate-base/mate-settings-daemon/Manifest
index f366ef824c68..07e45e493ff8 100644
--- a/mate-base/mate-settings-daemon/Manifest
+++ b/mate-base/mate-settings-daemon/Manifest
@@ -1 +1,2 @@
 DIST mate-settings-daemon-1.10.3.tar.xz 755888 SHA256 c82b81042b0c8e7fb09e649ae19d5c7d810b31e96e7bda39fc37153897ce4a0e SHA512 057e7d8523f2b29d9fd53a62583afa99f86b8fd6f751a77c8d1f676a40360bb6629931203bab64574189e06e37492a36398b000be8426a65299f378c875d35e3 WHIRLPOOL 7fb20864fadb61c249559583768757c5809298722c9bfaea47c832bd9991ac4dba26394c0de617b03477cc9ed2c2b5f3065e39db7282e13350ca21e5fa891c9c
+DIST mate-settings-daemon-1.12.1.tar.xz 781388 SHA256 a0d9ea55ba5828500e873eff6c771dae645fa3218c1ba9d701c408f0eb71e988 SHA512 36c0d2cacef22db1d27e694602ee390fd0a24e3478837fd7fbfe069f55278c7a7ff3f7d280e0bf9cd4e827beeb9b3d40f505e5772686036e47e3d0b7d1e4b47e WHIRLPOOL 771efca75fa7c0d337648b81e52f81d085fc62287e34ccdb132c3844fedbb7e3df2a49e327d7a34048515c661ac417cffa5d5c4f74a7589f136af2e628bc2a32
diff --git a/mate-base/mate-settings-daemon/mate-settings-daemon-1.12.1.ebuild b/mate-base/mate-settings-daemon/mate-settings-daemon-1.12.1.ebuild
new file mode 100644
index 000000000000..6c657923415b
--- /dev/null
+++ b/mate-base/mate-settings-daemon/mate-settings-daemon-1.12.1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+MATE_LA_PUNT="yes"
+
+inherit mate
+
+if [[ ${PV} != 9999 ]]; then
+	KEYWORDS="~amd64 ~arm ~x86"
+fi
+
+DESCRIPTION="MATE Settings Daemon"
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+
+IUSE="X debug gtk3 libnotify policykit pulseaudio smartcard +sound"
+
+REQUIRED_USE="pulseaudio? ( sound )"
+
+RDEPEND=">=dev-libs/dbus-glib-0.74:0
+	>=dev-libs/glib-2.17.3:2
+	>=gnome-base/dconf-0.13.4:0
+	>=mate-base/libmatekbd-1.7[gtk3(-)=]
+	>=mate-base/mate-desktop-1.9[gtk3(-)=]
+	media-libs/fontconfig:1.0
+	x11-libs/cairo:0
+	x11-libs/gdk-pixbuf:2
+	x11-libs/libX11:0
+	x11-libs/libXi:0
+	x11-libs/libXext:0
+	x11-libs/libXxf86misc:0
+	>=x11-libs/libxklavier-5:0
+	virtual/libintl:0
+	!gtk3? ( >=x11-libs/gtk+-2.24:2 )
+	gtk3? ( >=x11-libs/gtk+-3.0:3 )
+	libnotify? ( >=x11-libs/libnotify-0.7:0 )
+	policykit? (
+		>=dev-libs/dbus-glib-0.71:0
+		>=sys-apps/dbus-1.1.2:0
+		>=sys-auth/polkit-0.97:0
+	)
+	pulseaudio? (
+		>=media-libs/libmatemixer-1.10:0[pulseaudio]
+		>=media-sound/pulseaudio-0.9.15:0
+	)
+	smartcard? ( >=dev-libs/nss-3.11.2:0 )
+	sound? (
+		>=media-libs/libmatemixer-1.9
+		!gtk3? ( media-libs/libcanberra:0[gtk] )
+		gtk3? ( media-libs/libcanberra:0[gtk3] )
+	)"
+
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.50.1:0
+	sys-devel/gettext:0
+	virtual/pkgconfig:0
+	x11-proto/inputproto:0
+	x11-proto/xproto:0"
+
+src_configure() {
+	mate_src_configure \
+		--with-gtk=$(usex gtk3 3.0 2.0) \
+		$(use_with X x) \
+		$(use_with libnotify) \
+		$(use_with sound libcanberra) \
+		$(use_with sound libmatemixer) \
+		$(use_enable debug) \
+		$(use_enable policykit polkit) \
+		$(use_enable pulseaudio pulse) \
+		$(use_enable smartcard smartcard-support)
+}
diff --git a/mate-base/mate-settings-daemon/metadata.xml b/mate-base/mate-settings-daemon/metadata.xml
index 34327a4d4428..854c7a30f028 100644
--- a/mate-base/mate-settings-daemon/metadata.xml
+++ b/mate-base/mate-settings-daemon/metadata.xml
@@ -5,6 +5,9 @@
         <email>mate@gentoo.org</email>
         <name>Gentoo MATE Desktop</name>
     </maintainer>
+	<use>
+		<flag name="gtk3">Build with GTK+3 instead of GTK+2</flag>
+	</use>
     <upstream>
         <remote-id type="github">mate-desktop/mate-settings-daemon</remote-id>
     </upstream>