dev-python/pytest-bdd: use pep517

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

1 files changed, 39 insertions, 0 deletions

diff --git a/dev-python/pytest-bdd/pytest-bdd-5.0.0-r1.ebuild b/dev-python/pytest-bdd/pytest-bdd-5.0.0-r1.ebuild
new file mode 100644
index 000000000000..04e0d86ca1de
--- /dev/null
+++ b/dev-python/pytest-bdd/pytest-bdd-5.0.0-r1.ebuild
@@ -0,0 +1,39 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1
+
+DESCRIPTION="BDD library for the pytest runner"
+HOMEPAGE="https://pypi.org/project/pytest-bdd/"
+SRC_URI="https://github.com/pytest-dev/pytest-bdd/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/glob2[${PYTHON_USEDEP}]
+	dev-python/mako[${PYTHON_USEDEP}]
+	dev-python/parse[${PYTHON_USEDEP}]
+	dev-python/parse_type[${PYTHON_USEDEP}]
+	dev-python/py[${PYTHON_USEDEP}]"
+BDEPEND="dev-python/packaging[${PYTHON_USEDEP}]"
+
+distutils_enable_tests pytest
+
+DOCS=( AUTHORS.rst CHANGES.rst README.rst )
+
+src_test() {
+	# terminal_reporter test needs exact wrapping
+	local -x COLUMNS=80
+
+	# hooks output parsing may be affected by other pytest-*, e.g. tornasync
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=pytest_bdd.plugin
+
+	distutils-r1_src_test
+}