kde-apps/kig: 22.12.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 73 insertions, 0 deletions

diff --git a/kde-apps/kig/Manifest b/kde-apps/kig/Manifest
index b1d4d30c8dd3..a703c3f56ca0 100644
--- a/kde-apps/kig/Manifest
+++ b/kde-apps/kig/Manifest
@@ -1 +1,2 @@
 DIST kig-22.08.3.tar.xz 3184760 BLAKE2B 8027e137dea63294bf4ae30aa4ad8510140b6d44e63edcf2fc336124070e2fc539d8350bcb459b65b06a331f2ec1fc970df402969505d1818bc148497de078a8 SHA512 f71043e4eddd2d1391d43fe9f9300e6357d6c01077e12b6b0f37c2facd5c213985591a2c43aa6cae9598db5e1da9789a2929eacd5f64789a1009d5db59ed16c8
+DIST kig-22.12.0.tar.xz 3274592 BLAKE2B 9bc70f824892086dd4b4bc3599abe1e33233e231d8bbfa4725254cfc3abbeaeb0f82bcba2e23c580a18f7290ec90413c26c6d9953c956a0a88f7f955e65d0bfa SHA512 bfe9337880feaaaddbf43efae2eff8ee186d5873d7b54fae25cc1fedb49dedadfb27bdf9e415ea10fd33bfacec1fb4044c1e41ae1312d62fc23160c42b5b5e3e
diff --git a/kde-apps/kig/kig-22.12.0.ebuild b/kde-apps/kig/kig-22.12.0.ebuild
new file mode 100644
index 000000000000..7c1de3d109cf
--- /dev/null
+++ b/kde-apps/kig/kig-22.12.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+PYTHON_COMPAT=( python3_{8..11} )
+KFMIN=5.99.0
+QTMIN=5.15.5
+inherit python-single-r1 ecm gear.kde.org
+
+DESCRIPTION="KDE Interactive Geometry tool"
+HOMEPAGE="https://apps.kde.org/kig/ https://edu.kde.org/kig/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="geogebra scripting"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	geogebra? ( >=dev-qt/qtxmlpatterns-${QTMIN}:5 )
+	scripting? (
+		$(python_gen_cond_dep '
+			>=dev-libs/boost-1.70:=[python,${PYTHON_USEDEP}]
+		')
+	)
+"
+DEPEND="${RDEPEND}
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+"
+
+PATCHES=( "${FILESDIR}"/${PN}-20.08.70-cmake-boostpython.patch )
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	ecm_pkg_setup
+}
+
+src_prepare() {
+	ecm_src_prepare
+	python_fix_shebang .
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBOOSTPYTHON_VERSION_MAJOR_MINOR=${EPYTHON}
+		$(cmake_use_find_package geogebra Qt5XmlPatterns)
+		$(cmake_use_find_package scripting Boost)
+	)
+
+	ecm_src_configure
+}