kde-frameworks: Add KDE Frameworks 5.71.0

Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 69 insertions, 0 deletions

diff --git a/kde-frameworks/kfilemetadata/Manifest b/kde-frameworks/kfilemetadata/Manifest
index e91fc0d7117d..69aa884686c2 100644
--- a/kde-frameworks/kfilemetadata/Manifest
+++ b/kde-frameworks/kfilemetadata/Manifest
@@ -1 +1,2 @@
 DIST kfilemetadata-5.70.0.tar.xz 422812 BLAKE2B f55aab0be0009d0d190c6625ec2ce3a8ec297c62570ecb2724e2ddd4c5fb69397ffd3b2e822cf6301e8af18375de0f29015e61c93618b220c0fda86d1d293791 SHA512 51576765c334e885ef55bc6373821583f8ad1fe81cd6e7aaaa21c4ede9cae27fd162e5bbb29dd553e1cbc045a3396dd8d48d66171ce7dc82d4976d9c698df706
+DIST kfilemetadata-5.71.0.tar.xz 425156 BLAKE2B 1332693db05f5fc284026b8ae8c59145478b6c6adbb894c060217a61cc9c59f624e43bc2c36fd7a404961e19833f821b755444de645449b2719209123f887f5e SHA512 745a124ea48218d1be7b207393c045b6c2c6fdf063925340ed434593663c8fa28e45b622f52a12edf0d0bba7258449e7505d0b9d3ab8318bf969c7d5ce8decb1
diff --git a/kde-frameworks/kfilemetadata/kfilemetadata-5.71.0.ebuild b/kde-frameworks/kfilemetadata/kfilemetadata-5.71.0.ebuild
new file mode 100644
index 000000000000..63201f961d01
--- /dev/null
+++ b/kde-frameworks/kfilemetadata/kfilemetadata-5.71.0.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.14.1
+inherit ecm kde.org python-any-r1
+
+DESCRIPTION="Library for extracting file metadata"
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="epub exif ffmpeg kernel_linux office pdf taglib"
+
+BDEPEND="
+	test? ( ${PYTHON_DEPS} )
+"
+RDEPEND="
+	>=dev-qt/qtxml-${QTMIN}:5
+	=kde-frameworks/kcoreaddons-${PVCUT}*:5
+	=kde-frameworks/ki18n-${PVCUT}*:5
+	epub? ( app-text/ebook-tools )
+	exif? ( media-gfx/exiv2:= )
+	ffmpeg? ( media-video/ffmpeg:0= )
+	office? ( =kde-frameworks/karchive-${PVCUT}*:5 )
+	pdf? ( app-text/poppler[qt5] )
+	taglib? ( media-libs/taglib )
+"
+DEPEND="${RDEPEND}
+	kernel_linux? ( sys-apps/attr )
+"
+
+RESTRICT+=" test"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+	ecm_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package epub EPub)
+		$(cmake_use_find_package exif LibExiv2)
+		$(cmake_use_find_package ffmpeg FFmpeg)
+		$(cmake_use_find_package office KF5Archive)
+		$(cmake_use_find_package pdf Poppler)
+		$(cmake_use_find_package taglib Taglib)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# FIXME: bug 644650, fails on tmpfs (but not for everyone)
+	local myctestargs=( -E "(usermetadatawritertest)" )
+	ecm_src_test
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	if ! has_version app-text/catdoc || ! has_version dev-libs/libxls; then
+		elog "To get additional features, optional runtime dependencies may be installed:"
+		elog "app-text/catdoc - indexing of Microsoft Word or Powerpoint files"
+		elog "dev-libs/libxls - indexing of Microsoft Excel files"
+	fi
+}