dev-lang/swi-prolog: bump development version

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Keri Harris <keri@gentoo.org>

2 files changed, 104 insertions, 0 deletions

diff --git a/dev-lang/swi-prolog/Manifest b/dev-lang/swi-prolog/Manifest
index 80ec94d28ba4..f261c07415bf 100644
--- a/dev-lang/swi-prolog/Manifest
+++ b/dev-lang/swi-prolog/Manifest
@@ -5,3 +5,4 @@ DIST swipl-8.3.0.tar.gz 10955310 BLAKE2B 74fbe2460b4b911281846ee7fffb0ca053e6c1c
 DIST swipl-8.3.1.tar.gz 10956733 BLAKE2B 8fab6bb759371af7bf2ed71d7588eeb0694d9f8317a8daff0b663bf883428d0b80ce75196029d87192a82760719bb07086bb11a9969f0700d6dcb232bbd13704 SHA512 8e8e1b65e5e8f7b3ac22e09c9d9700fbdf44ada1470c9a741e3ea98063e096ce859cdfdf0ab1face7c41f1c04b55583ab5a38f91d8fa1fbd26ba1dff199be116
 DIST swipl-8.3.2.tar.gz 10971577 BLAKE2B d6dc5b7f4a3133d4fb97b236113c691a4aa4aecaeb9a1f9f2f417fc541a934eb3987ca3413b4d72e14849575aeb6eacd150f1b4e4290e2a62995e1554048509c SHA512 cab637aba1f11be96553bd68a4a7364d407ef600408d607f26ad2bab53f26b1399cd082dce65c1b8c7b73bc63ea16553942234f80d3024ef3ca853457769cda7
 DIST swipl-8.3.3.tar.gz 10983958 BLAKE2B 41243dc83a5bdf17f6b78b18f9da00b691294fcc557c3ae828e4d1d3ac3347019162143243864ff5db78c65ada1a5a07ff0b282bac57c5882f59518a62203771 SHA512 58bb9166e2b4c83b399985bf9b79e6851b76f459e97c6a820872f66b8a211ca490d953ed5815acc939b0b295533e017f31466bacd0be2e0f8d8e2357cf2d2d42
+DIST swipl-8.3.4.tar.gz 10998331 BLAKE2B 3d290b0119a8493f57788afb16c4ee4178a9d295a7e75897f92a13caf35c8638059334984d07c993e03e6eecb8eb37002287b3066c491848fb19ffbdb8e575d1 SHA512 119bcd7229443ef574be0ab420668d1cfab9ad1f90a6b708b3b17a41d7f3af8f8c2493a6c34e7bf0061b300013a0e95a2f1519e313aad081dd5fa7ffa002859e
diff --git a/dev-lang/swi-prolog/swi-prolog-8.3.4.ebuild b/dev-lang/swi-prolog/swi-prolog-8.3.4.ebuild
new file mode 100644
index 000000000000..2293c183ae1c
--- /dev/null
+++ b/dev-lang/swi-prolog/swi-prolog-8.3.4.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils eutils flag-o-matic multilib
+
+PATCHSET_VER="0"
+
+DESCRIPTION="versatile implementation of the Prolog programming language"
+HOMEPAGE="http://www.swi-prolog.org/"
+SRC_URI="http://www.swi-prolog.org/download/devel/src/swipl-${PV}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="archive berkdb debug doc +gmp java +libedit libressl minimal odbc pcre qt5 readline ssl test uuid X yaml"
+RESTRICT="!test? ( test )"
+
+RDEPEND="sys-libs/ncurses:=
+	sys-libs/zlib
+	archive? ( app-arch/libarchive )
+	berkdb? ( >=sys-libs/db-4:= )
+	odbc? ( dev-db/unixODBC )
+	pcre? ( dev-libs/libpcre )
+	readline? ( sys-libs/readline:= )
+	libedit? ( dev-libs/libedit )
+	gmp? ( dev-libs/gmp:0 )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0 )
+		libressl? ( dev-libs/libressl )
+	)
+	java? ( >=virtual/jdk-1.7:= )
+	uuid? ( dev-libs/ossp-uuid )
+	qt5? (
+		dev-qt/qtwidgets:5
+		dev-qt/qtgui:5
+	)
+	X? (
+		virtual/jpeg:0
+		x11-libs/libX11
+		x11-libs/libXft
+		x11-libs/libXinerama
+		x11-libs/libXpm
+		x11-libs/libXt
+		x11-libs/libICE
+		x11-libs/libSM )
+	yaml? ( dev-libs/libyaml )"
+
+DEPEND="${RDEPEND}
+	X? ( x11-base/xorg-proto )
+	java? ( test? ( =dev-java/junit-3.8* ) )"
+
+S="${WORKDIR}/swipl-${PV}"
+BUILD_DIR="${S}/build"
+CMAKE_USE_DIR="${S}"
+
+src_prepare() {
+	if [[ -d "${WORKDIR}"/${PV} ]] ; then
+		eapply "${WORKDIR}"/${PV}
+	fi
+	eapply_user
+
+	sed -i -e "s|\(SWIPL_INSTALL_PREFIX\)   lib/.*)|\1   $(get_libdir)/swipl)|" CMakeLists.txt || die
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+	use debug && append-flags -DO_DEBUG
+
+	mycmakeargs=(
+		-DSWIPL_INSTALL_PREFIX=$(get_libdir)/swipl
+		-DUSE_GMP=$(usex gmp)
+		-DINSTALL_DOCUMENTATION=$(use doc && usex archive)
+		-DSWIPL_PACKAGES_BASIC=$(usex !minimal)
+		-DSWIPL_PACKAGES_ARCHIVE=$(usex archive)
+		-DSWIPL_PACKAGES_ODBC=$(usex odbc)
+		-DSWIPL_PACKAGES_BDB=$(usex berkdb)
+		-DSWIPL_PACKAGES_PCRE=$(usex pcre)
+		-DSWIPL_PACKAGES_YAML=$(usex yaml)
+		-DSWIPL_PACKAGES_SSL=$(usex ssl)
+		-DSWIPL_PACKAGES_JAVA=$(usex java)
+		-DSWIPL_PACKAGES_QT=$(usex qt5)
+		-DSWIPL_PACKAGES_X=$(usex X)
+		-DSWIPL_PACKAGES_TERM=$(if use libedit || use readline; then echo yes; else echo no; fi)
+		)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	XDG_CONFIG_DIRS="${HOME}" \
+	XDG_DATA_DIRS="${HOME}" \
+		cmake-utils_src_compile
+}
+
+src_test() {
+	USE_PUBLIC_NETWORK_TESTS=false \
+	USE_ODBC_TESTS=false \
+		cmake-utils_src_test -V
+}