proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

5 files changed, 201 insertions, 0 deletions

diff --git a/dev-libs/dietlibc/Manifest b/dev-libs/dietlibc/Manifest
new file mode 100644
index 000000000000..2f471903e102
--- /dev/null
+++ b/dev-libs/dietlibc/Manifest
@@ -0,0 +1,4 @@
+DIST dietlibc-0.30.tar.bz2 567046 SHA256 2c8733825d364d374f0179a403a57e4a382fbb9852431228ef19062a5de183b5 SHA512 dfd2ea0de3db3aa7f9781353bfd3fe85e1925099afa05429e15714f7c73633f1e33a017e85f592b71d2649fc14484650b3fb88e2e92833e8aa7550cf687040bd WHIRLPOOL d46fbf8a9b471c6d3e55b5d5dff81c65649fe1c4d8362acf2f5a440541f4340e0cdf2349cf5e6567a0e0094cd8e0e598649200db64091661614fb1ac899dc118
+DIST dietlibc-0.33_pre20110403.tar.gz 743758 SHA256 6505ed424a5b53850ae1dcbc75fbf92f3b7e4038dd1104d114b366221cc48eea SHA512 32f9d752a77bcca5703a388ba64dcb53de75999043c1b2fabe973eba05fce4e9f48a6bdb71e061939eee339ca723234d33d2acb3677a8030accaccba31a5932e WHIRLPOOL 5756b1e42637d89fd17f1a79fe602f9e009b9d5dcca0fbe3540ad2af21ad96b32d0b4773f882cccfd97d6308cd3c9ad79d06cc7ca79e28a4d60fd00379eaef70
+DIST dietlibc-0.34_pre20140729.tar.bz2 670195 SHA256 d6693610c756dbfc070c0ffed5a75e1ddab8d119394962ca1ed4d42f34b57318 SHA512 a0bb5465f7fc985fd074dfcc4039003ec26b6b5fde5f2ccc53322067bd1a6459e742c9debeffda0b5146e287baa8e49f74f4a8ffafdf1daacacec4768d13db36 WHIRLPOOL 566e505a65e3f81c5507fc494324b4f48e5af27683d69c443cf7d2380599a24bbc984d7d430acb25bc0d28baa924565ee513c8217dd2eb6a960c70d6d2a7e1b7
+DIST dietlibc-patches-0.30-r2.tar.bz2 31582 SHA256 03a3ea9bba39fb78511a59e80bcbdafdc82a0859b31b6af925854052a79f06fe SHA512 f2d2a805b7c900ed174ca4460a68943dc16468a61dd2016fa329d5d20d547698d1a30a3f1f38b78c314b0ddaea8cdc3a4b0455c77b3a688ba4ffdc1bc88c65fe WHIRLPOOL a551a1c666fb43e291975e2b2acd03c2bf719e85c12256873048fab62e48401ecdbedfd8db7f6f6b273c75821931c3e87ed71f8ce811683f1b09740528056159
diff --git a/dev-libs/dietlibc/dietlibc-0.30-r2.ebuild b/dev-libs/dietlibc/dietlibc-0.30-r2.ebuild
new file mode 100644
index 000000000000..893191a9d860
--- /dev/null
+++ b/dev-libs/dietlibc/dietlibc-0.30-r2.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+inherit eutils flag-o-matic
+
+DESCRIPTION="A minimal libc"
+HOMEPAGE="http://www.fefe.de/dietlibc/"
+SRC_URI="mirror://gentoo/${P}.tar.bz2
+	http://dev.gentoo.org/~phreak/distfiles/${PN}-patches-${PVR}.tar.bz2
+	http://dev.gentoo.org/~hollow/distfiles/${PN}-patches-${PVR}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="alpha amd64 arm ~mips sparc x86"
+IUSE="debug"
+
+DEPEND=""
+
+pkg_setup() {
+	# Replace sparc64 related C[XX]FLAGS (see bug #45716)
+	use sparc && replace-sparc64-flags
+
+	# gcc-hppa suffers support for SSP, compilation will fail
+	# (do we still need this? SSP is disabled, see below)
+	use hppa && strip-unsupported-flags
+
+	# we use dietlibs STACKGAP in favor of the broken SSP implementation
+	filter-flags -fstack-protector -fstack-protector-all
+
+	# debug flags
+	use debug && append-flags -g
+}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	epatch "${WORKDIR}"/patches/*.patch
+}
+
+src_compile() {
+	# parallel make is b0rked
+	emake -j1 CFLAGS="${CFLAGS}" || die "make failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "make install failed"
+	dobin "${D}"/usr/diet/bin/* || die "dobin failed"
+	doman "${D}"/usr/diet/man/*/* || die "doman failed"
+	rm -r "${D}"/usr/diet/{man,bin}
+	dodoc AUTHOR BUGS CAVEAT CHANGES README THANKS TODO PORTING
+}
diff --git a/dev-libs/dietlibc/dietlibc-0.33_pre20110403.ebuild b/dev-libs/dietlibc/dietlibc-0.33_pre20110403.ebuild
new file mode 100644
index 000000000000..f90d08626382
--- /dev/null
+++ b/dev-libs/dietlibc/dietlibc-0.33_pre20110403.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="3"
+
+inherit eutils flag-o-matic toolchain-funcs
+
+GITHUB_AUTHOR="hollow"
+GITHUB_PROJECT="dietlibc"
+GITHUB_COMMIT="4e86d5e"
+
+DESCRIPTION="A libc optimized for small size"
+HOMEPAGE="http://www.fefe.de/dietlibc/"
+SRC_URI="http://nodeload.github.com/${GITHUB_AUTHOR}/${GITHUB_PROJECT}/tarball/v${PV} -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha amd64 ~arm ia64 ~mips sparc x86 ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+DEPEND=""
+RDEPEND=""
+
+S="${WORKDIR}"/${GITHUB_AUTHOR}-${GITHUB_PROJECT}-${GITHUB_COMMIT}
+
+DIETHOME=/usr/diet
+
+pkg_setup() {
+	# Replace sparc64 related C[XX]FLAGS (see bug #45716)
+	use sparc && replace-sparc64-flags
+
+	# gcc-hppa suffers support for SSP, compilation will fail
+	use hppa && strip-unsupported-flags
+
+	# debug flags
+	use debug && append-flags -g
+
+	# Makefile does not append CFLAGS
+	append-flags -nostdinc -W -Wall -Wextra -Wchar-subscripts \
+		-Wmissing-prototypes -Wmissing-declarations -Wno-switch \
+		-Wno-unused -Wredundant-decls -fno-strict-aliasing
+
+	# only use -nopie on archs that support it
+	gcc-specs-pie && append-flags -nopie
+}
+
+src_compile() {
+	emake prefix="${EPREFIX}"${DIETHOME} \
+		CC="$(tc-getCC)" \
+		CFLAGS="${CFLAGS}" \
+		STRIP=":" \
+		|| die "make failed"
+}
+
+src_install() {
+	emake prefix="${EPREFIX}"${DIETHOME} \
+		DESTDIR="${D}" \
+		install-bin \
+		install-headers \
+		|| die "make install failed"
+
+	dobin "${ED}"${DIETHOME}/bin/* || die "dobin failed"
+	doman "${ED}"${DIETHOME}/man/*/* || die "doman failed"
+	rm -r "${ED}"${DIETHOME}/{man,bin}
+
+	dodoc AUTHOR BUGS CAVEAT CHANGES README THANKS TODO PORTING
+}
diff --git a/dev-libs/dietlibc/dietlibc-0.34_pre20140729.ebuild b/dev-libs/dietlibc/dietlibc-0.34_pre20140729.ebuild
new file mode 100644
index 000000000000..43ec4b93320f
--- /dev/null
+++ b/dev-libs/dietlibc/dietlibc-0.34_pre20140729.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils flag-o-matic toolchain-funcs
+
+DESCRIPTION="A libc optimized for small size"
+HOMEPAGE="http://www.fefe.de/dietlibc/"
+SRC_URI="http://dev.gentoo.org/~patrick/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS=" ~alpha ~amd64 ~arm ~ia64 ~mips ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE=""
+
+DEPEND=""
+RDEPEND=""
+
+DIETHOME=/usr/diet
+
+S=${WORKDIR}/dietlibc
+
+src_prepare() {
+	# Replace sparc64 related C[XX]FLAGS (see bug #45716)
+	use sparc && replace-sparc64-flags
+
+	# gcc-hppa suffers support for SSP, compilation will fail
+	use hppa && strip-unsupported-flags
+
+	# Makefile does not append CFLAGS
+	append-flags -nostdinc -W -Wall -Wextra -Wchar-subscripts \
+		-Wmissing-prototypes -Wmissing-declarations -Wno-switch \
+		-Wno-unused -Wredundant-decls -fno-strict-aliasing
+
+	# Disable ssp for we default to it on >=gcc-4.8.3
+	append-flags $(test-flags -fno-stack-protector)
+
+	# only use -nopie on archs that support it
+	gcc-specs-pie && append-flags -nopie
+
+	sed -i -e 's:strip::' Makefile || die
+	append-flags -Wa,--noexecstack
+}
+
+src_compile() {
+	emake -j1 prefix="${EPREFIX}"${DIETHOME} \
+		CC="$(tc-getCC)" \
+		CFLAGS="${CFLAGS}" \
+		STRIP=":"
+}
+
+src_install() {
+	emake -j1 prefix="${EPREFIX}"${DIETHOME} \
+		DESTDIR="${D}" \
+		install-bin \
+		install-headers \
+		install-profiling
+
+	dobin "${ED}"${DIETHOME}/bin/*
+	doman "${ED}"${DIETHOME}/man/*/*
+	rm -r "${ED}"${DIETHOME}/{man,bin} || die
+
+	dodoc AUTHOR BUGS CAVEAT CHANGES README THANKS TODO PORTING
+}
diff --git a/dev-libs/dietlibc/metadata.xml b/dev-libs/dietlibc/metadata.xml
new file mode 100644
index 000000000000..965014493b69
--- /dev/null
+++ b/dev-libs/dietlibc/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer>
+		<email>maintainer-needed@gentoo.org</email>
+	</maintainer>
+	<longdescription>
+		The diet libc is a libc that is optimized for small size.  It can be
+		used to create small statically linked binaries for Linux on alpha, arm,
+		hppa, ia64, i386, mips, s390, sparc, sparc64, ppc and x86_64.
+	</longdescription>
+</pkgmetadata>