app-backup/dar: drop 2.7.13

Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>

2 files changed, 0 insertions, 98 deletions

diff --git a/app-backup/dar/Manifest b/app-backup/dar/Manifest
index 110c3d5f8b0c..06ab9425b9ea 100644
--- a/app-backup/dar/Manifest
+++ b/app-backup/dar/Manifest
@@ -1,2 +1 @@
-DIST dar-2.7.13.tar.gz 2425559 BLAKE2B 321a43b04553505279de6f6b27e332883f4209bbe81e24c418188f028b7ba7a794d4e0f510f2c6a22a57fbdbc0501d4fcf7201aadb8cca3e65c6649bff7cfedf SHA512 e7a4bd89ccefaca1d9251d05c39e80f9861b8154f414cd578ba98c3cf3a9f945738c6225fd007b5e73c2d7c2e4abe547e9a2e2deec2cb7e0ec5860603add64fb
 DIST dar-2.7.14.tar.gz 2443548 BLAKE2B a68ad06a2bf53b25a0b393f3e85eef5676382d63bfd86ba77696667786a688e326c118d937cd5dae6b1e78410e40295c67d8ba4677c37f7139bbdd2794c4efeb SHA512 0436c67e0dbd8f5e96e01a0db48a469d80fb81a7c7f37aed98308bd55d60d699b21c755d95fa83891690231fd2510eaa6c6652fb99a1bad9c8210084031391d4
diff --git a/app-backup/dar/dar-2.7.13.ebuild b/app-backup/dar/dar-2.7.13.ebuild
deleted file mode 100644
index 88c8bb47d6cd..000000000000
--- a/app-backup/dar/dar-2.7.13.ebuild
+++ /dev/null
@@ -1,97 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit flag-o-matic
-
-DESCRIPTION="A full featured backup tool, aimed for disks"
-HOMEPAGE="http://dar.linux.free.fr/"
-SRC_URI="https://downloads.sourceforge.net/project/dar/dar/${PV}/${P}.tar.gz"
-
-LICENSE="GPL-2+"
-SLOT="0"
-KEYWORDS="amd64 ppc sparc x86 ~amd64-linux"
-IUSE="argon2 curl dar32 dar64 doc gcrypt gpg lz4 lzo nls rsync xattr"
-
-REQUIRED_USE="
-	?? ( dar32 dar64 )
-	gpg? ( gcrypt )
-"
-
-RESTRICT="test" # need to be run as root
-
-RDEPEND="
-	app-arch/bzip2:=
-	app-arch/xz-utils
-	app-arch/zstd:=
-	dev-libs/libthreadar
-	sys-libs/libcap
-	>=sys-libs/zlib-1.2.3:=
-	argon2? ( app-crypt/argon2:= )
-	curl? ( net-misc/curl )
-	gcrypt? (
-		dev-libs/libgcrypt:0=
-		dev-libs/libgpg-error
-	)
-	gpg? (
-		app-crypt/gpgme:=
-		dev-libs/libassuan
-	)
-	lz4? ( app-arch/lz4:= )
-	lzo? ( dev-libs/lzo:2 )
-	nls? ( virtual/libintl )
-	rsync? ( net-libs/librsync:= )
-	xattr? ( sys-apps/attr )
-"
-
-DEPEND="${RDEPEND}"
-
-BDEPEND="
-	doc? ( app-text/doxygen )
-	nls? ( sys-devel/gettext )
-"
-
-QA_PKGCONFIG_VERSION=""	#862025 - upstream has a different numbering scheme for libdar
-
-src_configure() {
-	# configure.ac is totally funked up regarding the AC_ARG_ENABLE
-	# logic.
-	# For example "--enable-dar-static" causes configure to DISABLE
-	# static builds of dar.
-	# Do _not_ use $(use_enable) until you have verified that the
-	# logic has been fixed by upstream.
-	local myconf=(
-		--disable-dar-static
-		--disable-python-binding
-		--disable-upx
-		$(usev !argon2 --disable-libargon2-linking)
-		$(usev !curl --disable-libcurl-linking)
-		$(usev dar32 --enable-mode=32)
-		$(usev dar64 --enable-mode=64)
-		$(usev !doc --disable-build-html)
-		$(usev !gcrypt --disable-libgcrypt-linking)
-		$(usev !gpg --disable-gpgme-linking)
-		$(usev !lz4 --disable-liblz4-linking)
-		$(usev !lzo --disable-liblzo2-linking)
-		$(usev !nls --disable-nls)
-		$(usev !rsync --disable-librsync-linking)
-		$(usev !xattr --disable-ea-support)
-	)
-
-	# Bug 103741
-	filter-flags -fomit-frame-pointer
-
-	econf "${myconf[@]}"
-}
-
-src_install() {
-	emake DESTDIR="${D}" pkgdatadir="${EPREFIX}"/usr/share/doc/${PF}/html install
-
-	einstalldocs
-
-	find "${ED}" -name "*.la" -delete || die
-
-	# Bug 729150
-	rm "${ED}/usr/share/doc/${PF}/html/samples/MyBackup.sh.tar.gz" || die
-}