dev-cpp/libcmis: Add 0.5.2_pre20160820 snapshot

Contains the 2FA fixes necessary to make Google Drive remote access
work. No big difference to .1 otherwise.

Package-Manager: portage-2.2.28

3 files changed, 91 insertions, 7 deletions

diff --git a/dev-cpp/libcmis/Manifest b/dev-cpp/libcmis/Manifest
index 52162669e9e4..9bd934e03e6a 100644
--- a/dev-cpp/libcmis/Manifest
+++ b/dev-cpp/libcmis/Manifest
@@ -1,3 +1,4 @@
 DIST libcmis-0.5.0-gcc5.patch.gz 12452 SHA256 523763acda1de64bb40761fae1ce1b089756fba1bb0390587d6491b75ffafbea SHA512 75423caf195d9b6f2c0752f08fd9950ff1dac67884f7445da2389fb24ad13c2c29fbf73f29f6f60b1b440ad261c32697edf3a2ee9aba779630d40afdbf5d5495 WHIRLPOOL 5cbc92051da8dc99b6d575f13c6d3c853668dd1ce169e0f215f2d20cbaf1d77408d9af0844be5e04c1308e840110a0e5dd49ee86f0207bbead7361962c830cdb
 DIST libcmis-0.5.0.tar.gz 738119 SHA256 a87e02913dee3ee659db5abf6d7dafcfcd85dd4b24bf4389d8d4afe8c8dcf9b6 SHA512 abfdf5654ef8763c9744587ba831acea93cc0ba7deaa8d807eed2e9077be848db0334430f7c2d6eecefeb90f520abbe81364a86790c0aa4363724816aec4793b WHIRLPOOL 03041a0eb4af8fb515082731c4737f7c153756073464785994c431f54b27130b8407459efb5bcb4a26689a0baa1f5014e48cfa334948fb7d90fe646d5f8f0a02
 DIST libcmis-0.5.1.tar.gz 281863 SHA256 b88851b5e7dfa65b840d403231b38868ba77dae1e7abf2628d7a0dc3cd5a1409 SHA512 fb934c416b8a41714a5424375de507698992a0b014aa52a82a07dde07cba2ffe68a45ed97cfd0aa72b4a28f3697252ea1570a80ef9fa1b2a34af0a9ed865a752 WHIRLPOOL 4e154a417e98bd7e36fa5a4ad65b969e7c6661b6fbd33dc642a5430bda02e218e985b0b50d67f8fd811896c1a40fd4d3b78ae793d6620d8d5f4e92dd013d70d2
