app-text/libebook: Fix build with ICU-68, EAPI-7 bump

Thanks-to: Lars Wendler <polynomial-c@gentoo.org>
Closes: https://bugs.gentoo.org/751925
Package-Manager: Portage-3.0.8, Repoman-3.0.2
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 86 insertions, 0 deletions

diff --git a/app-text/libebook/files/libebook-0.1.3-icu-68.patch b/app-text/libebook/files/libebook-0.1.3-icu-68.patch
new file mode 100644
index 000000000000..964b8b7e195d
--- /dev/null
+++ b/app-text/libebook/files/libebook-0.1.3-icu-68.patch
@@ -0,0 +1,27 @@
+From 9ea3b4c2552770b66b83d44b6e6ccdd338296316 Mon Sep 17 00:00:00 2001
+From: Lars Wendler <polynomial-c@gentoo.org>
+Date: Fri, 30 Oct 2020 10:52:10 +0100
+Subject: [PATCH] Fix build with icu-68.0
+
+icu-68.1 removed public macro definitions for TRUE and FALSE
+
+Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
+---
+ src/lib/EBOOKCharsetConverter.cpp | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/src/lib/EBOOKCharsetConverter.cpp b/src/lib/EBOOKCharsetConverter.cpp
+index 0d85fa3..c9f8be0 100644
+--- a/src/lib/EBOOKCharsetConverter.cpp
++++ b/src/lib/EBOOKCharsetConverter.cpp
+@@ -124,7 +124,7 @@ bool EBOOKCharsetConverter::convertBytes(const char *const in, const unsigned le
+       m_converterToUTF8.get(), m_converterToUnicode.get(),
+       &outText, outText + out.size(), &inText, inText + length,
+       nullptr, nullptr, nullptr, nullptr,
+-      TRUE, TRUE, &status)
++      true, true, &status)
+     ;
+     if (status==U_BUFFER_OVERFLOW_ERROR)
+     {
+-- 
+2.29.2
diff --git a/app-text/libebook/libebook-0.1.3-r1.ebuild b/app-text/libebook/libebook-0.1.3-r1.ebuild
new file mode 100644
index 000000000000..e3bfee60ab37
--- /dev/null
+++ b/app-text/libebook/libebook-0.1.3-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_P="libe-book-${PV}"
+inherit autotools flag-o-matic
+
+DESCRIPTION="Library parsing various ebook formats"
+HOMEPAGE="https://sourceforge.net/projects/libebook/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="doc test tools"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-text/liblangtag
+	dev-libs/icu:=
+	dev-libs/librevenge
+	dev-libs/libxml2
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}
+	dev-libs/boost
+	dev-util/gperf
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	test? ( dev-util/cppunit )
+"
+RDEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=( "${FILESDIR}/${P}-icu-68.patch" )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-static
+		--disable-werror
+		$(use_with doc docs)
+		$(use_enable test tests)
+		$(use_with tools)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -type f -delete || die
+}