dev-util/diffoscope: add 283

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 141 insertions, 0 deletions

diff --git a/dev-util/diffoscope/Manifest b/dev-util/diffoscope/Manifest
index 6e9774fd6b68..7a4ccc648a0d 100644
--- a/dev-util/diffoscope/Manifest
+++ b/dev-util/diffoscope/Manifest
@@ -2,3 +2,4 @@ DIST diffoscope-272.tar.bz2 3155265 BLAKE2B 76f8475993dc8be7297b50a2dda71b965789
 DIST diffoscope-277.tar.bz2 3143869 BLAKE2B 98f0356060c8430236941ff9ef45c51d34d681a0cb8f8085bf40775aaa98c4c97add603d954b235f8615c539fb591eab3d812261f3b33dbeaee8418fabeeb5af SHA512 7ecc32204ed420ca2547976bd0548f4b9a4dd2cebacbeb2a3faf0fa6ac4015724abb6a764a81f20aea20dafc871b7fb262eeac81b86a1cd9cdfa42353178ea0f
 DIST diffoscope-279.tar.bz2 3146297 BLAKE2B 7dc1c2a8362db6c012be04aa2562a04079707502d6f61e4ee0093fe46042ad122fe73d1faaf81e6b565d369ba3ec83f6056c4ef62a6fe4649ed376d0404b2864 SHA512 564e731847cbc68a6d8612f543d9d40575c4e9240acc7ec405310878c9288566a5c6dd4aa87e2517db5ef1abcc4ab6e29d3002ee5cce281200d9381de103243b
 DIST diffoscope-282.tar.bz2 3149915 BLAKE2B 32378adc17210054f5d8adb0e3396f16bbab214c83a138cc0b732085bdec3d0215e5329bcf8c9044e055556e3d04002253b52130590f1e7dc7cfaaefafcc9296 SHA512 5f049054b03940bb97a95cf60a1f7510ed3fbe1b14494f15edc872ecfc1f76a219f8255a4e7a574d9fecf47b75500c8f794c72bc508137e9051c451ba9bbb346
