app-misc/dvtm: Do not strip (bug #565322). Drop obsolete sed scripts. Fix building against sys-libs/ncurses[tinfo] (bug #457530). Drop obsolete USE=unicode.

Package-Manager: Portage-2.3.19, Repoman-2.3.6

4 files changed, 120 insertions, 20 deletions

diff --git a/app-misc/dvtm/dvtm-0.15-r1.ebuild b/app-misc/dvtm/dvtm-0.15-r1.ebuild
new file mode 100644
index 000000000000..5d19ed9aab62
--- /dev/null
+++ b/app-misc/dvtm/dvtm-0.15-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit savedconfig toolchain-funcs
+
+DESCRIPTION="Dynamic virtual terminal manager"
+HOMEPAGE="http://www.brain-dump.org/projects/dvtm/"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://repo.or.cz/dvtm.git"
+else
+	SRC_URI="http://www.brain-dump.org/projects/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+
+RDEPEND="sys-libs/ncurses:0=[unicode]"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+"
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.15-gentoo.patch
+)
+
+src_prepare() {
+	default
+
+	restore_config config.h
+}
+
+src_compile() {
+	tc-export PKG_CONFIG
+	local msg=""
+	use savedconfig && msg=", please check the configfile"
+	emake CC=$(tc-getCC) ${PN} || die "emake failed${msg}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="/usr" STRIP=true install
+
+	insinto /usr/share/${PN}
+	newins config.h ${PF}.config.h
+
+	dodoc README.md
+
+	save_config config.h
+}
+
+pkg_postinst() {
+	elog "This ebuild has support for user defined configs"
+	elog "Please read this ebuild for more details and re-emerge as needed"
+	elog "if you want to add or remove functionality for ${PN}"
+}
diff --git a/app-misc/dvtm/dvtm-9999.ebuild b/app-misc/dvtm/dvtm-9999.ebuild
index a579a42918d3..e80675e8d2fe 100644
--- a/app-misc/dvtm/dvtm-9999.ebuild
+++ b/app-misc/dvtm/dvtm-9999.ebuild
@@ -1,7 +1,7 @@
 # Copyright 1999-2017 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
+EAPI=6
 
 inherit savedconfig toolchain-funcs
 
@@ -18,39 +18,31 @@ fi
 
 LICENSE="MIT"
 SLOT="0"
-IUSE="unicode"
 
-DEPEND="sys-libs/ncurses:0=[unicode?]"
-RDEPEND=${DEPEND}
+RDEPEND="sys-libs/ncurses:0=[unicode]"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+"
+PATCHES=(
+	"${FILESDIR}"/${PN}-9999-gentoo.patch
+)
 
 src_prepare() {
-	sed -i \
-		-e 's|FLAGS =|FLAGS +=|' \
-		-e 's|-I/usr/local/include||' \
-		-e 's|-L/usr/local/lib||' \
-		-e 's|-Os||' \
-		config.mk || die "sed config.mk failed"
-	use unicode || {
-		sed -i \
-			-e 's|-lncursesw|-lncurses|' \
-			config.mk || die "sed config.mk failed"
-	}
-	sed -i \
-		-e '/strip/d' \
-		-e 's:@tic :@tic -o ${DESTDIR}${PREFIX}/share/terminfo :g' \
-		Makefile || die "sed Makefile failed"
+	default
 
 	restore_config config.h
 }
 
 src_compile() {
+	tc-export PKG_CONFIG
 	local msg=""
 	use savedconfig && msg=", please check the configfile"
 	emake CC=$(tc-getCC) ${PN} || die "emake failed${msg}"
 }
 
 src_install() {
-	emake DESTDIR="${D}" PREFIX="/usr" install
+	emake DESTDIR="${D}" PREFIX="/usr" STRIP=true install
 
 	insinto /usr/share/${PN}
 	newins config.h ${PF}.config.h
diff --git a/app-misc/dvtm/files/dvtm-0.15-gentoo.patch b/app-misc/dvtm/files/dvtm-0.15-gentoo.patch
new file mode 100644
index 000000000000..3bb7dec3721f
--- /dev/null
+++ b/app-misc/dvtm/files/dvtm-0.15-gentoo.patch
@@ -0,0 +1,36 @@
+--- a/config.mk
++++ b/config.mk
+@@ -10,12 +10,12 @@
+ TERMINFO := ${DESTDIR}${PREFIX}/share/terminfo
+ 
+ INCS = -I.
+-LIBS = -lc -lutil -lncursesw
+-CPPFLAGS = -D_POSIX_C_SOURCE=200809L -D_XOPEN_SOURCE=700 -D_XOPEN_SOURCE_EXTENDED
++LIBS = -lc -lutil $(shell $(PKG_CONFIG) --libs ncursesw)
++CPPFLAGS += -D_POSIX_C_SOURCE=200809L -D_XOPEN_SOURCE=700 -D_XOPEN_SOURCE_EXTENDED
+ CFLAGS += -std=c99 ${INCS} -DVERSION=\"${VERSION}\" -DNDEBUG ${CPPFLAGS}
+ LDFLAGS += ${LIBS}
+ 
+-DEBUG_CFLAGS = ${CFLAGS} -UNDEBUG -O0 -g -ggdb -Wall -Wextra -Wno-unused-parameter
++DEBUG_CFLAGS += ${CFLAGS} -UNDEBUG -O0 -g -ggdb -Wall -Wextra -Wno-unused-parameter
+ 
+ CC ?= cc
+ STRIP ?= strip
+--- a/Makefile
++++ b/Makefile
+@@ -16,13 +16,13 @@
+ 
+ .c.o:
+ 	@echo CC $<
+-	@${CC} -c ${CFLAGS} $<
++	${CC} -c ${CFLAGS} $<
+ 
+ ${OBJ}: config.h config.mk
+ 
+ dvtm: ${OBJ}
+ 	@echo CC -o $@
+-	@${CC} -o $@ ${OBJ} ${LDFLAGS}
++	${CC} -o $@ ${OBJ} ${LDFLAGS}
+ 
+ debug: clean
+ 	@make CFLAGS='${DEBUG_CFLAGS}'
diff --git a/app-misc/dvtm/files/dvtm-9999-gentoo.patch b/app-misc/dvtm/files/dvtm-9999-gentoo.patch
new file mode 100644
index 000000000000..f29e316c3e5c
--- /dev/null
+++ b/app-misc/dvtm/files/dvtm-9999-gentoo.patch
@@ -0,0 +1,13 @@
+--- a/config.mk
++++ b/config.mk
+@@ -7,8 +7,8 @@
+ TERMINFO := ${DESTDIR}${PREFIX}/share/terminfo
+ 
+ INCS = -I.
+-LIBS = -lc -lutil -lncursesw
+-CPPFLAGS = -D_POSIX_C_SOURCE=200809L -D_XOPEN_SOURCE=700 -D_XOPEN_SOURCE_EXTENDED
++LIBS = -lc -lutil $(shell $(PKG_CONFIG) --libs ncursesw)
++CPPFLAGS += -D_POSIX_C_SOURCE=200809L -D_XOPEN_SOURCE=700 -D_XOPEN_SOURCE_EXTENDED
+ CFLAGS += -std=c99 ${INCS} -DNDEBUG ${CPPFLAGS}
+ 
+ CC ?= cc