dev-libs/libsass: Bump to 3.6.5 (needed for dev-python/libsass)

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 53 insertions, 0 deletions

diff --git a/dev-libs/libsass/libsass-3.6.5.ebuild b/dev-libs/libsass/libsass-3.6.5.ebuild
new file mode 100644
index 000000000000..14f45c1d6db9
--- /dev/null
+++ b/dev-libs/libsass/libsass-3.6.5.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools multilib-minimal
+
+if [[ ${PV} = *9999 ]]; then
+	EGIT_REPO_URI="https://github.com/sass/libsass.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/sass/libsass/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~x86 ~amd64-linux"
+fi
+
+DESCRIPTION="A C/C++ implementation of a Sass CSS compiler"
+HOMEPAGE="https://github.com/sass/libsass"
+LICENSE="MIT"
+SLOT="0/1" # libsass soname
+IUSE="static-libs"
+
+DOCS=( Readme.md SECURITY.md )
+
+src_prepare() {
+	default
+
+	if [[ ${PV} != *9999 ]]; then
+		[[ -f VERSION ]] || echo "${PV}" > VERSION
+	fi
+	eautoreconf
+
+	# only sane way to deal with various version-related scripts, env variables etc.
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		$(use_enable static-libs static)
+		--enable-shared
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+	find "${D}" -name '*.la' -delete || die
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	dodoc -r "${S}/docs"
+}