app-misc/geoclue: Version bump

Package-Manager: portage-2.2.28

1 files changed, 55 insertions, 0 deletions

diff --git a/app-misc/geoclue/geoclue-2.4.3.ebuild b/app-misc/geoclue/geoclue-2.4.3.ebuild
new file mode 100644
index 000000000000..64d892e02691
--- /dev/null
+++ b/app-misc/geoclue/geoclue-2.4.3.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+GCONF_DEBUG="no"
+
+inherit gnome2 systemd user versionator
+
+MY_PV=$(get_version_component_range 1-2)
+DESCRIPTION="A geoinformation D-Bus service"
+HOMEPAGE="http://freedesktop.org/wiki/Software/GeoClue"
+SRC_URI="http://www.freedesktop.org/software/${PN}/releases/${MY_PV}/${P}.tar.xz"
+
+LICENSE="LGPL-2"
+SLOT="2.0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd"
+IUSE="+introspection +modemmanager zeroconf"
+
+RDEPEND="
+	>=dev-libs/glib-2.34:2
+	>=dev-libs/json-glib-0.14
+	>=net-libs/libsoup-2.42:2.4
+	sys-apps/dbus
+	introspection? ( >=dev-libs/gobject-introspection-0.9.6:= )
+	modemmanager? ( >=net-misc/modemmanager-1 )
+	zeroconf? ( >=net-dns/avahi-0.6.10 )
+	!<sci-geosciences/geocode-glib-3.10.0
+"
+DEPEND="${RDEPEND}
+	dev-util/gdbus-codegen
+	>=dev-util/gtk-doc-am-1
+	>=dev-util/intltool-0.40
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_configure() {
+	# debug only affects CFLAGS
+	gnome2_src_configure \
+		--enable-backend \
+		--with-dbus-service-user=geoclue \
+		$(use_enable introspection) \
+		$(use_enable modemmanager 3g-source) \
+		$(use_enable modemmanager cdma-source) \
+		$(use_enable modemmanager modem-gps-source) \
+		$(use_enable zeroconf nmea-source) \
+		$(systemd_with_unitdir)
+}
+
+pkg_preinst() {
+	enewgroup geoclue
+	enewuser geoclue -1 -1 /var/lib/geoclue geoclue
+	gnome2_pkg_preinst
+}