dev-qt: Switch USE xcb -> X

Closes: https://bugs.gentoo.org/705440
Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

4 files changed, 310 insertions, 0 deletions

diff --git a/dev-qt/qtgui/qtgui-5.14.0-r3.ebuild b/dev-qt/qtgui/qtgui-5.14.0-r3.ebuild
new file mode 100644
index 000000000000..8ab48c846dd5
--- /dev/null
+++ b/dev-qt/qtgui/qtgui-5.14.0-r3.ebuild
@@ -0,0 +1,188 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+QT5_MODULE="qtbase"
+inherit qt5-build
+
+DESCRIPTION="The GUI module and platform plugins for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+fi
+
+# TODO: linuxfb
+
+IUSE="accessibility dbus egl eglfs evdev +gif gles2 ibus
+	jpeg +libinput +png tslib tuio +udev vnc wayland +X"
+REQUIRED_USE="
+	|| ( eglfs X )
+	accessibility? ( dbus X )
+	eglfs? ( egl )
+	ibus? ( dbus )
+	libinput? ( udev )
+	X? ( gles2? ( egl ) )
+"
+
+COMMON_DEPEND="
+	dev-libs/glib:2
+	~dev-qt/qtcore-${PV}
+	dev-util/gtk-update-icon-cache
+	media-libs/fontconfig
+	>=media-libs/freetype-2.6.1:2
+	>=media-libs/harfbuzz-1.6.0:=
+	sys-libs/zlib:=
+	virtual/opengl
+	dbus? ( ~dev-qt/qtdbus-${PV} )
+	egl? ( media-libs/mesa[egl] )
+	eglfs? (
+		media-libs/mesa[gbm]
+		x11-libs/libdrm
+	)
+	evdev? ( sys-libs/mtdev )
+	gles2? ( media-libs/mesa[gles2] )
+	jpeg? ( virtual/jpeg:0 )
+	libinput? (
+		dev-libs/libinput:=
+		>=x11-libs/libxkbcommon-0.5.0
+	)
+	png? ( media-libs/libpng:0= )
+	tslib? ( >=x11-libs/tslib-1.21 )
+	tuio? ( ~dev-qt/qtnetwork-${PV} )
+	udev? ( virtual/libudev:= )
+	vnc? ( ~dev-qt/qtnetwork-${PV} )
+	X? (
+		x11-libs/libICE
+		x11-libs/libSM
+		x11-libs/libX11
+		>=x11-libs/libxcb-1.12:=[xkb]
+		>=x11-libs/libxkbcommon-0.5.0[X]
+		x11-libs/xcb-util-image
+		x11-libs/xcb-util-keysyms
+		x11-libs/xcb-util-renderutil
+		x11-libs/xcb-util-wm
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	evdev? ( sys-kernel/linux-headers )
+	udev? ( sys-kernel/linux-headers )
+"
+# bug 703306, _populate_Gui_plugin_properties breaks installed cmake modules
+RDEPEND="${COMMON_DEPEND}
+	!<dev-qt/qtimageformats-5.14.0:5
+	!<dev-qt/qtsvg-5.14.0:5
+	!<dev-qt/qtvirtualkeyboard-5.14.0:5
+	!<dev-qt/qtwayland-5.14.0:5
+"
+PDEPEND="
+	ibus? ( app-i18n/ibus )
+	wayland? ( ~dev-qt/qtwayland-${PV} )
+"
+
+QT5_TARGET_SUBDIRS=(
+	src/tools/qvkgen
+	src/gui
+	src/openglextensions
+	src/platformheaders
+	src/platformsupport
+	src/plugins/generic
+	src/plugins/imageformats
+	src/plugins/platforms
+	src/plugins/platforminputcontexts
+)
+
+QT5_GENTOO_CONFIG=(
+	accessibility:accessibility-atspi-bridge
+	egl:egl:
+	eglfs:eglfs:
+	eglfs:eglfs_egldevice:
+	eglfs:eglfs_gbm:
+	evdev:evdev:
+	evdev:mtdev:
+	:fontconfig:
+	:system-freetype:FREETYPE
+	!:no-freetype:
+	!gif:no-gif:
+	gles2::OPENGL_ES
+	gles2:opengles2:OPENGL_ES_2
+	!:no-gui:
+	:system-harfbuzz:
+	!:no-harfbuzz:
+	jpeg:system-jpeg:IMAGEFORMAT_JPEG
+	!jpeg:no-jpeg:
+	libinput
+	libinput:xkbcommon:
+	:opengl
+	png:png:
+	png:system-png:IMAGEFORMAT_PNG
+	!png:no-png:
+	tslib:tslib:
+	udev:libudev:
+	X:xcb:
+	X:xcb-glx:
+	X:xcb-plugin:
+	X:xcb-render:
+	X:xcb-sm:
+	X:xcb-xlib:
+	X:xcb-xinput:
+)
+
+QT5_GENTOO_PRIVATE_CONFIG=(
+	:gui
+)
+
+PATCHES=(
+	"${FILESDIR}/qt-5.12-gcc-avx2.patch" # bug 672946
+	"${FILESDIR}/${PN}-5.13.2-no-xcb-no-xkbcommon.patch" # bug 699110
+	"${FILESDIR}/${P}-restore-scaling.patch" # QTBUG-80967, in Qt 5.14.1
+)
+
+src_prepare() {
+	# don't add -O3 to CXXFLAGS, bug 549140
+	sed -i -e '/CONFIG\s*+=/s/optimize_full//' src/gui/gui.pro || die
+
+	# egl_x11 is activated when both egl and X are enabled
+	use egl && QT5_GENTOO_CONFIG+=(X:egl_x11:) || QT5_GENTOO_CONFIG+=(egl:egl_x11:)
+
+	qt_use_disable_config dbus dbus \
+		src/platformsupport/themes/genericunix/genericunix.pri
+
+	qt_use_disable_config tuio tuiotouch src/plugins/generic/generic.pro
+
+	qt_use_disable_mod ibus dbus \
+		src/plugins/platforminputcontexts/platforminputcontexts.pro
+
+	use vnc || sed -i -e '/SUBDIRS += vnc/d' \
+		src/plugins/platforms/platforms.pro || die
+
+	qt5-build_src_prepare
+}
+
+src_configure() {
+	local myconf=(
+		$(usex dbus -dbus-linked '')
+		$(qt_use egl)
+		$(qt_use eglfs)
+		$(usex eglfs '-gbm -kms' '')
+		$(qt_use evdev)
+		$(qt_use evdev mtdev)
+		-fontconfig
+		-system-freetype
+		$(usex gif '' -no-gif)
+		-gui
+		-system-harfbuzz
+		$(qt_use jpeg libjpeg system)
+		$(qt_use libinput)
+		-opengl $(usex gles2 es2 desktop)
+		$(qt_use png libpng system)
+		$(qt_use tslib)
+		$(qt_use udev libudev)
+		$(qt_use X xcb system)
+		$(usex X '-xcb-xlib -xcb-xinput -xkb' '')
+	)
+	if use libinput || use X; then
+		myconf+=( -xkbcommon )
+	fi
+	qt5-build_src_configure
+}
diff --git a/dev-qt/qtvirtualkeyboard/qtvirtualkeyboard-5.14.0-r1.ebuild b/dev-qt/qtvirtualkeyboard/qtvirtualkeyboard-5.14.0-r1.ebuild
new file mode 100644
index 000000000000..36d34ee4fe23
--- /dev/null
+++ b/dev-qt/qtvirtualkeyboard/qtvirtualkeyboard-5.14.0-r1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit qt5-build
+
+DESCRIPTION="Customizable input framework and virtual keyboard for Qt"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+# TODO: unbudle libraries for more layouts
+IUSE="handwriting +spell +X"
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtdeclarative-${PV}
+	~dev-qt/qtgui-${PV}
+	~dev-qt/qtsvg-${PV}
+	spell? ( app-text/hunspell:= )
+	X? ( x11-libs/libxcb:= )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local myqmakeargs=(
+		$(usex handwriting CONFIG+=lipi-toolkit '')
+		$(usex spell '' CONFIG+=disable-hunspell)
+		$(usex X '' CONFIG+=disable-desktop)
+		CONFIG+="lang-ar_AR lang-bg_BG lang-cs_CZ lang-da_DK lang-de_DE \
+			lang-el_GR lang-en_GB lang-en_US lang-es_ES lang-es_MX \
+			lang-et_EE lang-fa_FA lang-fi_FI lang-fr_CA lang-fr_FR \
+			lang-he_IL lang-hi_IN lang-hr_HR lang-hu_HU lang-id_ID \
+			lang-it_IT lang-ms_MY lang-nb_NO lang-nl_NL lang-pl_PL \
+			lang-pt_BR lang-pt_PT lang-ro_RO lang-ru_RU lang-sk_SK \
+			lang-sl_SI lang-sq_AL lang-sr_SP lang-sv_SE lang-tr_TR \
+			lang-uk_UA lang-vi_VN"
+	)
+
+	qt5-build_src_configure
+}
diff --git a/dev-qt/qtwidgets/qtwidgets-5.14.0-r1.ebuild b/dev-qt/qtwidgets/qtwidgets-5.14.0-r1.ebuild
new file mode 100644
index 000000000000..3d14a9cd5446
--- /dev/null
+++ b/dev-qt/qtwidgets/qtwidgets-5.14.0-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+QT5_MODULE="qtbase"
+inherit qt5-build
+
+DESCRIPTION="Set of components for creating classic desktop-style UIs for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+fi
+
+# keep IUSE defaults in sync with qtgui
+IUSE="gles2 gtk +png +X"
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtgui-${PV}[gles2=,png=,X?]
+	gtk? (
+		~dev-qt/qtgui-${PV}[dbus]
+		x11-libs/gtk+:3
+		x11-libs/libX11
+		x11-libs/pango
+	)
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+	src/tools/uic
+	src/widgets
+	src/plugins/platformthemes
+)
+
+QT5_GENTOO_CONFIG=(
+	gtk:gtk3:
+	::widgets
+	!:no-widgets:
+)
+
+QT5_GENTOO_PRIVATE_CONFIG=(
+	:widgets
+)
+
+src_configure() {
+	local myconf=(
+		-opengl $(usex gles2 es2 desktop)
+		$(qt_use gtk)
+		-gui
+		$(qt_use png libpng system)
+		-widgets
+		$(qt_use X xcb system)
+		$(usex X '-xcb-xlib -xcb-xinput -xkb -xkbcommon' '')
+	)
+	qt5-build_src_configure
+}
diff --git a/dev-qt/qtx11extras/qtx11extras-5.14.0-r1.ebuild b/dev-qt/qtx11extras/qtx11extras-5.14.0-r1.ebuild
new file mode 100644
index 000000000000..32aefe9b955d
--- /dev/null
+++ b/dev-qt/qtx11extras/qtx11extras-5.14.0-r1.ebuild
@@ -0,0 +1,22 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit qt5-build
+
+DESCRIPTION="Linux/X11-specific support library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+fi
+
+IUSE=""
+
+RDEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtgui-${PV}[X]
+"
+DEPEND="${RDEPEND}
+	test? ( ~dev-qt/qtwidgets-${PV} )
+"