www-apps/freshrss: new package, add 1.23.1

Signed-off-by: Julien Roy <julien@jroy.ca>

3 files changed, 76 insertions, 0 deletions

diff --git a/www-apps/freshrss/Manifest b/www-apps/freshrss/Manifest
new file mode 100644
index 000000000..37b916270
--- /dev/null
+++ b/www-apps/freshrss/Manifest
@@ -0,0 +1 @@
+DIST freshrss-1.23.1.gh.tar.gz 4321975 BLAKE2B 583fe3895b2d7b82d77c202bed985de46214affc3e35f022e64a818954667f10b4838f1c25854394b9896f834b21b0af1265f32936110329202bd7dfd275ced2 SHA512 df4c7eedf3dc8c5c9d0de722e00e3846d1bb1b1605d53a9415b5fd49715b91d6cf22f7f64503a706af32dc6f96415e28d772f7442816e76e266b4aa908984e95
diff --git a/www-apps/freshrss/freshrss-1.23.1.ebuild b/www-apps/freshrss/freshrss-1.23.1.ebuild
new file mode 100644
index 000000000..e599f8e58
--- /dev/null
+++ b/www-apps/freshrss/freshrss-1.23.1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit webapp
+
+DESCRIPTION="A free, self-hostable news aggregator"
+HOMEPAGE="
+	https://freshrss.org/
+	https://github.com/FreshRSS/FreshRSS
+"
+SRC_URI="https://github.com/FreshRSS/FreshRSS/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}/FreshRSS-${PV}"
+
+LICENSE="AGPL-3"
+KEYWORDS="~amd64"
+IUSE="mysql +postgres sqlite"
+REQUIRED_USE="|| ( mysql postgres sqlite )"
+
+RDEPEND="
+	dev-lang/php[ctype,curl,fileinfo,fpm,jit,mysql?,pdo,postgres?,sqlite?,unicode,xml,zip,zlib]
+	virtual/httpd-php
+"
+DEPEND="${RDEPEND}"
+
+need_httpd_fastcgi
+
+src_compile() {
+	:
+}
+
+src_install() {
+	webapp_src_preinst
+
+	insinto "${MY_HTDOCSDIR}"
+	doins -r .
+
+	webapp_serverowned "${MY_HTDOCSDIR}"/data
+	webapp_serverowned "${MY_HTDOCSDIR}"/data/{index.html,cache,favicons,fever,users,users/_,tokens}
+	webapp_serverowned "${MY_HTDOCSDIR}"/data/{cache,favicons,fever,users,users/_,tokens}/index.html
+
+	webapp_src_install
+}
diff --git a/www-apps/freshrss/metadata.xml b/www-apps/freshrss/metadata.xml
new file mode 100644
index 000000000..9a1196601
--- /dev/null
+++ b/www-apps/freshrss/metadata.xml
@@ -0,0 +1,31 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<name>Julien Roy</name>
+		<email>julien@jroy.ca</email>
+	</maintainer>
+	<longdescription>
+FreshRSS is a self-hosted RSS feed aggregator.
+
+It is lightweight, easy to work with, powerful, and customizable.
+
+It is a multi-user application with an anonymous reading mode. It supports custom tags. There is an API for (mobile) clients, and a Command-Line Interface.
+
+Thanks to the WebSub standard, FreshRSS is able to receive instant push notifications from compatible sources, such as Friendica, WordPress, Blogger, Medium, etc.
+
+FreshRSS natively supports basic Web scraping, based on XPath, for Web sites not providing any RSS / Atom feed. Also supports JSON documents.
+
+FreshRSS offers the ability to reshare selections of articles by HTML, RSS, and OPML.
+
+Different login methods are supported: Web form (including an anonymous option), HTTP Authentication (compatible with proxy delegation), OpenID Connect.
+
+Finally, FreshRSS supports extensions for further tuning.
+	</longdescription>
+	<upstream>
+		<bugs-to>https://github.com/FreshRSS/FreshRSS/issues</bugs-to>
+		<changelog>https://github.com/FreshRSS/FreshRSS/releases</changelog>
+		<doc>https://freshrss.github.io/FreshRSS/</doc>
+		<remote-id type="github">FreshRSS/FreshRSS</remote-id>
+	</upstream>
+</pkgmetadata>