Merge updates from master

6 files changed, 216 insertions, 5 deletions

diff --git a/app-crypt/qca/qca-2.3.6-r2.ebuild b/app-crypt/qca/qca-2.3.6-r2.ebuild
new file mode 100644
index 000000000000..0cdc05cdc7ad
--- /dev/null
+++ b/app-crypt/qca/qca-2.3.6-r2.ebuild
@@ -0,0 +1,115 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake kde.org multibuild qmake-utils
+
+DESCRIPTION="Qt Cryptographic Architecture (QCA)"
+HOMEPAGE="https://userbase.kde.org/QCA"
+SRC_URI="mirror://kde/stable/${PN}/${PV}/${P}.tar.xz"
+
+LICENSE="LGPL-2.1"
+SLOT="2"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="botan debug doc examples gcrypt gpg logger nss pkcs11 +qt5 qt6 sasl softstore +ssl test"
+REQUIRED_USE="|| ( qt5 qt6 )"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	botan? ( dev-libs/botan:3= )
+	gcrypt? ( dev-libs/libgcrypt:= )
+	gpg? ( app-crypt/gnupg )
+	nss? ( dev-libs/nss )
+	pkcs11? (
+		>=dev-libs/openssl-1.1
+		dev-libs/pkcs11-helper
+	)
+	qt5? ( >=dev-qt/qtcore-5.14:5 )
+	qt6? (
+		dev-qt/qtbase:6
+		dev-qt/qt5compat:6
+	)
+	sasl? ( dev-libs/cyrus-sasl:2 )
+	ssl? ( >=dev-libs/openssl-1.1:= )
+"
+DEPEND="${RDEPEND}
+	test? (
+		qt5? (
+			dev-qt/qtnetwork:5
+			dev-qt/qttest:5
+		)
+		qt6? ( dev-qt/qtbase:6[network,test] )
+	)
+"
+BDEPEND="
+	doc? (
+		app-doc/doxygen[dot]
+		virtual/latex-base
+	)
+"
+
+PATCHES=( "${FILESDIR}/${PN}-disable-pgp-test.patch" )
+
+qca_plugin_use() {
+	echo -DWITH_${2:-$1}_PLUGIN=$(usex "$1")
+}
+
+pkg_setup() {
+	MULTIBUILD_VARIANTS=( $(usev qt5) $(usev qt6) )
+}
+
+src_configure() {
+	myconfigure() {
+		local mycmakeargs=(
+			-DQCA_FEATURE_INSTALL_DIR="${EPREFIX}$(${MULTIBUILD_VARIANT}_get_mkspecsdir)/features"
+			-DQCA_PLUGINS_INSTALL_DIR="${EPREFIX}$(${MULTIBUILD_VARIANT}_get_plugindir)"
+			$(qca_plugin_use botan)
+			$(qca_plugin_use gcrypt)
+			$(qca_plugin_use gpg gnupg)
+			$(qca_plugin_use logger)
+			$(qca_plugin_use nss)
+			$(qca_plugin_use pkcs11)
+			$(qca_plugin_use sasl cyrus-sasl)
+			$(qca_plugin_use softstore)
+			$(qca_plugin_use ssl ossl)
+			-DBUILD_TESTS=$(usex test)
+		)
+		if [[ ${MULTIBUILD_VARIANT} == qt6 ]]; then
+				mycmakeargs+=( -DBUILD_WITH_QT6=ON )
+		else
+				mycmakeargs+=( -DBUILD_WITH_QT6=OFF )
+		fi
+		cmake_src_configure
+	}
+
+	multibuild_foreach_variant myconfigure
+}
+
+src_compile() {
+	multibuild_foreach_variant cmake_src_compile
+}
+
+src_test() {
+	mytest() {
+		local -x QCA_PLUGIN_PATH="${BUILD_DIR}/lib/qca"
+		cmake_src_test
+	}
+	multibuild_foreach_variant mytest
+}
+
+src_install() {
+	multibuild_foreach_variant cmake_src_install
+
+	if use doc; then
+		pushd "${BUILD_DIR}" >/dev/null || die
+		doxygen Doxyfile || die
+		dodoc -r apidocs/html
+		popd >/dev/null || die
+	fi
+
+	if use examples; then
+		dodoc -r "${S}"/examples
+	fi
+}
diff --git a/dev-ruby/connection_pool/Manifest b/dev-ruby/connection_pool/Manifest
index 27e4ac7a4de7..9bee1cb9a6be 100644
--- a/dev-ruby/connection_pool/Manifest
+++ b/dev-ruby/connection_pool/Manifest
@@ -1,3 +1,3 @@
-DIST connection_pool-2.2.5.gem 14848 BLAKE2B d3e21e5d3c330fb501e9890260c0fed003f3c8afc6a9106c139f77e879c45232de1cbc16be6088c757a1204f3c64b0797010fddc0d1c9cf555389348b6f61152 SHA512 3bc4e4d241cd4b1adb00d341aafe7795bbf0eff459ace962670d83c20c0eaa0d42f49a1f5e61c2327ff4fcbf3abfbc6f6c910f7a31d4a0f62bc55c782ab20e45
 DIST connection_pool-2.3.0.tar.gz 10656 BLAKE2B 235ddcf6956c53bff276c27b47f3dd21f008cad4eea07692cad186117e6d6a986acb1fa1e2eeb29a9bb72f5ee5e3b7c80927e711ebdf00ceec9af2f02ca37e25 SHA512 8f9c9c1c738b5321b52c28033bb7ac8f6697edfe584f858ce4891514c65730ccb950db9136f059991c4fe1d1386b18883d7b61557aeeb687c602a09229dcb38f
 DIST connection_pool-2.4.0.tar.gz 11243 BLAKE2B b8fcb164473863dfa4d4cd0a2f511f006ab0369a3890639115b42755eb6a50f1e8e37e1b2bdba0a4ac203ef05e5fde84cc95b0f10f547b56effbaa19df0ee64e SHA512 7b3d732da657ecdd1ebe2fa1600c0d723496be9c89397db3da06d854daba07aa959750527ec2c08bdf5a41e30df2ee04407fe76260440848db9b426c508a3544
