gnome-base/gnome-desktop: bump to 40.6

Package-Manager: Portage-3.0.20, Repoman-3.0.2
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

2 files changed, 71 insertions, 0 deletions

diff --git a/gnome-base/gnome-desktop/Manifest b/gnome-base/gnome-desktop/Manifest
index 53ee0e48a0b5..1ee97e4de9c8 100644
--- a/gnome-base/gnome-desktop/Manifest
+++ b/gnome-base/gnome-desktop/Manifest
@@ -2,3 +2,4 @@ DIST gnome-desktop-40.2.tar.xz 721852 BLAKE2B a7258d0465b17c5c9c78a066acd72571c0
 DIST gnome-desktop-40.3.tar.xz 721788 BLAKE2B bfdb77995d8cb392805a9d4a7a1276608aa53ea7c73604b12817c1660176c4e0274ba6954523cd0bec067230520c2736ed77885726696e463c97d09992186243 SHA512 96f2069ec3eb1bd1f6c2056c73d268eed5521398818cc05c22cdedfd1c09805fe5abc7f450abc7752690e809f3bdca502dfc107564236bbb03e262531418804f
 DIST gnome-desktop-40.4.tar.xz 721840 BLAKE2B f663460ce6a2b2d03543e92eab9e2f127da4a7c8e800149842f5f30e4f885c104786806be8e8f32e0783003b18015d39b4501f3ceccdee0ab94206031bf671b4 SHA512 4e91438c17faa2d12e7d6a9914fe4308543bbd5f8821e94dee9052f087110e2a3776109c203de6ef7bf66ae1825fc5e890d969ce2ebab2654cc157e9629fe6fc
 DIST gnome-desktop-40.5.tar.xz 722316 BLAKE2B 1f2e214eaea74295c892a465f767d29175ac0719a66d8d5b60b924c448f7b8317d3f9e23361d65b4d171018edd206dce764c38545a716ad9c83f20214fe5c4e9 SHA512 a65bf42be69d04efd80da6a8c8b08c4adc09db1c6627b93d4eecc3396376bc4407bfad914fc131d16d78b3b3263e635c925ed3dcff92af069525f809bea21afc
+DIST gnome-desktop-40.6.tar.xz 722388 BLAKE2B b13fbf4ba6c38a5b26f3275b973f834d41416f7163ccf192a20fc9092af8021d5a9ba34a7a44141b1f6f61a890fee1d3e4a89b047bd0b27c42d4296a98ca88a2 SHA512 0e1bd2c1add0485d6c6cdaf1ba816ad4cbe1dd338d494ff90b09f2ac8cef140433c136b4be4e6832478e4880fb8bfbf3cc931b3925cad29b64eca4573d6c4498
diff --git a/gnome-base/gnome-desktop/gnome-desktop-40.6.ebuild b/gnome-base/gnome-desktop/gnome-desktop-40.6.ebuild
new file mode 100644
index 000000000000..4d52f427709e
--- /dev/null
+++ b/gnome-base/gnome-desktop/gnome-desktop-40.6.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="Library with common API for various GNOME modules"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-desktop/"
+
+LICENSE="GPL-2+ LGPL-2+ FDL-1.1+"
+SLOT="3/19" # subslot = libgnome-desktop-3 soname version
+IUSE="debug gtk-doc +introspection seccomp systemd udev"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+
+COMMON_DEPEND="
+	>=x11-libs/gdk-pixbuf-2.36.5:2[introspection?]
+	>=x11-libs/gtk+-3.3.6:3[X,introspection?]
+	>=dev-libs/glib-2.53.0:2
+	>=gnome-base/gsettings-desktop-schemas-3.27.0[introspection?]
+	x11-misc/xkeyboard-config
+	x11-libs/libxkbcommon
+	app-text/iso-codes
+	systemd? ( sys-apps/systemd:= )
+	udev? ( virtual/libudev:= )
+	seccomp? ( sys-libs/libseccomp )
+
+	x11-libs/cairo:=
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${COMMON_DEPEND}
+	media-libs/fontconfig
+"
+RDEPEND="${COMMON_DEPEND}
+	seccomp? ( sys-apps/bubblewrap )
+"
+BDEPEND="
+	app-text/docbook-xml-dtd:4.1.2
+	dev-util/gdbus-codegen
+	gtk-doc? ( >=dev-util/gtk-doc-1.14 )
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	x11-base/xorg-proto
+	virtual/pkgconfig
+"
+# Includes X11/Xatom.h in libgnome-desktop/gnome-bg.c which comes from xorg-proto
+
+PATCHES=(
+	"${FILESDIR}"/3.32.2-optional-introspection.patch # add introspection meson option
+)
+
+src_prepare() {
+	# Don't build manual test programs that will never get run
+	sed -i -e "/'test-.*'/d" libgnome-desktop/meson.build || die
+	xdg_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dgnome_distributor=Gentoo
+		-Ddate_in_gnome_version=true
+		-Ddesktop_docs=true
+		$(meson_use debug debug_tools)
+		$(meson_use introspection)
+		$(meson_feature udev)
+		$(meson_feature systemd)
+		$(meson_use gtk-doc gtk_doc)
+		-Dinstalled_tests=false
+	)
+	meson_src_configure
+}