dev-python/pyatspi: Version bump

Package-Manager: portage-2.3.0_rc1

1 files changed, 57 insertions, 0 deletions

diff --git a/dev-python/pyatspi/pyatspi-2.20.2.ebuild b/dev-python/pyatspi/pyatspi-2.20.2.ebuild
new file mode 100644
index 000000000000..d7e2f8e8007b
--- /dev/null
+++ b/dev-python/pyatspi/pyatspi-2.20.2.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_3,3_4,3_5} )
+
+inherit gnome2 python-r1
+
+DESCRIPTION="Python binding to at-spi library"
+HOMEPAGE="https://wiki.gnome.org/Accessibility"
+
+# Note: only some of the tests are GPL-licensed, everything else is LGPL
+LICENSE="LGPL-2 GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="" # test
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="${PYTHON_DEPS}
+	>=dev-libs/atk-2.11.2
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	>=dev-python/pygobject-2.90.1:3[${PYTHON_USEDEP}]
+"
+RDEPEND="${COMMON_DEPEND}
+	>=sys-apps/dbus-1
+	>=app-accessibility/at-spi2-core-${PV}[introspection]
+	!<gnome-extra/at-spi-1.32.0-r1
+"
+DEPEND="${COMMON_DEPEND}
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	# https://bugzilla.gnome.org/show_bug.cgi?id=689957
+	"${FILESDIR}/${PN}-2.6.0-examples-python3.patch"
+)
+
+src_prepare() {
+	gnome2_src_prepare
+	python_copy_sources
+}
+
+src_configure() {
+	python_foreach_impl run_in_build_dir gnome2_src_configure --disable-tests
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir gnome2_src_compile
+}
+
+src_install() {
+	python_foreach_impl run_in_build_dir gnome2_src_install
+
+	docinto examples
+	dodoc examples/*.py
+}