dev-python/kombu: 4.6.8 bump

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Matthew Thode <prometheanfire@gentoo.org>

2 files changed, 81 insertions, 0 deletions

diff --git a/dev-python/kombu/Manifest b/dev-python/kombu/Manifest
index 1c7ad368f805..44ab0f2816b9 100644
--- a/dev-python/kombu/Manifest
+++ b/dev-python/kombu/Manifest
@@ -1 +1,2 @@
 DIST kombu-4.6.3.tar.gz 427754 BLAKE2B 0db078eb8d6afd18a5e9b48c970791d2c55c46f5f705e8e0737c8685c2415e1ca974594377a54764f744cc73ff607668ece3c0999b1a7dad6a259567ac1fd319 SHA512 35113c4f19fe6bf94c374477c89a629f565975a23c16a3cedefa8e0c2a800cabbaa8917d48f732cf28e89cd5430fe8408a3514e055b1858c216b6ea31b4c014a
+DIST kombu-4.6.8.tar.gz 406196 BLAKE2B 43ddb45e7e6a5bc1aff55867a816ebf7a1afed68bd41d9d74b6179a45d951ac4a4f0f687bbaebd23cf81b67fe2b81d47498b3e25eead0822e16d9acbb436338a SHA512 65b4ebb283ae380388de5d9f8fdc1ec0f41a9910744906b23eb150bc62ecb55ae6d65bb96ad31d8a033f26c2a8dc386939fced393866b6467e77a9760dfa17cc
diff --git a/dev-python/kombu/kombu-4.6.8.ebuild b/dev-python/kombu/kombu-4.6.8.ebuild
new file mode 100644
index 000000000000..838b1c73c56d
--- /dev/null
+++ b/dev-python/kombu/kombu-4.6.8.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit distutils-r1
+
+DESCRIPTION="AMQP Messaging Framework for Python"
+HOMEPAGE="https://pypi.org/project/kombu/ https://github.com/celery/kombu"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc examples mongodb msgpack redis sqs test yaml"
+RESTRICT="!test? ( test )"
+
+# zookeeper backend support possible via dev-python/kazoo
+RDEPEND="
+	>=dev-python/importlib_metadata-0.18[${PYTHON_USEDEP}]
+	>=dev-python/py-amqp-2.5.2[${PYTHON_USEDEP}]
+	<dev-python/py-amqp-2.6[${PYTHON_USEDEP}]
+	>=dev-python/pyro-4.76:4[${PYTHON_USEDEP}]
+	sqs? ( >=dev-python/boto3-1.4.4[${PYTHON_USEDEP}] )
+	msgpack? ( >=dev-python/msgpack-0.3.0[${PYTHON_USEDEP}] )
+	mongodb? ( >=dev-python/pymongo-3.3.0[${PYTHON_USEDEP}] )
+	redis? ( >=dev-python/redis-py-3.3.11[${PYTHON_USEDEP}] )
+	yaml? ( >=dev-python/pyyaml-3.10[${PYTHON_USEDEP}] )"
+# Fix to https://github.com/celery/kombu/issues/474 obliges dev-python/pymongo to >=-3.0.2
+DEPEND="${RDEPEND}
+	>=dev-python/setuptools-20.6.7[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/case-1.5.2[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		dev-python/unittest2[${PYTHON_USEDEP}] )
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		>=dev-python/sphinx_celery-1.1[${PYTHON_USEDEP}] )"
+
+# kazoo is optional for tests.
+# Refrain for now, no established demand for it from users
+
+# Req'd for test phase
+DISTUTILS_IN_SOURCE_BUILD=1
+
+PATCHES=(
+)
+
+python_prepare_all() {
+	# AttributeError: test_Etcd instance has no attribute 'patch'
+	rm t/unit/transport/test_etcd.py || die
+	# allow use of new (renamed) msgpack
+	sed -i '/msgpack/d' requirements/extras/msgpack.txt || die
+	# pytest-sugar is not packaged
+	sed -i '/pytest-sugar/d' requirements/test.txt || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	# Doc build misses and skips only content re librabbitmq which is not in portage
+	if use doc; then
+		emake -C docs html
+	fi
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		docinto examples
+		dodoc -r examples/.
+	fi
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}