dev-python/zope-component: EAPI 8, PEP517, tests, no namespace

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 60 insertions, 0 deletions

diff --git a/dev-python/zope-component/zope-component-4.4.1-r1.ebuild b/dev-python/zope-component/zope-component-4.4.1-r1.ebuild
new file mode 100644
index 000000000000..60d792a5516d
--- /dev/null
+++ b/dev-python/zope-component/zope-component-4.4.1-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+MY_PN=zope.component
+MY_P=${MY_PN}-${PV}
+DESCRIPTION="Zope Component Architecture"
+HOMEPAGE="
+	https://pypi.org/project/zope.component/
+	https://github.com/zopefoundation/zope.component/
+	https://docs.zope.org/zope.component/
+"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="ZPL"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+RDEPEND="
+	dev-python/zope-event[${PYTHON_USEDEP}]
+	>=dev-python/zope-interface-4.1.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/zope-configuration[${PYTHON_USEDEP}]
+		dev-python/zope-i18nmessageid[${PYTHON_USEDEP}]
+		dev-python/zope-testing[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# strip rdep specific to namespaces
+	sed -i -e "/'setuptools'/d" setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	# this is needed to keep the tests working while
+	# dev-python/namespace-zope is still installed
+	cat > zope/__init__.py <<-EOF || die
+		__path__ = __import__('pkgutil').extend_path(__path__, __name__)
+	EOF
+	eunittest
+	rm zope/__init__.py || die
+}