proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 71 insertions, 0 deletions

diff --git a/dev-python/networkx/networkx-1.9.1.ebuild b/dev-python/networkx/networkx-1.9.1.ebuild
new file mode 100644
index 000000000000..7957bc3bb3d7
--- /dev/null
+++ b/dev-python/networkx/networkx-1.9.1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python tools to manipulate graphs and complex networks"
+HOMEPAGE="http://networkx.github.io/ https://github.com/networkx/networkx"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 ppc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="doc examples test"
+
+COMMON_DEPEND="dev-python/matplotlib[${PYTHON_USEDEP}]
+		sci-libs/scipy[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/numpydoc[${PYTHON_USEDEP}]' python2_7)
+		$(python_gen_cond_dep 'dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]' python2_7 python{3_3,3_4})
+	)
+	test? (
+		${COMMON_DEPEND}
+		dev-python/nose[${PYTHON_USEDEP}]
+	)"
+RDEPEND="
+	>=dev-python/decorator-3.4.0[${PYTHON_USEDEP}]
+	examples? (
+		${COMMON_DEPEND}
+		$(python_gen_cond_dep 'dev-python/pygraphviz[${PYTHON_USEDEP}]' python2_7)
+		dev-python/pyparsing[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+	)"
+
+python_prepare_all() {
+	# Avoid d'loading of file objects.inv from 2 sites of python docs
+	sed -e "s/'sphinx.ext.intersphinx', //" -i doc/source/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	# https://github.com/networkx/networkx/issues/1263
+	if use doc; then
+		sed \
+			-e "s:^\t\./:\t${PYTHON} :g" \
+			-i doc/Makefile || die
+		emake -C doc html
+	fi
+}
+
+python_test() {
+	nosetests -vv || die
+}
+
+python_install_all() {
+	# Oh my.
+	rm -r "${ED}"usr/share/doc/${P} || die
+
+	use doc && local HTML_DOCS=( doc/build/html/. )
+	use examples && local EXAMPLES=( examples/. )
+
+	distutils-r1_python_install_all
+}