dev-python/oct2py: version bump, dropping arm and ppc64 because of octave_kernel

Package-Manager: Portage-2.3.7, Repoman-2.3.3

2 files changed, 55 insertions, 0 deletions

diff --git a/dev-python/oct2py/Manifest b/dev-python/oct2py/Manifest
index cf3f0d6afb96..192bb65d8d7b 100644
--- a/dev-python/oct2py/Manifest
+++ b/dev-python/oct2py/Manifest
@@ -1 +1,2 @@
 DIST oct2py-3.6.0.tar.gz 668836 SHA256 b356daf63a80c778fcf81b380c187863b86e9aae88f8321bb543c5512835c69f SHA512 f414a0231665bc3bedb7dcdaab8c86f32c140e5107ef80b70e2f99467e737d033de6ff492f2af7233671bff9b148475e0af4881c073ac727d0fd1228b7cf59b6 WHIRLPOOL 498b69f6292fe60b1035ea8ef587b3dc7b49fb4353bf31ce5f19ca3afc74a3b4bdcff7700d77d6bd8e6bf079c590114fee1c2f0352127745d162fc3f6be9b3b9
+DIST oct2py-4.0.6.tar.gz 431738 SHA256 07cbcee467f6bd7bd2430d2ae270fcc035acf2c8ad35f6ad9bb6f7b0f915e179 SHA512 997ca843571d2d68c4c57c0213a525c1be5f8b3e3dbffffb6cd41e423d68c8836dd12a03d5210d7f0cbf8ff19be7bb9d25b48c62a236cae68a0762547e574caa WHIRLPOOL b824f9c21665a70e21e614022ccca7e05032f59d5fd5b1993b31f16dcd9d4d5cf2dfc948873df5ab9234b095d7b188867eac5ab4ee238c046131c0e042e3bb5e
diff --git a/dev-python/oct2py/oct2py-4.0.6.ebuild b/dev-python/oct2py/oct2py-4.0.6.ebuild
new file mode 100644
index 000000000000..cafb9f92a0ff
--- /dev/null
+++ b/dev-python/oct2py/oct2py-4.0.6.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python to GNU Octave bridge"
+HOMEPAGE="http://blink1073.github.io/oct2py/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples test"
+
+RDEPEND="
+	>=dev-python/numpy-1.11[${PYTHON_USEDEP}]
+	dev-python/octave_kernel[${PYTHON_USEDEP}]
+	>=sci-libs/scipy-0.17[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	doc? (
+		dev-python/numpydoc[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/sphinx-bootstrap-theme[${PYTHON_USEDEP}]
+	)
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/ipython[${PYTHON_USEDEP}]
+	)
+"
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs html || die
+		HTML_DOCS=( html/. )
+	fi
+}
+
+python_test() {
+	cd "${BUILD_DIR}/lib" || die
+	py.test -v -v || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if use examples; then
+		docinto examples
+		dodoc -r example/.
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}