dev-util/include-what-you-use: bump up to 9.0

Package-Manager: Portage-2.3.78, Repoman-2.3.17
Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>

1 files changed, 55 insertions, 0 deletions

diff --git a/dev-util/include-what-you-use/include-what-you-use-9.0.ebuild b/dev-util/include-what-you-use/include-what-you-use-9.0.ebuild
new file mode 100644
index 000000000000..2b95d9035551
--- /dev/null
+++ b/dev-util/include-what-you-use/include-what-you-use-9.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6} )
+
+inherit cmake-utils flag-o-matic llvm python-single-r1
+
+DESCRIPTION="Find unused include directives in C/C++ programs"
+HOMEPAGE="https://include-what-you-use.org/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/clang_${PV}.tar.gz -> ${P}.src.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+LLVM_MAX_SLOT=9
+
+RDEPEND="sys-devel/llvm:${LLVM_MAX_SLOT}
+	sys-devel/clang:${LLVM_MAX_SLOT}
+	${PYTHON_DEPS}
+"
+DEPEND="${RDEPEND}"
+
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+S=${WORKDIR}/${PN}-clang_${PV}
+
+pkg_setup() {
+	llvm_pkg_setup
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	cmake-utils_src_prepare
+	python_fix_shebang .
+}
+
+src_configure() {
+	local mycmakeargs=(
+		# Note [llvm install path]
+		# Unfortunately all binaries using clang driver
+		# have to reside at the same path depth as
+		# 'clang' binary itself. See bug #625972
+		# Thus as a hack we install it to the same directory
+		# as llvm/clang itself.
+		-DCMAKE_INSTALL_PREFIX="$(get_llvm_prefix "${LLVM_MAX_SLOT}")"
+	)
+	cmake-utils_src_configure
+}
+
+src_test() {
+	"${EPYTHON}" run_iwyu_tests.py
+}