proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 79 insertions, 0 deletions

diff --git a/dev-libs/ucommon/ucommon-6.3.1.ebuild b/dev-libs/ucommon/ucommon-6.3.1.ebuild
new file mode 100644
index 000000000000..938dae96ff67
--- /dev/null
+++ b/dev-libs/ucommon/ucommon-6.3.1.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+AUTOTOOLS_AUTORECONF=1
+
+inherit autotools-utils eutils
+
+DESCRIPTION="Portable C++ runtime for threads and sockets"
+HOMEPAGE="http://www.gnu.org/software/commoncpp"
+SRC_URI="mirror://gnu/commoncpp/${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0/6"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux"
+IUSE="doc static-libs socks +cxx debug ssl gnutls"
+
+RDEPEND="
+	ssl? (
+		!gnutls? ( dev-libs/openssl:0= )
+		gnutls? (
+			net-libs/gnutls:0=
+			dev-libs/libgcrypt:0=
+		)
+	)"
+
+DEPEND="virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	${RDEPEND}"
+
+DOCS=(README NEWS SUPPORT ChangeLog AUTHORS)
+PATCHES=( "${FILESDIR}"/6.1/install_gcrypt.m4_file.patch
+		  "${FILESDIR}"/${PN}-6.3.1-gcrypt_autotools.patch )
+
+# Needed for doxygen, bug #526726
+AUTOTOOLS_IN_SOURCE_BUILD=1
+
+src_prepare() {
+	# Aclocal 1.13 deprecated error BGO #467674
+	sed -e 's/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/g' -i configure.ac || die
+
+	# don't install latex and rtf documents
+	sed -e '/^GENERATE_LATEX/s@YES@NO@' -e '/^GENERATE_RTF/s@YES@NO@' \
+		-i Doxyfile.in || die
+
+	autotools-utils_src_prepare
+}
+
+src_configure() {
+	local myconf=""
+	if use ssl; then
+		myconf+=" --with-sslstack=$(usex gnutls gnu ssl) "
+	else
+		myconf+=" --with-sslstack=nossl ";
+	fi
+
+	local myeconfargs=(
+		$(use_enable  socks)
+		$(use_enable  cxx stdcpp)
+		${myconf}
+		--enable-atomics
+		--with-pkg-config
+	)
+	autotools-utils_src_configure
+}
+
+src_compile() {
+	autotools-utils_src_compile
+	use doc && autotools-utils_src_compile doxy
+}
+
+src_install() {
+	autotools-utils_src_install
+	if use doc; then
+		dohtml doc/html/*
+	fi
+}