+DIST connection_pool-2.4.1.tar.gz 11425 BLAKE2B 17aae4f8ce0461554eaddb4ee3535062608d75a29219ca44b1535f087db39429ddbc591d996c020b1fa557337e75bb15b0ac218e8b9f393f94e32e70ffe76800 SHA512 4529446de89d01adee28127807fe104ada683866bc61b60ee77acb718881aced982aa1a1e6e2330077d79ed3d77af199e8612a6dc08de4c40468ac4e3623b799
diff --git a/dev-ruby/connection_pool/connection_pool-2.2.5.ebuild b/dev-ruby/connection_pool/connection_pool-2.4.1.ebuild
index 874f8711c51d..38cf2c565b28 100644
--- a/dev-ruby/connection_pool/connection_pool-2.2.5.ebuild
+++ b/dev-ruby/connection_pool/connection_pool-2.4.1.ebuild
@@ -1,9 +1,10 @@
-# Copyright 1999-2022 Gentoo Authors
+# Copyright 1999-2023 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
-USE_RUBY="ruby26 ruby27 ruby30 ruby31"
+EAPI=8
+USE_RUBY="ruby30 ruby31 ruby32"
 
+RUBY_FAKEGEM_GEMSPEC="connection_pool.gemspec"
 RUBY_FAKEGEM_RECIPE_TEST="rake"
 RUBY_FAKEGEM_RECIPE_DOC="none"
 RUBY_FAKEGEM_EXTRADOC="Changes.md README.md"
@@ -12,10 +13,11 @@ inherit ruby-fakegem
 
 DESCRIPTION="Generic connection pooling for Ruby"
 HOMEPAGE="https://github.com/mperham/connection_pool"
+SRC_URI="https://github.com/mperham/connection_pool/archive/v${PV}.tar.gz -> ${P}.tar.gz"
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc x86"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
 IUSE=""
 
 ruby_add_bdepend "test? ( >=dev-ruby/minitest-5 )"
diff --git a/eclass/qmake-utils.eclass b/eclass/qmake-utils.eclass
index 88755ab7aa8a..5c5fa8dcb047 100644
--- a/eclass/qmake-utils.eclass
+++ b/eclass/qmake-utils.eclass
@@ -155,4 +155,63 @@ qt6_get_plugindir() {
 	echo $(qt6_get_libdir)/qt6/plugins
 }
 
