gui-wm/sway: 1.7 bump :D

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Matthew Thode <prometheanfire@gentoo.org>

3 files changed, 87 insertions, 4 deletions

diff --git a/gui-wm/sway/Manifest b/gui-wm/sway/Manifest
index fd95879a6f9f..71b949b10486 100644
--- a/gui-wm/sway/Manifest
+++ b/gui-wm/sway/Manifest
@@ -1 +1,2 @@
 DIST sway-1.6.1.tar.gz 5550126 BLAKE2B a4ecc93df0eb16fcd9037ce62dd39c63e1712b3bc9e8ae36331a815759b18576f4a2c1b78a26545922038974f226f02e2d91f78d6e3933125d9b808871b7a887 SHA512 7f37fea99970db42c5485277df06d69bef5225fa03d25be179893b14d73c1d681f0355a1bc74091b4173bbccc88994a63ad0f9322e070811ba963648cf68cdeb
+DIST sway-1.7.tar.gz 5559075 BLAKE2B 702b9a209d603c88743f2e89d0787431b7a30e8b7554c9596edb9735af862d23c585158737a0943a470637138cbc5275bee37bd2d820a7489cdd0747d98e6e22 SHA512 028cf5d504d5914bfb78d44156d6a290de660c5ed0638f4e2c56e5be76db9b0baeda035e1fa1ae23559016bd7e4312f7ff70c2fb4904df25358577c1a3d21243
diff --git a/gui-wm/sway/sway-1.7.ebuild b/gui-wm/sway/sway-1.7.ebuild
new file mode 100644
index 000000000000..c23563749bdc
--- /dev/null
+++ b/gui-wm/sway/sway-1.7.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson
+
+DESCRIPTION="i3-compatible Wayland window manager"
+HOMEPAGE="https://swaywm.org"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/swaywm/${PN}.git"
+else
+	MY_PV=${PV/_rc/-rc}
+	SRC_URI="https://github.com/swaywm/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+	S="${WORKDIR}/${PN}-${MY_PV}"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="+man +swaybar +swaybg +swayidle +swaylock +swaymsg +swaynag tray wallpapers X"
+
+DEPEND="
+	>=dev-libs/json-c-0.13:0=
+	>=dev-libs/libinput-1.6.0:0=
+	sys-auth/seatd:=
+	dev-libs/libpcre
+	>=dev-libs/wayland-1.20.0
+	x11-libs/cairo
+	x11-libs/libxkbcommon
+	x11-libs/pango
+	x11-libs/pixman
+	media-libs/mesa[gles2,libglvnd(+)]
+	swaybar? ( x11-libs/gdk-pixbuf:2 )
+	swaybg? ( gui-apps/swaybg )
+	swayidle? ( gui-apps/swayidle )
+	swaylock? ( gui-apps/swaylock )
+	wallpapers? ( x11-libs/gdk-pixbuf:2[jpeg] )
+	X? ( x11-libs/libxcb:0= )
+"
+if [[ ${PV} == 9999 ]]; then
+	DEPEND+="~gui-libs/wlroots-9999:=[X=]"
+else
+	DEPEND+="
+		>=gui-libs/wlroots-0.15:=[X=]
+		<gui-libs/wlroots-0.16:=[X=]
+	"
+fi
+RDEPEND="
+	x11-misc/xkeyboard-config
+	${DEPEND}
+"
+BDEPEND="
+	>=dev-libs/wayland-protocols-1.24
+	>=dev-util/meson-0.60.0
+	virtual/pkgconfig
+"
+if [[ ${PV} == 9999 ]]; then
+	BDEPEND+="man? ( ~app-text/scdoc-9999 )"
+else
+	BDEPEND+="man? ( >=app-text/scdoc-1.9.3 )"
+fi
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature man man-pages)
+		$(meson_feature tray)
+		$(meson_feature X xwayland)
+		$(meson_feature swaybar gdk-pixbuf)
+		$(meson_use swaynag)
+		$(meson_use swaybar)
+		$(meson_use wallpapers default-wallpaper)
+		-Dfish-completions=true
+		-Dzsh-completions=true
+		-Dbash-completions=true
+		-Dwerror=false
+	)
+
+	meson_src_configure
+}
diff --git a/gui-wm/sway/sway-9999.ebuild b/gui-wm/sway/sway-9999.ebuild
index 966fdddfa29c..376a229bbf80 100644
--- a/gui-wm/sway/sway-9999.ebuild
+++ b/gui-wm/sway/sway-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -14,7 +14,7 @@ if [[ ${PV} == 9999 ]]; then
 else
 	MY_PV=${PV/_rc/-rc}
 	SRC_URI="https://github.com/swaywm/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
 	S="${WORKDIR}/${PN}-${MY_PV}"
 fi
 
@@ -44,8 +44,8 @@ if [[ ${PV} == 9999 ]]; then
 	DEPEND+="~gui-libs/wlroots-9999:=[X=]"
 else
 	DEPEND+="
-		>=gui-libs/wlroots-0.15:=[X=]
-		<gui-libs/wlroots-0.16:=[X=]
+		>=gui-libs/wlroots-0.16:=[X=]
+		<gui-libs/wlroots-0.17:=[X=]
 	"
 fi
 RDEPEND="