dev-python/ginga: initial import

Package-Manager: portage-2.3.3

4 files changed, 119 insertions, 0 deletions

diff --git a/dev-python/ginga/Manifest b/dev-python/ginga/Manifest
new file mode 100644
index 000000000000..d3557700e2ca
--- /dev/null
+++ b/dev-python/ginga/Manifest
@@ -0,0 +1 @@
+DIST ginga-2.6.0.tar.gz 12682426 SHA256 ae4661cc2438cafcd66281172776e6968255482d122a154030bc815c19e0afd4 SHA512 b07fc8a20f17173682bfce5190200f3080dff12fae73e06e1447ebdfe1dc98362e03bd2ed5c524fce0ffcd15e3b74170c97a74222f7601f25e9e5bf0bd93148a WHIRLPOOL 430f9e0585f1b4546400ca9ba89eda1a81d88fd62ebade5d907d069f3f19e6155d7b7c8bdaa9186ba306873a1d41f7cfb64ed5f2262a96eb1c5e06f4a1027d82
diff --git a/dev-python/ginga/files/ginga-no-roboto.patch b/dev-python/ginga/files/ginga-no-roboto.patch
new file mode 100644
index 000000000000..36b222fea5e2
--- /dev/null
+++ b/dev-python/ginga/files/ginga-no-roboto.patch
@@ -0,0 +1,19 @@
+From: Ole Streicher <olebole@debian.org>
+Date: Tue, 2 Aug 2016 09:06:36 +0200
+Subject: Don't install the fonts included in the package.
+
+Use the package roboto-fonts-unhinted instead.
+---
+ ginga/fonts/setup_package.py | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/ginga/fonts/setup_package.py b/ginga/fonts/setup_package.py
+index 9dd1e93..fe0ed0a 100644
+--- a/ginga/fonts/setup_package.py
++++ b/ginga/fonts/setup_package.py
+@@ -3,4 +3,4 @@ from __future__ import absolute_import
+ 
+ 
+ def get_package_data():
+-    return {'ginga.fonts': ['*/*.ttf', '*/*.txt']}
++    return {}
diff --git a/dev-python/ginga/ginga-2.6.0.ebuild b/dev-python/ginga/ginga-2.6.0.ebuild
new file mode 100644
index 000000000000..249b5fa5fc74
--- /dev/null
+++ b/dev-python/ginga/ginga-2.6.0.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_5} )
+PYTHON_REQ_USE='tk?'
+
+inherit distutils-r1 eutils fdo-mime
+
+DESCRIPTION="Astronomical image toolkit for Python"
+HOMEPAGE="https://ejeschke.github.io/ginga"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="doc examples gtk qt4 qt5 test tk"
+
+RDEPEND="
+	dev-python/astropy[${PYTHON_USEDEP}]
+	media-fonts/roboto
+	gtk? (  dev-python/pygobject[${PYTHON_USEDEP},cairo] )
+	qt4? ( || (
+		  dev-python/pyside[${PYTHON_USEDEP},help,X]
+		  dev-python/PyQt4[${PYTHON_USEDEP},help,X]
+	   ) )
+	qt5? (  dev-python/PyQt5[${PYTHON_USEDEP},help,gui,widgets] )"
+
+DEPEND="${RDEPEND}
+	dev-python/astropy-helpers[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+PATCHES=( "${FILESDIR}"/${PN}-no-roboto.patch )
+
+python_prepare_all() {
+	# use system astropy-helpers instead of bundled one
+	sed -i -e '/auto_use/s/True/False/' setup.cfg || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		python_setup
+		PYTHONPATH="${BUILD_DIR}"/lib esetup.py build_sphinx --no-intersphinx
+	fi
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/_build/html/. )
+	distutils-r1_python_install_all
+	rm -r "${ED%/}"/usr/lib*/*/*/ginga/examples || die
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		doins -r ginga/examples
+	fi
+	domenu ginga.desktop
+}
+
+pkg_postinst() {
+	optfeature "Pick, Cuts, Histogram, LineProfile" \
+			   dev-python/matplotlib sci-libs/scipy
+	optfeature "Online help browser" dev-qt/qtwebkit
+	optfeature "To save a movie" media-video/mplayer
+	optfeature "Speeds up rotation and some transformations" \
+			   dev-python/numexpr dev-python/opencv dev-python/pyopencl
+	optfeature "Aids in identifying files when opening them" \
+			   dev-python/filemagic
+	optfeature "Useful for various RGB file manipulations" dev-python/pillow
+
+	# Update mimedb for the new .desktop file
+	fdo-mime_desktop_database_update
+}
diff --git a/dev-python/ginga/metadata.xml b/dev-python/ginga/metadata.xml
new file mode 100644
index 000000000000..9b4ee82bcef3
--- /dev/null
+++ b/dev-python/ginga/metadata.xml
@@ -0,0 +1,20 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>sci-astronomy@gentoo.org</email>
+    <name>Gentoo Astronomy Project</name>
+  </maintainer>
+  <longdescription lang="en">
+    Ginga is a toolkit designed for building viewers for scientific image
+    data in Python, visualizing 2D pixel data in numpy arrays.
+    It can view astronomical data such as contained in files based on the
+    FITS (Flexible Image Transport System) file format.  It is written and
+    is maintained by software engineers at the Subaru Telescope, National
+    Astronomical Observatory of Japan.
+  </longdescription>
+  <upstream>
+    <remote-id type="pypi">ginga</remote-id>
+    <remote-id type="github">ejeschke/ginga</remote-id>
+  </upstream>
+</pkgmetadata>