kde-plasma: Add KDE Plasma 5.19.0

Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 83 insertions, 0 deletions

diff --git a/kde-plasma/plasma-nm/Manifest b/kde-plasma/plasma-nm/Manifest
index 13a126294a3b..47c30789f8d4 100644
--- a/kde-plasma/plasma-nm/Manifest
+++ b/kde-plasma/plasma-nm/Manifest
@@ -1 +1,2 @@
 DIST plasma-nm-5.18.5.tar.xz 828008 BLAKE2B 557a31d5a0e7886be90e62be3f5328baf4a8bbfeb3e9decf1f2f106f33bef7e64fb886b94691faab57119f231b6bbcff58514d795df75f858ca9c8ea8c1af9a7 SHA512 8f785f257f274fb9384bf2afbe4231a057c46706483e26dd2270a93a6fc97e6198916ff119d258a67d4f8bb73facb0ff67412f43e5fa66812962edb64331db4a
+DIST plasma-nm-5.19.0.tar.xz 853872 BLAKE2B 8236c7f0e8f3c5097d2278fb728454676ca35e8fe5d8b05819da89ff35ed82bd5c0097f8fa393c699ff5c8fc47a16add871c6165d4599543e9edefa63f4df11c SHA512 09eefd9d05525d7eca3dc1f4102a48ca08307b8f26bd85e50ecb166db0d0c764d87f0ea812ec44fdf791c16df48b0c021b5689d252276e181c2e401f78d53071
diff --git a/kde-plasma/plasma-nm/plasma-nm-5.19.0.ebuild b/kde-plasma/plasma-nm/plasma-nm-5.19.0.ebuild
new file mode 100644
index 000000000000..5a3983e28f53
--- /dev/null
+++ b/kde-plasma/plasma-nm/plasma-nm-5.19.0.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_TEST="true"
+KFMIN=5.70.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.14.1
+inherit ecm kde.org
+
+DESCRIPTION="KDE Plasma applet for NetworkManager"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64"
+IUSE="modemmanager openconnect teamd"
+
+DEPEND="
+	>=app-crypt/qca-2.1.1:2[qt5(+)]
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/networkmanager-qt-${KFMIN}:5[teamd=]
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	net-misc/networkmanager[teamd=]
+	modemmanager? (
+		>=dev-qt/qtxml-${QTMIN}:5
+		>=kde-frameworks/modemmanager-qt-${KFMIN}:5
+		net-misc/mobile-broadband-provider-info
+	)
+	openconnect? (
+		>=dev-qt/qtxml-${QTMIN}:5
+		net-vpn/networkmanager-openconnect
+		net-vpn/openconnect:=
+	)
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DDISABLE_MODEMMANAGER_SUPPORT=$(usex !modemmanager)
+		$(cmake_use_find_package modemmanager KF5ModemManagerQt)
+		$(cmake_use_find_package openconnect OpenConnect)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	if ! has_version "kde-plasma/plasma-workspace:5"; then
+		elog "${PN} is not terribly useful without kde-plasma/plasma-workspace:5."
+		elog "However, the networkmanagement KCM can be called from either systemsettings"
+		elog "or manually: $ kcmshell5 kcm_networkmanagement"
+	fi
+}