kde-frameworks/kirigami: Drop examples from 5.116.0

Now that KF6 is close to stabilisation, let's take care of those users
enabling USE=examples globally. In this case, simply KF6 based examples
trump older KF5 based ones, no special handling worth putting effort into.

Bug: https://bugs.gentoo.org/934478
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 52 insertions, 0 deletions

diff --git a/kde-frameworks/kirigami/kirigami-5.116.0-r1.ebuild b/kde-frameworks/kirigami/kirigami-5.116.0-r1.ebuild
new file mode 100644
index 000000000000..136cd68024e5
--- /dev/null
+++ b/kde-frameworks/kirigami/kirigami-5.116.0-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_EXAMPLES="false"
+ECM_QTHELP="false"
+ECM_TEST="true"
+KDE_ORG_TAR_PN="${PN}2"
+QTMIN=5.15.9
+inherit ecm frameworks.kde.org toolchain-funcs
+
+DESCRIPTION="Lightweight user interface framework for mobile and convergent applications"
+HOMEPAGE="https://techbase.kde.org/Kirigami"
+
+LICENSE="LGPL-2+"
+KEYWORDS="amd64 ~arm arm64 ~loong ~ppc64 ~riscv x86"
+IUSE="openmp"
+
+# requires package to already be installed
+RESTRICT="test"
+
+DEPEND="
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
+"
+BDEPEND=">=dev-qt/linguist-tools-${QTMIN}:5"
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_EXAMPLES=OFF
+		$(cmake_use_find_package openmp OpenMP)
+	)
+
+	ecm_src_configure
+}