dev-lisp/ecls: bump to 23.9.9

Closes: https://bugs.gentoo.org/913906
Signed-off-by: Andrey Grozin <grozin@gentoo.org>

2 files changed, 90 insertions, 0 deletions

diff --git a/dev-lisp/ecls/Manifest b/dev-lisp/ecls/Manifest
index c596a7c16915..6cb34002d034 100644
--- a/dev-lisp/ecls/Manifest
+++ b/dev-lisp/ecls/Manifest
@@ -1 +1,2 @@
 DIST ecl-21.2.1.tgz 7875088 BLAKE2B b8c05fab8ce5892ad9df830e3ad230e1c646bd30bc35243703ace18f1bf963057b132d980c74b364ff30a5b776a8f161e71bfd69d7908970811ab3dddbab1aac SHA512 0849bebe1a8073ea8027cfb172c1d7781d43adb6a8b80585bd08d5674b80422d1648b6fbf718cc17a51c5de6c696514523b4d13a82e8113bf9365c95d3c28648
+DIST ecl-23.9.9.tgz 8129105 BLAKE2B 883454e1b5459b348a2184727dc9d512988f3b8218370cbe01045e5bc401a6785cb736a16592d20ad9fe19e6518056ece5b809323fa7697304f39d31d60021fc SHA512 c8f1dcf2bffad7358c3d4e5bb0924cbb69afaf79871e6444bd780a594e1e96e6c547346b7c9c5184a6b12ce920a6a959334cf2a85c3f3ea0e0c8f22f72fb84df
diff --git a/dev-lisp/ecls/ecls-23.9.9.ebuild b/dev-lisp/ecls/ecls-23.9.9.ebuild
new file mode 100644
index 000000000000..d547a6fc1135
--- /dev/null
+++ b/dev-lisp/ecls/ecls-23.9.9.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit readme.gentoo-r1
+
+MY_P=ecl-${PV}
+DESCRIPTION="ECL is an embeddable Common Lisp implementation"
+HOMEPAGE="https://common-lisp.net/project/ecl/"
+SRC_URI="https://common-lisp.net/project/ecl/static/files/release/${MY_P}.tgz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD-2 LGPL-2.1+"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux"
+IUSE="cxx debug emacs gengc precisegc cpu_flags_x86_sse +threads +unicode X"
+# test phase only works if ecls already installed #516876
+RESTRICT="test"
+
+RDEPEND="dev-libs/gmp:0=
+		dev-libs/libffi:=
+		dev-libs/libatomic_ops
+		>=dev-libs/boehm-gc-7.1[threads?]
+		>=dev-lisp/asdf-2.33-r3:="
+DEPEND="${RDEPEND}
+		app-text/texi2html
+		emacs? ( >=app-editors/emacs-23.1:* >=app-eselect/eselect-emacs-1.12 )"
+
+DOCS=( README.md CHANGELOG )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-16.1.3-headers-gentoo.patch"
+	"${FILESDIR}/${PN}-16.1.3-build.patch"
+	"${FILESDIR}/${PN}-21.2.1-donotcompressinfo.patch"
+)
+
+src_prepare() {
+	default
+	cp "${EPREFIX}"/usr/share/common-lisp/source/asdf/build/asdf.lisp contrib/asdf/ || die
+}
+
+src_configure() {
+	econf \
+		--enable-gmp=system \
+		--enable-boehm=system \
+		--with-dffi \
+		--enable-libatomic=system \
+		--with-defsystem \
+		$(use_with cxx) \
+		$(use_enable gengc) \
+		$(use_enable precisegc) \
+		$(use_with debug debug-cflags) \
+		$(use_with cpu_flags_x86_sse sse) \
+		$(use_enable threads) \
+		$(use_enable unicode) \
+		$(use_with X x)
+}
+
+src_compile() {
+	if use emacs; then
+		local ETAGS=$(eselect --brief etags list | sed -ne '/emacs/{p;q}')
+		[[ -n ${ETAGS} ]] || die "No etags implementation found"
+		pushd build > /dev/null || die
+		emake ETAGS=${ETAGS} TAGS
+		popd > /dev/null || die
+	else
+		touch build/TAGS
+	fi
+
+	## for /proc/self/clear_refs (see #867052)
+	addpredict /proc
+
+	emake
+}
+
+src_install() {
+	default
+
+	readme.gentoo_create_doc
+	pushd build/doc > /dev/null || die
+	newman ecl.man ecl.1
+	newman ecl-config.man ecl-config.1
+	popd > /dev/null || die
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+}