dev-util/buildbot: Version bump, clean oldest -0.8 release

Package-Manager: Portage-2.3.6, Repoman-2.3.1

4 files changed, 202 insertions, 99 deletions

diff --git a/dev-util/buildbot/Manifest b/dev-util/buildbot/Manifest
index a0e595b72df8..21102ff942a8 100644
--- a/dev-util/buildbot/Manifest
+++ b/dev-util/buildbot/Manifest
@@ -1,5 +1,5 @@
-DIST buildbot-0.8.10.tar.gz 4822307 SHA256 c4964d2ebd81cb80a14cb058fb2aab0572a1d8d86672d514e775b42deb08a5f4 SHA512 e148a1670a56837587d858d1697fe117661cbbfedab42bf7be905f9e8e4266e4ff0170b0cd81aed61234d30497a05427061c3084033f09811d0bc306b200661b WHIRLPOOL 26397b6f914266201aba4feb4df7353facad4fd0f51bdf7e35cf25205c45eadcf83f24c265e540b13d327750ce9561362be6a5aa237152cf1298d970c504f76c
 DIST buildbot-0.8.12.tar.gz 4834352 SHA256 c6b66976dff712268566574d57131ec15e5682f6d4390cd5c8559bab0980c4d6 SHA512 18c5144132fb033f3581d3c494d5e8ff35d3e8b1548764452ce9ae543d710e58a2c6e3e8e46a0ef237804f9a6a45485890ae4616ab655fb00d4ccf328d6f6645 WHIRLPOOL 5754b7c0278fb5e7da8a7dd66253f6f4d12f54c125f6a78aa9018a2b6b22fd88a27e79e6821ab05e4cd9e87bf0dd08c3c73c7914d4c499ac13c48ca232ed21c8
+DIST buildbot-0.9.10.tar.gz 3112750 SHA256 8c5ed75f3f16f4ff0f2c9e3f9b091acb5e6e1c0ef68ffa8f687a55413a833143 SHA512 95b489d5f7d0bc00ae5f71cd056b36fe689c4dc9408a7a0e4b1b45e036c9074832c8e3755981520a8c85a791b50f7f40765962c12a71887198dc0bbd0140d0e0 WHIRLPOOL 8d62d0aecdea4122709693ce48c72d5dbac2e946a6923a7ea41842dc759369a678e21a8abb0b4ff825e1ba559a9d490bcc4ff56fc5568a4f7f2d94b4f6c5f027
 DIST buildbot-0.9.4.docs.tar.xz 69224 SHA256 69fc33762a885568b02c42954a64d62d28bcb750b3aed011c3da8a9f84c13371 SHA512 906e551e0db32c8a0b4010b3b8b00c4776e3d1b7d7381e4dc0ccf01d361184e4605c3ab0ecaf4e42207bd73c3e72f8a570a4d4c29db72f4d68241abf48741d7e WHIRLPOOL 95f263e0b9ab22a649118f362d866b08cbdf62511f2a1f9bd6a7265103f174e35d0c8d86ad6a3b7dd5fd0b4277d60dbd25801c5e6f7e414e7fa634c241dae987
 DIST buildbot-0.9.4.tar.gz 3020851 SHA256 068161cd9ada10b87f40117c768a37ce796ebf5e7bf08f224f4c7ded88cd7472 SHA512 938a94192560b989a277d9650c50781d7e7c116bc5e2010ccb2e655df757de0ee254369531b2f432c835c0285c724e52d999a393d0ce1b104d4b9dcc5c6687da WHIRLPOOL 0ffe61b82ee93b78cdb3cb74ef96d5a3547e0fcab9ec8093b59a7212c5e2a1ad16eff046306bffcc0ea63b2e0bf2df1e54b5a0874dc78e27744db2088ccac804
 DIST buildbot-0.9.7.tar.gz 3092434 SHA256 8fcbf0e6536e5d60407f59d14f96d5f8386cd91846a4fa47b4336d71551a9e33 SHA512 3fd2b488cabac37e297bb1a475cdb115f261324a22ec4d6fbcf8dc5bfb6ee135fab3763998433be8795581d476f69e2adb6f42d248bf2131a42eecfc1667202a WHIRLPOOL 427d4c1c452f767550a3d2731b2e34480c399dcf50e57d4fb69f0a350f381e3e7ecc47d712fc8fbb99afcf8b230c7bd3afe8437ec3b24bf9ddbf7d35b4d1caad
