games-strategy/naev: add 0.10.1

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

2 files changed, 102 insertions, 0 deletions

diff --git a/games-strategy/naev/Manifest b/games-strategy/naev/Manifest
index 626f661e0ccb..56240bde5b35 100644
--- a/games-strategy/naev/Manifest
+++ b/games-strategy/naev/Manifest
@@ -1,2 +1,3 @@
 DIST naev-0.10.0-source.tar.xz 444793760 BLAKE2B efac6df5c5e75c2367ab9b9c2d6a208e917634bf10544516955f1a66e3a8ab31f37ecea9c327478accbd6f33342341542c49fda160c6e19175c67b88301d1e5f SHA512 419573ce6812e87ee73527df0c68853405046b6e3ac16a1de32b754c1a7aefaeecd285d0252115c421154e0695d64c28b06810fcff230b9bed722b694368ac35
+DIST naev-0.10.1-source.tar.xz 444805652 BLAKE2B 5855608c14ba2d32824d14867c60b91321dba0be44e9857f795db308353428c6c0fcf891dc099221695e94479f6bffbc309e97380751d70b55f2060f889a9144 SHA512 91a1f3909462cb00a366a5006a1ea5da289f10dfe8ec3a5b8ab21bc281a74742724bb287fc8ffc31277e38b0f4c778812b800eb814f399b480ba72deb957249c
 DIST naev-0.9.4-source.tar.xz 395461576 BLAKE2B cbfdc443ecb8cb27694769d054f7162c3d1d2bcd8dc28045696d6891abfb46e4a3518ce265c97b55a96b8d000c9900e4bc49ae7b45a16db75f9de48ea0cb702b SHA512 e8efb115d8d623ea92d348854d98ee22e8863aaf6555efa058d6160210f000186ae39f054f5b4f0fa8d92949de83defa35d4acd8216398157a1a42886745ddab
diff --git a/games-strategy/naev/naev-0.10.1.ebuild b/games-strategy/naev/naev-0.10.1.ebuild
new file mode 100644
index 000000000000..a7a76f796caf
--- /dev/null
+++ b/games-strategy/naev/naev-0.10.1.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-1 luajit )
+PYTHON_COMPAT=( python3_{8..11} )
+inherit lua-single meson python-any-r1 virtualx xdg
+
+DESCRIPTION="2D space trading and combat game, in a similar vein to Escape Velocity"
+HOMEPAGE="https://naev.org/"
+SRC_URI="https://github.com/naev/naev/releases/download/v${PV}/${P}-source.tar.xz"
+
+LICENSE="
+	GPL-3+
+	Apache-2.0 BSD BSD-2 CC-BY-2.0 CC-BY-3.0 CC-BY-4.0 CC-BY-SA-3.0
+	CC-BY-SA-4.0 CC0-1.0 GPL-2+ MIT OFL-1.1 public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+# dlopen: libglvnd
+RDEPEND="
+	${LUA_DEPS}
+	dev-games/physfs
+	dev-libs/libpcre2:=
+	dev-libs/libunibreak:=
+	dev-libs/libxml2
+	media-libs/freetype:2
+	media-libs/libglvnd
+	media-libs/libsdl2[joystick,opengl,video]
+	media-libs/libvorbis
+	media-libs/openal
+	media-libs/sdl2-image[png,webp]
+	net-libs/enet:1.3=
+	sci-libs/cholmod
+	sci-libs/cxsparse
+	sci-libs/openblas
+	sci-libs/suitesparse
+	sci-mathematics/glpk:=
+	virtual/libintl"
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-games/physfs[zip]
+		media-libs/libsdl2[X]
+		media-libs/mesa[llvm]
+	)"
+BDEPEND="
+	$(python_gen_any_dep 'dev-python/pyyaml[${PYTHON_USEDEP}]')
+	sys-devel/gettext
+	doc? (
+		app-doc/doxygen[dot]
+		dev-lua/ldoc
+	)"
+
+python_check_deps() {
+	python_has_version "dev-python/pyyaml[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	lua-single_pkg_setup
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# use eclass' generated lua.pc first rather than as fallback
+	sed -i "s/'lua51'/'lua'/" meson.build || die
+
+	# don't probe OpenGL for tests (avoids sandbox violations, bug #829369)
+	sed -i "/subdir('glcheck')/d" test/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature doc docs_c)
+		$(meson_feature doc docs_lua)
+		$(meson_feature lua_single_target_luajit luajit)
+	)
+
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+src_install() {
+	local DOCS=( CHANGELOG Readme.md )
+	meson_src_install
+
+	if use doc; then
+		dodir /usr/share/doc/${PF}/html
+		mv "${ED}"/usr/{doc/naev/{c,lua},share/doc/${PF}/html} || die
+		rm -r "${ED}"/usr/doc || die
+	fi
+	rm -r "${ED}"/usr/share/doc/naev || die
+}