proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 64 insertions, 0 deletions

diff --git a/dev-lang/maude/maude-2.6-r1.ebuild b/dev-lang/maude/maude-2.6-r1.ebuild
new file mode 100644
index 000000000000..775f24320063
--- /dev/null
+++ b/dev-lang/maude/maude-2.6-r1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+AUTOTOOLS_AUTORECONF=1
+AUTOTOOLS_IN_SOURCE_BUILD=1
+
+inherit autotools-utils versionator
+
+MYP="${PN/m/M}-$(get_version_component_range 1-2)"
+
+DESCRIPTION="High-level specification language for equational and logic programming"
+HOMEPAGE="http://maude.cs.uiuc.edu/"
+SRC_URI="
+	http://maude.cs.uiuc.edu/download/current/${MYP}.tar.gz
+	http://dev.gentoo.org/~jlec/distfiles/${P}-extras.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples"
+
+RDEPEND="
+	>=dev-libs/gmp-4.1.3
+	dev-libs/libsigsegv
+	dev-libs/libtecla
+	sci-libs/buddy"
+DEPEND="${RDEPEND}
+	sys-devel/bison
+	sys-devel/flex"
+
+S="${WORKDIR}/${MYP}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.5.0-prll.patch
+	"${FILESDIR}"/${PN}-2.6-search-datadir.patch
+	"${FILESDIR}"/${PN}-2.6-gcc47.patch
+)
+
+src_configure() {
+	local myeconfargs=(
+		--datadir="${EPREFIX}/usr/share/${PN}"
+	)
+	sed -i -e "s:/usr:${EPREFIX}/usr:g" src/Mixfix/global.hh || die
+	autotools-utils_src_configure
+}
+
+src_install() {
+	autotools-utils_src_install
+
+	# install data and full maude
+	insinto /usr/share/${PN}
+	doins -r src/Main/*.maude
+	doins "${WORKDIR}"/${P}-extras/full-maude.maude
+
+	# install docs and examples
+	use doc && doins -r "${WORKDIR}"/${P}-extras/pdfs/*
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins -r "${WORKDIR}"/${P}-extras/{manual,primer}-examples
+	fi
+}