dev-vcs/gitg: Version bump to 44

Signed-off-by: Guillermo Joandet <gjoandet@gmail.com>
Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 91 insertions, 0 deletions

diff --git a/dev-vcs/gitg/Manifest b/dev-vcs/gitg/Manifest
index 706c061c5b4b..f81d7d6c91c5 100644
--- a/dev-vcs/gitg/Manifest
+++ b/dev-vcs/gitg/Manifest
@@ -1 +1,2 @@
 DIST gitg-41.tar.xz 10604696 BLAKE2B bc8a07565338f77a0a4706d6ff145ed09096acb0230fb160218a6374b87968ffde6615b6e2970ca9162ef542f877c3c8ab2023396c13e023cc47dd5bf466f22c SHA512 4e8fe0b1ab5302f975f58277e5ae42300a96d20bb1c41426d8c0e058a53420fcca73f75566f593f5aa2882b3a0e1608cdd542bc4f68c731153ba9185972d6f51
+DIST gitg-44.tar.xz 10629352 BLAKE2B 2c96b9e59ae04b8f9d760526007a564d7eda6bc2130b9e4970c55049da08e7a9f16c98bb8aa1a6d12e6baebc4b795a7947419cf9180b1f073cc79d9c54f83781 SHA512 3a5eadcd80aad42344adbe8783ba7e6d91dd5abe8343987e51db32db73205eb660d1c98bbfacbc6399a8c285fbd8ceb56ee87bc76569d45ca5c69bf1926e6bee
diff --git a/dev-vcs/gitg/gitg-44.ebuild b/dev-vcs/gitg/gitg-44.ebuild
new file mode 100644
index 000000000000..f25cedb16549
--- /dev/null
+++ b/dev-vcs/gitg/gitg-44.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+inherit gnome.org gnome2-utils meson python-r1 vala xdg
+
+DESCRIPTION="git repository viewer for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Gitg"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="glade +python"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+# test if unbundling of libgd is possible
+# Currently it seems not to be (unstable API/ABI)
+RDEPEND="
+	app-crypt/gpgme
+	app-crypt/libsecret[vala]
+	>=app-text/gspell-1[vala]
+	>=dev-libs/glib-2.38:2[dbus]
+	>=dev-libs/gobject-introspection-0.10.1:=
+	dev-libs/json-glib
+	dev-libs/libdazzle[vala]
+	dev-libs/libgee:0.8[introspection]
+	>=dev-libs/libgit2-glib-1.2.0[ssh]
+	dev-libs/libgit2:=[threads]
+	>=dev-libs/libpeas-1.5.0[gtk]
+	>=dev-libs/libxml2-2.9.0:2
+	>=gnome-base/gsettings-desktop-schemas-0.1.1
+	>=gui-libs/libhandy-1.5.0
+	>=x11-libs/gtk+-3.20.0:3
+	>=x11-libs/gtksourceview-4.0.3:4
+	x11-themes/adwaita-icon-theme
+	glade? ( >=dev-util/glade-3.2:3.10 )
+	python? (
+		${PYTHON_DEPS}
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}
+	>=dev-libs/libgit2-glib-1.0.0[vala]
+"
+BDEPEND="
+	>=sys-devel/gettext-0.19.7
+	virtual/pkgconfig
+	$(vala_depend)
+"
+
+src_prepare() {
+	default
+
+	# it doesn't do anything in DESTDIR mode, except for failing
+	# when python3 symlink is not present
+	echo "#!/bin/sh" > meson_post_install.py || die
+}
+
+src_configure() {
+	vala_setup
+
+	local emesonargs=(
+		$(meson_use glade glade_catalog)
+		# we install the module manually anyway
+		-Dpython=false
+	)
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use python ; then
+		python_moduleinto gi.overrides
+		python_foreach_impl python_domodule libgitg-ext/GitgExt.py
+	fi
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}