+DIST libcmis-0.5.2_pre20160820.tar.gz 285100 SHA256 49c0d46be0019703b8dbbc0a37fcdd97ed2f5a9576315df2a516b997b07e5b03 SHA512 4b6d0fc4d80444fea2c5eb16621b92a10b41c58128cc8a355caca50f12648ed5113bd977cc5dbe8971e3dbc11f9d7ae8d45c9d2aa19f37c83659141af135bd1a WHIRLPOOL 524391339976b32a698faa75e4597732d487fcee77c5cdf2acb0380dd81686bc357a5ad5df02693f4d0b7a66890c02701dfa04286270c17ab28a86b01d7dfe55
diff --git a/dev-cpp/libcmis/libcmis-0.5.2_pre20160820.ebuild b/dev-cpp/libcmis/libcmis-0.5.2_pre20160820.ebuild
new file mode 100644
index 000000000000..2a04934c848f
--- /dev/null
+++ b/dev-cpp/libcmis/libcmis-0.5.2_pre20160820.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+EGIT_REPO_URI="https://github.com/tdf/libcmis.git"
+[[ ${PV} == 9999 ]] && SCM_ECLASS="git-r3"
+inherit eutils alternatives autotools ${SCM_ECLASS}
+unset SCM_ECLASS
+
+DESCRIPTION="C++ client library for the CMIS interface"
+HOMEPAGE="https://github.com/tdf/libcmis"
+if [[ ${PV} = *_pre* ]]; then
+	snapshot=da8c3fdc281a0cb3753a6bb9eaa63ac6385e2963
+	SRC_URI="https://github.com/tdf/${PN}/archive/${snapshot}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}-${snapshot}"
+	unset snapshot
+elif [[ ${PV} != 9999 ]] ; then
+	SRC_URI="https://github.com/tdf/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+fi
+
+LICENSE="|| ( GPL-2 LGPL-2 MPL-1.1 )"
+SLOT="0.5"
+
+# Don't move KEYWORDS on the previous line or ekeyword won't work # 399061
+[[ ${PV} == 9999 ]] || \
+KEYWORDS="~amd64 ~arm ~x86 ~amd64-linux ~x86-linux"
+
+IUSE="static-libs man test"
+
+COMMON_DEPEND="
+	dev-libs/boost:=
+	dev-libs/libxml2
+	net-misc/curl
+"
+DEPEND="${COMMON_DEPEND}
+	virtual/pkgconfig
+	man? (
+		app-text/docbook2X
+		dev-libs/libxslt
+	)
+	test? (
+		dev-util/cppcheck
+		dev-util/cppunit
+	)
+"
+RDEPEND="${COMMON_DEPEND}
+	!<dev-cpp/libcmis-0.5.0
+"
+
+src_prepare() {
+	default
+	[[ ${PV} = *_pre* || ${PV} = 9999 ]] && eautoreconf
+}
+
+src_configure() {
+	econf \
+		--docdir="${EPREFIX}"/usr/share/doc/${PF} \
+		--program-suffix=-${SLOT} \
+		--disable-werror \
+		$(use_with man) \
+		$(use_enable static-libs static) \
+		$(use_enable test tests) \
+		--enable-client
+}
+
+src_install() {
+	default
+	prune_libtool_files --all
+}
+
+pkg_postinst() {
+	alternatives_auto_makesym /usr/bin/cmis-client "/usr/bin/cmis-client-[0-9].[0-9]"
+}
+
+pkg_postrm() {
+	alternatives_auto_makesym /usr/bin/cmis-client "/usr/bin/cmis-client-[0-9].[0-9]"
+}
diff --git a/dev-cpp/libcmis/libcmis-9999.ebuild b/dev-cpp/libcmis/libcmis-9999.ebuild
index cf54088f06bc..f6c40f8a2d59 100644
--- a/dev-cpp/libcmis/libcmis-9999.ebuild
+++ b/dev-cpp/libcmis/libcmis-9999.ebuild
@@ -11,7 +11,14 @@ unset SCM_ECLASS
 
 DESCRIPTION="C++ client library for the CMIS interface"
 HOMEPAGE="https://github.com/tdf/libcmis"
-[[ ${PV} == 9999 ]] || SRC_URI="https://github.com/tdf/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+if [[ ${PV} = *_pre* ]]; then
+	snapshot=d2054a12e3f52fff8e96341e8c48f0dcd75e2e2a
+	SRC_URI="https://github.com/tdf/${PN}/archive/${snapshot}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}-${snapshot}"
+	unset snapshot
+elif [[ ${PV} != 9999 ]] ; then
+	SRC_URI="https://github.com/tdf/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+fi
 
 LICENSE="|| ( GPL-2 LGPL-2 MPL-1.1 )"
 SLOT="0.5"
@@ -39,15 +46,12 @@ DEPEND="${COMMON_DEPEND}
 	)
 "
 RDEPEND="${COMMON_DEPEND}
-	!dev-cpp/libcmis:0
-	!dev-cpp/libcmis:0.2
-	!dev-cpp/libcmis:0.3
-	!dev-cpp/libcmis:0.4
+	!<dev-cpp/libcmis-0.5.0
 "
 
 src_prepare() {
-	eapply_user
-	[[ ${PV} == 9999 ]] && eautoreconf
+	default
+	[[ ${PV} = *_pre* || ${PV} = 9999 ]] && eautoreconf
 }
 
 src_configure() {