diff --git a/dev-util/buildbot/buildbot-0.8.10.ebuild b/dev-util/buildbot/buildbot-0.8.10.ebuild
deleted file mode 100644
index 87e8bcf233e0..000000000000
--- a/dev-util/buildbot/buildbot-0.8.10.ebuild
+++ /dev/null
@@ -1,97 +0,0 @@
-# Copyright 1999-2017 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI="5"
-PYTHON_COMPAT=( python2_7 )
-PYTHON_REQ_USE="sqlite"
-
-inherit distutils-r1 readme.gentoo systemd user
-
-MY_PV="${PV/_p/p}"
-MY_P="${PN}-${MY_PV}"
-
-DESCRIPTION="BuildBot build automation system"
-HOMEPAGE="http://buildbot.net/ https://github.com/buildbot/buildbot https://pypi.python.org/pypi/buildbot"
-SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris"
-IUSE="doc examples irc mail manhole test"
-
-RDEPEND=">=dev-python/jinja-2.1[${PYTHON_USEDEP}]
-	dev-python/twisted-core[${PYTHON_USEDEP}]
-	dev-python/twisted-web[${PYTHON_USEDEP}]
-	<=dev-python/sqlalchemy-0.7.10-r999[${PYTHON_USEDEP}]
-	~dev-python/sqlalchemy-migrate-0.7.2[${PYTHON_USEDEP}]
-	irc? ( dev-python/twisted-words[${PYTHON_USEDEP}] )
-	mail? ( dev-python/twisted-mail[${PYTHON_USEDEP}] )
-	manhole? ( dev-python/twisted-conch[${PYTHON_USEDEP}] )"
-DEPEND="${DEPEND}
-	dev-python/setuptools[${PYTHON_USEDEP}]
-	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
-	test? (
-		dev-python/python-dateutil[${PYTHON_USEDEP}]
-		dev-python/mock[${PYTHON_USEDEP}]
-		dev-python/twisted-mail[${PYTHON_USEDEP}]
-		dev-python/twisted-web[${PYTHON_USEDEP}]
-		dev-python/twisted-words[${PYTHON_USEDEP}]
-	)"
-
-S="${WORKDIR}/${MY_P}"
-
-pkg_setup() {
-	enewuser buildbot
-
-	DOC_CONTENTS="The \"buildbot\" user and the \"buildmaster\" init script has been added
-		to support starting buildbot through Gentoo's init system. To use this,
-		set up your build master following the documentation, make sure the
-		resulting directories are owned by the \"buildbot\" user and point
-		\"${EROOT}etc/conf.d/buildmaster\" at the right location. The scripts can
-		run as a different user if desired. If you need to run more than one
-		build master, just copy the scripts."
-}
-
-src_compile() {
-	distutils-r1_src_compile
-
-	if use doc; then
-		einfo "Generation of documentation"
-		pushd docs > /dev/null
-		#'man' target is currently broken
-		emake html
-		popd > /dev/null
-	fi
-}
-
-src_install() {
-	distutils-r1_src_install
-
-	doman docs/buildbot.1
-
-	if use doc; then
-		dohtml -r docs/_build/html/
-		# TODO: install man pages
-	fi
-
-	if use examples; then
-		insinto /usr/share/doc/${PF}
-		doins -r contrib docs/examples
-	fi
-
-	newconfd "${FILESDIR}/buildmaster.confd" buildmaster
-	newinitd "${FILESDIR}/buildmaster.initd" buildmaster
-	systemd_dounit "${FILESDIR}"/${PN}.service
-
-	readme.gentoo_create_doc
-}
-
-pkg_postinst() {
-	readme.gentoo_print_elog
-	elog
-	elog "Upstream recommends the following when upgrading:"
-	elog "Each time you install a new version of Buildbot, you should run the"
-	elog "\"buildbot upgrade-master\" command on each of your pre-existing build masters."
-	elog "This will add files and fix (or at least detect) incompatibilities between"
-	elog "your old config and the new code."
-}
diff --git a/dev-util/buildbot/buildbot-0.9.10.ebuild b/dev-util/buildbot/buildbot-0.9.10.ebuild
new file mode 100644
index 000000000000..faf2365417b5
--- /dev/null
+++ b/dev-util/buildbot/buildbot-0.9.10.ebuild
@@ -0,0 +1,201 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="5"
+PYTHON_REQ_USE="sqlite"
+PYTHON_COMPAT=( python2_7 python3_5 )
+
+EGIT_REPO_URI="https://github.com/buildbot/${PN}.git"
+
+[[ ${PV} == *9999 ]] && inherit git-r3
+inherit readme.gentoo-r1 user systemd distutils-r1
+
+MY_PV="${PV/_p/.post}"
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="BuildBot build automation system"
+HOMEPAGE="https://buildbot.net/ https://github.com/buildbot/buildbot https://pypi.python.org/pypi/buildbot"
+[[ ${PV} == *9999 ]] || SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+if [[ ${PV} == *9999 ]]; then
+	KEYWORDS=""
+else
+	KEYWORDS="~amd64"
+fi
+
+IUSE="crypt doc examples irc test"
+
+RDEPEND="
+	>=dev-python/jinja-2.1[${PYTHON_USEDEP}]
+	>=dev-python/twisted-17.5.0[${PYTHON_USEDEP}]
+	>=dev-python/autobahn-0.16.0[${PYTHON_USEDEP}]
+	>=dev-python/sqlalchemy-0.8[${PYTHON_USEDEP}]
+	>=dev-python/sqlalchemy-migrate-0.9[${PYTHON_USEDEP}]
+	crypt? (
+		>=dev-python/twisted-17.5.0[${PYTHON_USEDEP},crypt]
+		>=dev-python/pyopenssl-16.0.0[${PYTHON_USEDEP}]
+		dev-python/idna[${PYTHON_USEDEP}]
+		dev-python/service_identity[${PYTHON_USEDEP}]
+	)
+	irc? (
+		dev-python/txrequests[${PYTHON_USEDEP}]
+	)
+	dev-python/future[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-1.5[${PYTHON_USEDEP}]
+	>=dev-python/txaio-2.2.2[${PYTHON_USEDEP}]
+	dev-python/pyjwt[${PYTHON_USEDEP}]
+	>=dev-python/zope-interface-4.1.1[${PYTHON_USEDEP}]
+	~dev-util/buildbot-worker-${PV}[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	>=dev-python/setuptools-21.2.1[${PYTHON_USEDEP}]
+	doc? (
+		>=dev-python/sphinx-1.4.3[${PYTHON_USEDEP}]
+		dev-python/sphinxcontrib-blockdiag[${PYTHON_USEDEP}]
+		dev-python/sphinxcontrib-spelling[${PYTHON_USEDEP}]
+		dev-python/pyenchant[${PYTHON_USEDEP}]
+		>=dev-python/docutils-0.8[${PYTHON_USEDEP}]
+		<dev-python/docutils-0.13.0[${PYTHON_USEDEP}]
+		dev-python/sphinx-jinja[${PYTHON_USEDEP}]
+		dev-python/ramlfications[${PYTHON_USEDEP}]
+	)
+	test? (
+		>=dev-python/python-dateutil-1.5[${PYTHON_USEDEP}]
+		>=dev-python/mock-2.0.0[${PYTHON_USEDEP}]
+		dev-python/moto[${PYTHON_USEDEP}]
+		dev-python/boto3[${PYTHON_USEDEP}]
+		dev-python/ramlfications[${PYTHON_USEDEP}]
+		dev-python/pyjade[${PYTHON_USEDEP}]
+		dev-python/txgithub[${PYTHON_USEDEP}]
+		dev-python/txrequests[${PYTHON_USEDEP}]
+		dev-python/lz4[${PYTHON_USEDEP}]
+		dev-python/treq[${PYTHON_USEDEP}]
+		dev-python/setuptools_trial[${PYTHON_USEDEP}]
+		~dev-util/buildbot-worker-${PV}[${PYTHON_USEDEP}]
+	)"
+
+S=${WORKDIR}/${MY_P}
+[[ ${PV} == *9999 ]] && S=${S}/master
+
+pkg_setup() {
+	enewuser buildbot
+
+	DOC_CONTENTS="The \"buildbot\" user and the \"buildmaster\" init script has been added
+		to support starting buildbot through Gentoo's init system. To use this,
+		execute \"emerge --config =${CATEGORY}/${PF}\" to create a new instance.
+		The scripts can	run as a different user if desired."
+}
+
+python_prepare_all() {
+	# Disable distribution version test.
+	sed \
+		-e 's/self.assertNotIn("unknown", distro\[1\])//' \
+		-i buildbot/test/unit/test_buildbot_net_usage_data.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+src_compile() {
+	distutils-r1_src_compile
+
+	if use doc; then
+		einfo "Generation of documentation"
+		pushd docs > /dev/null
+		#'man' target is currently broken
+		emake html
+		popd > /dev/null
+	fi
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	doman docs/buildbot.1
+
+	if use doc; then
+		dohtml -r docs/_build/html/
+		# TODO: install man pages
+	fi
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		doins -r contrib docs/examples
+	fi
+
+	newconfd "${FILESDIR}/buildmaster.confd" buildmaster
+	newinitd "${FILESDIR}/buildmaster.initd" buildmaster
+	systemd_dounit "${FILESDIR}/buildmaster.target"
+	systemd_newunit "${FILESDIR}/buildmaster_at.service" "buildmaster@.service"
+	systemd_install_serviced "${FILESDIR}/buildmaster_at.service.conf" "buildmaster@.service"
+
+	readme.gentoo_create_doc
+}
+
+python_test() {
+	distutils_install_for_testing
+
+	esetup.py test || die "Tests failed under ${EPYTHON}"
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+
+	if [[ -n ${REPLACING_VERSIONS} ]]; then
+		ewarn
+		ewarn "Starting with buildbot-0.8.12-r2, more than one instance of buildmaster"
+		ewarn "can be run simultaneously. Note that \"BASEDIR\" in the buildbot configuration file"
+		ewarn "is now the common base directory for all instances. If you are migrating from an older"
+		ewarn "version, make sure that you copy the current contents of \"BASEDIR\" to a subdirectory."
+		ewarn "The name of the subdirectory corresponds to the name of the buildmaster instance."
+		ewarn "In order to start the service running OpenRC-based systems need to link to the init file:"
+		ewarn "    ln --symbolic --relative /etc/init.d/buildmaster /etc/init.d/buildmaster.myinstance"
+		ewarn "    rc-update add buildmaster.myinstance default"
+		ewarn "    /etc/init.d/buildmaster.myinstance start"
+		ewarn "Systems using systemd can do the following:"
+		ewarn "    systemctl enable buildmaster@myinstance.service"
+		ewarn "    systemctl enable buildmaster.target"
+		ewarn "    systemctl start buildmaster.target"
+		elog
+		elog "Upstream recommends the following when upgrading:"
+		elog "Each time you install a new version of Buildbot, you should run the"
+		elog "\"buildbot upgrade-master\" command on each of your pre-existing build masters."
+		elog "This will add files and fix (or at least detect) incompatibilities between"
+		elog "your old config and the new code."
+	fi
+	elog
+	elog "In order to create a new instance of buildmaster, execute:"
+	elog "    emerge --config =${CATEGORY}/${PF}"
+}
+
+pkg_config() {
+	local buildmaster_path="/var/lib/buildmaster"
+	einfo "This will prepare a new buildmaster instance in ${buildmaster_path}."
+	einfo "Press Control-C to abort."
+
+	einfo "Enter the name for the new instance: "
+	read instance_name
+	[[ -z "${instance_name}" ]] && die "Invalid instance name"
+
+	local instance_path="${buildmaster_path}/${instance_name}"
+	if [[ -e "${instance_path}" ]]; then
+		eerror "The instance with the specified name already exists:"
+		eerror "${instance_path}"
+		die "Instance already exists"
+	fi
+
+	local buildbot="/usr/bin/buildbot"
+	if [[ ! -d "${buildmaster_path}" ]]; then
+		mkdir --parents "${buildmaster_path}" || die "Unable to create directory ${buildmaster_path}"
+	fi
+	"${buildbot}" create-master "${instance_path}" &>/dev/null || die "Creating instance failed"
+	chown --recursive buildbot "${instance_path}" || die "Setting permissions for instance failed"
+	mv "${instance_path}/master.cfg.sample" "${instance_path}/master.cfg" \
+		|| die "Moving sample configuration failed"
+	ln --symbolic --relative "/etc/init.d/buildmaster" "/etc/init.d/buildmaster.${instance_name}" \
+		|| die "Unable to create link to init file"
+
+	einfo "Successfully created a buildmaster instance at ${instance_path}."
+	einfo "To change the default settings edit the master.cfg file in this directory."
+}
diff --git a/dev-util/buildbot/buildbot-9999.ebuild b/dev-util/buildbot/buildbot-9999.ebuild
index ed83f8319940..d3239e23f64f 100644
--- a/dev-util/buildbot/buildbot-9999.ebuild
+++ b/dev-util/buildbot/buildbot-9999.ebuild
@@ -46,7 +46,6 @@ RDEPEND="
 	>=dev-python/python-dateutil-1.5[${PYTHON_USEDEP}]
 	>=dev-python/txaio-2.2.2[${PYTHON_USEDEP}]
 	dev-python/pyjwt[${PYTHON_USEDEP}]
-	dev-python/distro[${PYTHON_USEDEP}]
 	>=dev-python/zope-interface-4.1.1[${PYTHON_USEDEP}]
 	~dev-util/buildbot-worker-${PV}[${PYTHON_USEDEP}]
 "