app-office/texmacs: correct Qt5 dependencies

Bug: https://bugs.gentoo.org/644606
Package-Manager: Portage-2.3.19, Repoman-2.3.6

1 files changed, 73 insertions, 0 deletions

diff --git a/app-office/texmacs/texmacs-1.99.6-r2.ebuild b/app-office/texmacs/texmacs-1.99.6-r2.ebuild
new file mode 100644
index 000000000000..a5c61a4633ff
--- /dev/null
+++ b/app-office/texmacs/texmacs-1.99.6-r2.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils xdg-utils gnome2-utils qmake-utils
+
+MY_P=${P/tex/TeX}-src
+
+DESCRIPTION="Wysiwyg text processor with high-quality maths"
+HOMEPAGE="http://www.texmacs.org/"
+SRC_URI="ftp://ftp.texmacs.org/pub/TeXmacs/tmftp/source/${MY_P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="jpeg netpbm sqlite svg spell"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	app-text/ghostscript-gpl
+	<dev-scheme/guile-1.9[deprecated]
+	media-libs/freetype
+	x11-apps/xmodmap
+	x11-libs/libXext
+	virtual/latex-base
+	>=dev-qt/qtcore-5.9.1:5
+	>=dev-qt/qtgui-5.9.1:5
+	>=dev-qt/qtwidgets-5.9.1:5
+	>=dev-qt/qtprintsupport-5.9.1:5
+	sqlite? ( dev-db/sqlite )
+	jpeg? ( || ( media-gfx/imagemagick media-gfx/jpeg2ps ) )
+	netpbm? ( media-libs/netpbm )
+	spell? ( app-text/aspell )
+	svg? ( || ( media-gfx/inkscape gnome-base/librsvg:2 ) )
+"
+DEPEND="${RDEPEND}
+	x11-proto/xproto"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	# respect LDFLAGS, bug #338459
+	"${FILESDIR}"/${PN}-plugins-1.patch
+
+	# dont update mime and desktop databases and icon cache
+	"${FILESDIR}"/${PN}-updates.patch
+
+	"${FILESDIR}"/${PN}-1.99.2-desktop.patch
+
+	# remove new/delete declarations, bug 590002
+	"${FILESDIR}"/${PN}-1.99-remove-new-declaration.patch
+
+	"${FILESDIR}"/${PN}-1.99.6-math_util.patch
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_SQLITE=$(usex sqlite sqlite3)
+	)
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+	gnome2_icon_cache_update
+}