dev-python/boto3: version bump to 1.4.8

Upstream changed accepted version range of dev-python/botocore.

Package-Manager: Portage-2.3.14, Repoman-2.3.6

1 files changed, 54 insertions, 0 deletions

diff --git a/dev-python/boto3/boto3-1.4.8.ebuild b/dev-python/boto3/boto3-1.4.8.ebuild
new file mode 100644
index 000000000000..fd9d72e960f4
--- /dev/null
+++ b/dev-python/boto3/boto3-1.4.8.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_4 python3_5 python3_6 )
+
+inherit distutils-r1 vcs-snapshot
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="https://github.com/boto/boto3"
+SRC_URI="https://github.com/boto/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc test"
+
+CDEPEND="
+	>=dev-python/botocore-1.8.0[${PYTHON_USEDEP}]
+	<dev-python/botocore-1.9.0[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	<dev-python/jmespath-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.1.10[${PYTHON_USEDEP}]
+	<dev-python/s3transfer-0.2.0[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		>=dev-python/guzzle_sphinx_theme-0.7.10[${PYTHON_USEDEP}]
+		<dev-python/guzzle_sphinx_theme-0.8[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.1.3[${PYTHON_USEDEP}]
+		<dev-python/sphinx-1.7[${PYTHON_USEDEP}]
+	)
+	test? (
+		${CDEPEND}
+		~dev-python/mock-1.3.0[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="${CDEPEND}"
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	nosetests -v tests/unit/ tests/functional/ || die "test failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/build/html/. )
+
+	distutils-r1_python_install_all
+}