+DIST diffoscope-283.tar.bz2 3149385 BLAKE2B e50e4c31912c7bb0acaa3152c869937a9f4cbbcb0860775c58bbde13808ffcd0183032f7b444b2fb4d6cea83f943ac15f36a648a0f9fcbaaae5cfde098232d97 SHA512 e0c6ddd7b687b93dafdab81408d285b385efb3e2dd5c78c378943f03054e6ca59a18b6be7879023b54a571b18c5ada2722773626553761f245460abd239faef9
diff --git a/dev-util/diffoscope/diffoscope-283.ebuild b/dev-util/diffoscope/diffoscope-283.ebuild
new file mode 100644
index 000000000000..f7fae2952726
--- /dev/null
+++ b/dev-util/diffoscope/diffoscope-283.ebuild
@@ -0,0 +1,140 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+PYTHON_REQ_USE="ncurses"
+inherit distutils-r1 toolchain-funcs
+
+DESCRIPTION="Will try to get to the bottom of what makes files or directories different"
+HOMEPAGE="https://diffoscope.org/ https://pypi.org/project/diffoscope/"
+# We could use pypi, but upstream provide distribution tarballs, so let's use those.
+# TODO: verify-sig
+SRC_URI="https://diffoscope.org/archive/${P}.tar.bz2"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="acl binutils bzip2 libcaca colord cpio +diff docx dtc e2fsprogs file
+find gettext gif gpg haskell hdf5 hex imagemagick iso java llvm lzma
+mono opendocument pascal pdf postscript R rpm sqlite squashfs
+ssh tar test tcpdump zip zlib zstd"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	|| (
+		dev-python/python-magic[${PYTHON_USEDEP}]
+		sys-apps/file[python,${PYTHON_USEDEP}]
+	)
+	dev-python/libarchive-c[${PYTHON_USEDEP}]
+	dev-python/distro[${PYTHON_USEDEP}]
+	dev-python/python-tlsh[${PYTHON_USEDEP}]
+	acl? ( sys-apps/acl )
+	binutils? ( sys-devel/binutils )
+	bzip2? ( app-arch/bzip2 )
+	libcaca? ( media-libs/libcaca )
+	colord? ( x11-misc/colord )
+	cpio? ( app-alternatives/cpio )
+	diff? ( sys-apps/diffutils )
+	docx? ( app-text/docx2txt )
+	dtc? ( sys-apps/dtc )
+	e2fsprogs? ( sys-fs/e2fsprogs )
+	file? ( sys-apps/file )
+	find? ( sys-apps/findutils )
+	gettext? ( sys-devel/gettext )
+	gif? ( media-libs/giflib )
+	gpg? ( app-crypt/gnupg )
+	haskell? ( dev-lang/ghc )
+	hdf5? ( sci-libs/hdf5 )
+	hex? ( app-editors/vim-core )
+	imagemagick? ( media-gfx/imagemagick )
+	iso? ( app-cdr/cdrtools )
+	java? ( virtual/jdk )
+	llvm? ( sys-devel/llvm )
+	lzma? ( app-arch/xz-utils )
+	mono? ( dev-lang/mono )
+	opendocument? ( app-text/odt2txt )
+	pascal? ( dev-lang/fpc )
+	pdf? (
+		app-text/pdftk
+		app-text/poppler
+		dev-python/pypdf[${PYTHON_USEDEP}]
+	)
+	postscript? ( app-text/ghostscript-gpl )
+	R? ( dev-lang/R )
+	rpm? ( app-arch/rpm )
+	sqlite? ( dev-db/sqlite:3 )
+	squashfs? ( sys-fs/squashfs-tools )
+	ssh? ( virtual/openssh )
+	tar? ( app-arch/tar )
+	tcpdump? ( net-analyzer/tcpdump )
+	zip? ( app-arch/unzip )
+	zlib? ( app-arch/gzip )
+	zstd? ( app-arch/zstd )
+"
+
+# pull in optional tools for tests:
+# img2txt: bug #797688
+# docx2txt: bug #797688
+BDEPEND="
+	test? (
+		app-arch/p7zip
+		app-text/docx2txt
+		app-text/html2text
+		media-libs/libcaca
+		virtual/imagemagick-tools[jpeg]
+	)
+"
+
+EPYTEST_DESELECT=(
+	# Test seems to use different tarball
+	tests/test_presenters.py::test_text_proper_indentation
+
+	# Needs triage
+	tests/comparators/test_binary.py::test_with_compare_details_and_tool_not_found
+	tests/comparators/test_rlib.py::test_item3_deflate_llvm_bitcode
+	tests/comparators/test_gif.py::test_has_visuals
+
+	# img2txt based failures, bug #797688
+	tests/comparators/test_ico_image.py::test_diff
+	tests/comparators/test_ico_image.py::test_diff_meta
+	tests/comparators/test_ico_image.py::test_diff_meta2
+	tests/comparators/test_ico_image.py::test_has_visuals
+	tests/comparators/test_jpeg_image.py::test_diff
+	tests/comparators/test_jpeg_image.py::test_compare_non_existing
+	tests/comparators/test_jpeg_image.py::test_diff_meta
+	tests/comparators/test_jpeg_image.py::test_has_visuals
+
+	# docx2txt based falures, bug #797688
+	tests/comparators/test_docx.py::test_diff
+
+	# Formatting
+	tests/test_source.py::test_code_is_black_clean
+
+	# Fails on ZFS
+	tests/test_main.py::test_non_unicode_filename
+
+	# Fails on (unreleased) LLVM 16 with minor difference
+	#tests/comparators/test_macho.py::test_llvm_diff
+	#tests/comparators/test_elf.py::test_libmix_differences
+)
+
+distutils_enable_tests pytest
+
+src_test() {
+	case $(tc-get-ptr-size) in
+		4)
+			EPYTEST_IGNORE+=(
+				# Needs fixing in Perl itself (bug #934443)
+				tests/comparators/test_epub.py
+				tests/comparators/test_zip.py
+			)
+			;;
+		*)
+			;;
+	esac
+
+	distutils-r1_src_test
+}