gui-wm/sway: 1.6 bump

Package-Manager: Portage-3.0.17, Repoman-3.0.2
Signed-off-by: Matthew Thode <prometheanfire@gentoo.org>

3 files changed, 118 insertions, 1 deletions

diff --git a/gui-wm/sway/Manifest b/gui-wm/sway/Manifest
index c6267a153727..ed173c7796c3 100644
--- a/gui-wm/sway/Manifest
+++ b/gui-wm/sway/Manifest
@@ -1 +1,2 @@
 DIST sway-1.5.1.tar.gz 5536721 BLAKE2B 4dcb6ca380ef8451ab9219a584598928a79e999bc0b1de0599cb7867c8fd94d54c55a2be9585635b4fd230fd83852141d6fd41ef35dbc4a8fef1bcc2828b3be4 SHA512 3b937249db2875100bc22e99f955a3300d3294a296fb37006fa1468a3986bf4fa8e5197279e3587bd8dc29f31adff8fbdc9ddc840e7be982b73331a05cd06ba5
+DIST sway-1.6.tar.gz 5549909 BLAKE2B ee0d7aad2fe8c57061e23e9b875ebb8e991e2fb30483dee6cf7d7faa3ec782a3f28676bf9fe2183c0e643b5ed744535eba07d7e5cf20ec0756c8e5407c0f34e2 SHA512 f62477aa4a20de99c41078c6866ec67d04d0d1824f4cb21a0c40213dbadf6394e31cd239b74376bf604d20d03ce047ba97f1728043568fd49fcef43f5101c750
diff --git a/gui-wm/sway/sway-1.6.ebuild b/gui-wm/sway/sway-1.6.ebuild
new file mode 100644
index 000000000000..b0647726df7b
--- /dev/null
+++ b/gui-wm/sway/sway-1.6.ebuild
@@ -0,0 +1,115 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit eutils meson
+
+DESCRIPTION="i3-compatible Wayland window manager"
+HOMEPAGE="https://swaywm.org"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/swaywm/${PN}.git"
+else
+	MY_PV=${PV/_rc/-rc}
+	SRC_URI="https://github.com/swaywm/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+	S="${WORKDIR}/${PN}-${MY_PV}"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="elogind fish-completion +man +swaybar +swaybg +swayidle +swaylock +swaymsg +swaynag seatd systemd tray wallpapers X zsh-completion"
+REQUIRED_USE="?? ( elogind systemd )
+	tray? ( || ( elogind seatd systemd ) )"
+
+DEPEND="
+	>=dev-libs/json-c-0.13:0=
+	>=dev-libs/libinput-1.6.0:0=
+	dev-libs/libpcre
+	dev-libs/wayland
+	x11-libs/cairo
+	x11-libs/libxkbcommon
+	x11-libs/pango
+	x11-libs/pixman
+	media-libs/mesa[gles2,libglvnd(+)]
+	elogind? ( >=sys-auth/elogind-239 )
+	swaybar? ( x11-libs/gdk-pixbuf:2 )
+	swaybg? ( gui-apps/swaybg )
+	swayidle? ( gui-apps/swayidle )
+	swaylock? ( gui-apps/swaylock )
+	systemd? ( >=sys-apps/systemd-239[policykit] )
+	wallpapers? ( x11-libs/gdk-pixbuf:2[jpeg] )
+	X? ( x11-libs/libxcb:0= )
+"
+if [[ ${PV} == 9999 ]]; then
+	DEPEND+="~gui-libs/wlroots-9999:=[elogind=,seatd=,systemd=,X=]"
+else
+	DEPEND+="
+		>=gui-libs/wlroots-0.13:=[elogind=,seatd=,systemd=,X=]
+		<gui-libs/wlroots-0.14:=[elogind=,seatd=,systemd=,X=]
+	"
+fi
+RDEPEND="
+	x11-misc/xkeyboard-config
+	${DEPEND}
+"
+BDEPEND="
+	>=dev-libs/wayland-protocols-1.14
+	>=dev-util/meson-0.53.0
+	virtual/pkgconfig
+"
+if [[ ${PV} == 9999 ]]; then
+	BDEPEND+="man? ( ~app-text/scdoc-9999 )"
+else
+	BDEPEND+="man? ( >=app-text/scdoc-1.9.3 )"
+fi
+
+src_prepare() {
+	default
+
+	use swaybar || sed -e "s/subdir('swaybar')//g" -e "/sway-bar.[0-9].scd/d" \
+		-e "/completions\/[a-z]\+\/_\?swaybar/d" -i meson.build || die
+	use swaymsg || sed -e "s/subdir('swaymsg')//g" -e "/swaymsg.[0-9].scd/d" \
+		-e "/completions\/[a-z]\+\/_\?swaymsg/d" -i meson.build || die
+	use swaynag || sed -e "s/subdir('swaynag')//g" -e "/swaynag.[0-9].scd/d" \
+		-e "/completions\/[a-z]\+\/_\?swaynag/d" -i meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dman-pages=$(usex man enabled disabled)
+		-Dtray=$(usex tray enabled disabled)
+		-Dxwayland=$(usex X enabled disabled)
+		$(meson_use wallpapers default-wallpaper)
+		$(meson_use fish-completion fish-completions)
+		$(meson_use zsh-completion zsh-completions)
+		"-Dbash-completions=true"
+		"-Dwerror=false"
+	)
+
+	if use swaybar; then
+		emesonargs+=("-Dgdk-pixbuf=enabled")
+	else
+		emesonargs+=("-Dgdk-pixbuf=disabled")
+	fi
+
+	meson_src_configure
+}
+
+pkg_preinst() {
+	if ! use systemd && ! use elogind && ! use seatd; then
+		fowners root:0 /usr/bin/sway
+		fperms 4511 /usr/bin/sway
+	fi
+}
+
+pkg_postinst() {
+	if ! use systemd && ! use elogind && ! use seatd; then
+		elog ""
+		elog "If your system does not set the XDG_RUNTIME_DIR environment"
+		elog "variable, you must set it manually to run Sway. See wiki"
+		elog "for details: https://wiki.gentoo.org/wiki/Sway"
+	fi
+}
diff --git a/gui-wm/sway/sway-9999.ebuild b/gui-wm/sway/sway-9999.ebuild
index d03dab5a9bc0..b0647726df7b 100644
--- a/gui-wm/sway/sway-9999.ebuild
+++ b/gui-wm/sway/sway-9999.ebuild
@@ -47,7 +47,8 @@ if [[ ${PV} == 9999 ]]; then
 	DEPEND+="~gui-libs/wlroots-9999:=[elogind=,seatd=,systemd=,X=]"
 else
 	DEPEND+="
-		=gui-libs/wlroots-0.12.0*:=[elogind=,seatd=,systemd=,X=]
+		>=gui-libs/wlroots-0.13:=[elogind=,seatd=,systemd=,X=]
+		<gui-libs/wlroots-0.14:=[elogind=,seatd=,systemd=,X=]
 	"
 fi
 RDEPEND="