dev-lang/swi-prolog: bump development version

Package-Manager: Portage-3.0.4, Repoman-2.3.22
Signed-off-by: Keri Harris <keri@gentoo.org>

2 files changed, 105 insertions, 0 deletions

diff --git a/dev-lang/swi-prolog/Manifest b/dev-lang/swi-prolog/Manifest
index 7c8abb53fd44..d480c75ee31e 100644
--- a/dev-lang/swi-prolog/Manifest
+++ b/dev-lang/swi-prolog/Manifest
@@ -4,3 +4,4 @@ DIST swipl-8.2.2.tar.gz 11002077 BLAKE2B 581c3ea83d2440cbe2454ba12ea2752bec9fda9
 DIST swipl-8.3.10.tar.gz 11095901 BLAKE2B ff695f3a9ed77b8062c8e19fe0f099b3fe1a2ed84beacd965f133d2fa4c2b873ce95d0af6a71a9c5f8c8033b6026e72585ad36dbd7537cb90c5bd98bf852cff7 SHA512 f34e53df42ba3cfdce6be96a2c5dba9ecd0a938f1df9824522c852d8d1b7e42e1de96cebd7c988d9e9091a12cfc791f3916e198e8bb08e8798fc8b196c48058d
 DIST swipl-8.3.11.tar.gz 11098611 BLAKE2B 5ec01773be2466ac8e35f9cba5a5ce4b5c96beafed6e294ecff649a24dbfa332d1280d3022a379a68d8bee2080efb2616737a5e7f4113cc5301e7f4b8fc9a089 SHA512 f0d6bd40127d077a04028c9800c798f6745d80f9852b38d770bd9b1a4778652a90d13c04be1fb4f650c250bb95f9a7e576bfc6c298f8eac608cc96edadb77963
 DIST swipl-8.3.12.tar.gz 11099881 BLAKE2B adbf262457e96371f29e2e002fc5e0e927a417259e57e722334481ce16284a19e850cb3d4bac7696140645a80b1257d1210643900d79deeb9b3abbe5cf39da6e SHA512 30e0d0db70bdca2457a629046db571d17a4b25c705f56c8077f5798ffac9a62020f472165ede7aec0be68a0bcaf71d787108452505fe3fa30ff894445a37882a
+DIST swipl-8.3.13.tar.gz 11099911 BLAKE2B 6153c7d19f8626b1786d63c5fa2cd52299d51e1ab0d859f21aa9d298d57b8e8a193a0fbddb12b69fb92f1d41c7183cfa98615c3265967b24e529dbe312dbdfae SHA512 e0e05883a6c2c592c08bfd8142593e47427d7a48cdfaa8c92556749c4de10eef7807d273b66862541109f60764dcd67378ac7fa3781ac4b23e3e916b269d362d
diff --git a/dev-lang/swi-prolog/swi-prolog-8.3.13.ebuild b/dev-lang/swi-prolog/swi-prolog-8.3.13.ebuild
new file mode 100644
index 000000000000..d7f0a906f57e
--- /dev/null
+++ b/dev-lang/swi-prolog/swi-prolog-8.3.13.ebuild
@@ -0,0 +1,104 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils eutils flag-o-matic multilib
+
+PATCHSET_VER="0"
+
+DESCRIPTION="versatile implementation of the Prolog programming language"
+HOMEPAGE="http://www.swi-prolog.org/"
+SRC_URI="http://www.swi-prolog.org/download/devel/src/swipl-${PV}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="archive berkdb debug doc +gmp java +libedit libressl minimal odbc pcre qt5 readline ssl test uuid X yaml"
+RESTRICT="!test? ( test )"
+
+RDEPEND="sys-libs/ncurses:=
+	sys-libs/zlib
+	archive? ( app-arch/libarchive )
+	berkdb? ( >=sys-libs/db-4:= )
+	odbc? ( dev-db/unixODBC )
+	pcre? ( dev-libs/libpcre )
+	readline? ( sys-libs/readline:= )
+	libedit? ( dev-libs/libedit )
+	gmp? ( dev-libs/gmp:0 )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0 )
+		libressl? ( dev-libs/libressl )
+	)
+	java? ( >=virtual/jdk-1.7:= )
+	uuid? ( dev-libs/ossp-uuid )
+	qt5? (
+		dev-qt/qtwidgets:5
+		dev-qt/qtgui:5
+	)
+	X? (
+		virtual/jpeg:0
+		x11-libs/libX11
+		x11-libs/libXft
+		x11-libs/libXinerama
+		x11-libs/libXpm
+		x11-libs/libXt
+		x11-libs/libICE
+		x11-libs/libSM )
+	yaml? ( dev-libs/libyaml )"
+
+DEPEND="${RDEPEND}
+	X? ( x11-base/xorg-proto )
+	java? ( test? ( =dev-java/junit-3.8* ) )"
+
+S="${WORKDIR}/swipl-${PV}"
+BUILD_DIR="${S}/build"
+CMAKE_USE_DIR="${S}"
+
+src_prepare() {
+	if [[ -d "${WORKDIR}"/${PV} ]] ; then
+		eapply "${WORKDIR}"/${PV}
+	fi
+	eapply_user
+
+	sed -i -e "s|\(SWIPL_INSTALL_PREFIX\)   lib/.*)|\1   $(get_libdir)/swipl)|" CMakeLists.txt || die
+	sed -i -e "s|\(SWIPL_INSTALL_CMAKE_CONFIG_DIR\) lib/|\1   $(get_libdir)/|" CMakeLists.txt || die
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+	use debug && append-flags -DO_DEBUG
+
+	mycmakeargs=(
+		-DSWIPL_INSTALL_PREFIX=$(get_libdir)/swipl
+		-DUSE_GMP=$(usex gmp)
+		-DINSTALL_DOCUMENTATION=$(use doc && usex archive)
+		-DSWIPL_PACKAGES_BASIC=$(usex !minimal)
+		-DSWIPL_PACKAGES_ARCHIVE=$(usex archive)
+		-DSWIPL_PACKAGES_ODBC=$(usex odbc)
+		-DSWIPL_PACKAGES_BDB=$(usex berkdb)
+		-DSWIPL_PACKAGES_PCRE=$(usex pcre)
+		-DSWIPL_PACKAGES_YAML=$(usex yaml)
+		-DSWIPL_PACKAGES_SSL=$(usex ssl)
+		-DSWIPL_PACKAGES_JAVA=$(usex java)
+		-DSWIPL_PACKAGES_QT=$(usex qt5)
+		-DSWIPL_PACKAGES_X=$(usex X)
+		-DSWIPL_PACKAGES_TERM=$(if use libedit || use readline; then echo yes; else echo no; fi)
+		)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	XDG_CONFIG_DIRS="${HOME}" \
+	XDG_DATA_DIRS="${HOME}" \
+		cmake-utils_src_compile
+}
+
+src_test() {
+	USE_PUBLIC_NETWORK_TESTS=false \
+	USE_ODBC_TESTS=false \
+		cmake-utils_src_test -V
+}