kde-apps/dolphin-plugins-dropbox: 20.08.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 65 insertions, 0 deletions

diff --git a/kde-apps/dolphin-plugins-dropbox/Manifest b/kde-apps/dolphin-plugins-dropbox/Manifest
index e357f5d4e437..a71bf45f0572 100644
--- a/kde-apps/dolphin-plugins-dropbox/Manifest
+++ b/kde-apps/dolphin-plugins-dropbox/Manifest
@@ -1 +1,2 @@
 DIST dolphin-plugins-20.04.3.tar.xz 213888 BLAKE2B 8ad8e98a42c5a6d12bd3c03ffcc9f5923d1651bc10a74152f5561ebf59b50aafa24fe29d0ea6a7ce147d4f8732fa72c50664b7a890a6e4fe00c64298c8aa0bd4 SHA512 cab1d81deb8204e2d95ae10dc375d5cdc98958ae3dd0a969ee9ea78326229877cd314d2f37266b2ef1ebcdd876cffade6d7e5ee296028867f9c00592c8cd6eb6
+DIST dolphin-plugins-20.08.0.tar.xz 227076 BLAKE2B 363636a0ad68b702e905cea14ca06311372b3fb647c57ea59375a859ad95d32cb2dbd851d209b991ffa143b85dcf1594cfd6493defa4886ebad6d201cf63d256 SHA512 4a9578bc9c20c9bcbb282369b7ac6955bdf1de20609762c2d0b396bd24a0a561422eda961f44761f59a2741db8b5191c8c6feb972d4a54a386ebb0fde67de5cb
diff --git a/kde-apps/dolphin-plugins-dropbox/dolphin-plugins-dropbox-20.08.0.ebuild b/kde-apps/dolphin-plugins-dropbox/dolphin-plugins-dropbox-20.08.0.ebuild
new file mode 100644
index 000000000000..5f2f640acffb
--- /dev/null
+++ b/kde-apps/dolphin-plugins-dropbox/dolphin-plugins-dropbox-20.08.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="false"
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="dropbox"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.72.0
+QTMIN=5.14.2
+inherit ecm kde.org
+
+DESCRIPTION="Dolphin plugin for Dropbox service integration"
+HOMEPAGE="https://kde.org/applications/system/org.kde.dolphin_plugins"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/dolphin-${PVCUT}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	!kde-apps/dolphin-plugins:5
+	net-misc/dropbox-cli
+"
+
+src_prepare() {
+	ecm_src_prepare
+	# solid, qtdbus only required by mountiso
+	ecm_punt_bogus_dep Qt5 DBus
+	ecm_punt_bogus_dep KF5 Solid
+	# delete non-${PN} translations
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find po -type f -name "*po" -and -not -name "*${MY_PLUGIN_NAME}plugin" -delete || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_${MY_PLUGIN_NAME}=ON
+		-DBUILD_bazaar=OFF
+		-DBUILD_git=OFF
+		-DBUILD_hg=OFF
+		-DBUILD_mountiso=OFF
+		-DBUILD_svn=OFF
+	)
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	rm "${D}"/usr/share/metainfo/org.kde.dolphin-plugins.metainfo.xml || die
+}