sys-kernel/gentoo-kernel-bin: bump to 5.10.59-r1 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index fa1bfdb45eb9..c2aff59dd361 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -76,6 +76,7 @@ DIST gentoo-kernel-5.10.58-1.amd64.xpak 65511736 BLAKE2B 48f3bf825208658a833549e
 DIST gentoo-kernel-5.10.58-1.arm64.xpak 61161741 BLAKE2B fdeea503d632971e80739ae7abe10da20febfc1a5f7b1ccf73f8937f40a8daecf141b36e780b41903ebd3dd8a60eae66e7ce40b697f1b53b9fec13b1092ab320 SHA512 f48fcbdc395cc57c6a5c5e2d5e2e79598b563df843d11f10d9be2f209f36c78dc1700f23aaad2b1052a847dffac6b74eaf8f86df6caaea560199b1e250bd7c33
 DIST gentoo-kernel-5.10.58-1.x86.xpak 57234241 BLAKE2B 03e1fe1c0ee4a571564fba7b8095540e901e5f74e856f67ea03a389bcd3ab0f8a482aee0b74eb13494afe471b528748b58b24cbe653b4963466142e3a38126ef SHA512 01b4b4b33de3dd396d92d0b3e99c33413c5e936c85ca038caba94d53ed671b885312e5b1508897edf39de045e13c05d546b9053c9ef5b7700058a4a02db8cdd0
 DIST gentoo-kernel-5.10.59-1.amd64.xpak 65483612 BLAKE2B c4d11193b90c1ce87c7fa28ea07e3f416bf0184cb6f1866b7581bca4b2d817cb6c4ac20e081894d0b000c7b823a47fb9679fed239d2d6ea97dcd257c9a187261 SHA512 f10dc637d0ea60a2a4a52fe0e332f6c7d82ce8a4313abcfba4cc3ebaa64240b6f820dfb736cf42d1437c180c84b54824f98a994040d543fa2aaf150d15fc2131
+DIST gentoo-kernel-5.10.59-1.arm64.xpak 61218981 BLAKE2B 4b47ad4e03d5d823fe91037262f0aa0df6c918a6c832db82356ff77c2e2e382b66323e15e4e684f6de31de44786a6f5e05ff83a34268b27f6a9ba809e2cfb1ce SHA512 e715701d1e1103267a83f62d8ada47659e8c9d98d92255eb332e96f27191478da03fbc6401954f1f7990f89f82fce3af8cf0e2542ba9f2caaadd42e305e8acaf
 DIST gentoo-kernel-5.10.59-1.x86.xpak 57223109 BLAKE2B 07be7a4f1221832b360cbd47ec5e376616d9d248b7f93669ab290ced5f3cc2cd15d130d624437582319cd165e3bbe3ce579e324ec865a0289d9f951e2228bd96 SHA512 4b315dfb9b81d9dd5e9c4ca5320b1f4eee1d925cb99050a054593a07e2c3705cb5299309e26c25b721e227dc3223b36a7afce2c4a2476fa5ea9e488f73232265
 DIST gentoo-kernel-5.10.60-1.amd64.xpak 65504358 BLAKE2B 233766cf8fd62c2b70cf257a8bbf5dab9a45d1d10b508827c58593c7523b04e3843a69f51dd38798f5889447eae8a861f8b3cebe5985e48b63c65dbc7183ff4e SHA512 d547eee171746da27a4d1ebfce701b18c1e8fcded3c46c5ef875da6177645ed9088bdeed4188bb2d6746311ebe839b077e1a97ed5f9f7fa14ed2e43129701780
 DIST gentoo-kernel-5.10.60-1.x86.xpak 57229580 BLAKE2B 90b7d12883271c0ac49cfff5ece81fde229c2f9f5c27c21d19c4c97132dd091bb798d75332c72491178655d8350e30addf868df71562bbaf645af5705d49daeb SHA512 043d1a0c5cefc49188a444b2ccc85decae53a318ee759449af4b30922a46329d57e1fd45f40b5c74b74f08e0cc5edc2835ba8291be460dea9699a998b9e1a6ac
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.59-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.59-r1.ebuild
new file mode 100644
index 000000000000..9f8ae493e215
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.59-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 6 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}