+# @FUNCTION: qt6_get_qmake_args
+# @DESCRIPTION:
+# Echoes a multi-line string containing arguments to pass to qmake.
+qt6_get_qmake_args() {
+	cat <<-EOF
+		QMAKE_AR="$(tc-getAR) cqs"
+		QMAKE_CC="$(tc-getCC)"
+		QMAKE_LINK_C="$(tc-getCC)"
+		QMAKE_LINK_C_SHLIB="$(tc-getCC)"
+		QMAKE_CXX="$(tc-getCXX)"
+		QMAKE_LINK="$(tc-getCXX)"
+		QMAKE_LINK_SHLIB="$(tc-getCXX)"
+		QMAKE_OBJCOPY="$(tc-getOBJCOPY)"
+		QMAKE_RANLIB=
+		QMAKE_STRIP=
+		QMAKE_CFLAGS="${CFLAGS}"
+		QMAKE_CFLAGS_RELEASE=
+		QMAKE_CFLAGS_DEBUG=
+		QMAKE_CFLAGS_RELEASE_WITH_DEBUGINFO=
+		QMAKE_CXXFLAGS="${CXXFLAGS}"
+		QMAKE_CXXFLAGS_RELEASE=
+		QMAKE_CXXFLAGS_DEBUG=
+		QMAKE_CXXFLAGS_RELEASE_WITH_DEBUGINFO=
+		QMAKE_LFLAGS="${LDFLAGS}"
+		QMAKE_LFLAGS_RELEASE=
+		QMAKE_LFLAGS_DEBUG=
+		QMAKE_LFLAGS_RELEASE_WITH_DEBUGINFO=
+	EOF
+}
+
+# @FUNCTION: eqmake6
+# @USAGE: [arguments for qmake]
+# @DESCRIPTION:
+# Wrapper for Qt6's qmake. All arguments are passed to qmake.
+#
+# For recursive build systems, i.e. those based on the subdirs template,
+# you should run eqmake6 on the top-level project file only, unless you
+# have a valid reason to do otherwise. During the building, qmake will
+# be automatically re-invoked with the right arguments on every directory
+# specified inside the top-level project file.
+eqmake6() {
+	debug-print-function ${FUNCNAME} "$@"
+
+	ebegin "Running qmake"
+
+	local -a args
+	mapfile -t args <<<"$(qt6_get_qmake_args)"
+	# NB: we're passing literal quotes in but qmake doesn't seem to mind
+	"$(qt6_get_bindir)"/qmake -makefile "${args[@]}" "$@"
+
+	if ! eend $? ; then
+		echo
+		eerror "Running qmake has failed! (see above for details)"
+		eerror "This shouldn't happen - please send a bug report to https://bugs.gentoo.org/"
+		echo
+		die "eqmake6 failed"
+	fi
+}
+
 fi
diff --git a/www-apps/klaus/Manifest b/www-apps/klaus/Manifest
index 9cde6004cc56..f18d5856d648 100644
--- a/www-apps/klaus/Manifest
+++ b/www-apps/klaus/Manifest
@@ -1 +1,2 @@
 DIST klaus-2.0.2.tar.gz 43030 BLAKE2B ba3a1d07d92ab02e43a31f9e720e26bafc744c2867b8bd6cf300d6e2fdcbcb560a426e8cf55bd6d8c11d23775ae5beddb8fd3ee89c3b0f21302bb463cc2571f3 SHA512 87aa4943d4e918c7ac9c269c095b8381b9e367ed68a50fb70bd75e02ec723c379d0ceaa2da9d5b81484b4c308941283dd2fb58046ba18e0950611c51b2337edd
+DIST klaus-2.0.3.tar.gz 46961 BLAKE2B 29d84ccf829853f091f8bc944e4bf0ec119e1a2dcf67c7d82561a0924cc60634ec67580b6d9103fe33e7a4f40dc909d9dd04f1765441b9dbfd2638adad91df48 SHA512 81bb1ecd01555bb3e49b4fa482e8bfc679b9754047508201467640bab25e56e3f109339efa419f00b05d99d27138a16ab5fb7c3578792992e343653eb175fc1e
diff --git a/www-apps/klaus/klaus-2.0.3.ebuild b/www-apps/klaus/klaus-2.0.3.ebuild
new file mode 100644
index 000000000000..41b3713ceb0a
--- /dev/null
+++ b/www-apps/klaus/klaus-2.0.3.ebuild
@@ -0,0 +1,34 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A simple, easy-to-set-up Git web viewer"
+HOMEPAGE="https://github.com/jonashaag/klaus/"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="ctags"
+
+RDEPEND="
+	>=dev-python/dulwich-0.19.3[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/httpauth[${PYTHON_USEDEP}]
+	dev-python/humanize[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	ctags? ( dev-python/python-ctags3[${PYTHON_USEDEP}] )
+"
+
+# The tests can only be run from a git repository
+# so they are not included in the source distributions
+
+python_install_all() {
+	distutils-r1_python_install_all
+	doman ${PN}.1
+}