gui-wm/phoc: add 0.40.0

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

2 files changed, 116 insertions, 0 deletions

diff --git a/gui-wm/phoc/Manifest b/gui-wm/phoc/Manifest
index 9b16e87f9..dba992cae 100644
--- a/gui-wm/phoc/Manifest
+++ b/gui-wm/phoc/Manifest
@@ -2,3 +2,5 @@ DIST phoc-0.36.0.tar.xz 681384 BLAKE2B 6c27c785dd01f9e44cb0940c5a4f73d5ce75cad85
 DIST phoc-0.36.0.tar.xz.asc 833 BLAKE2B 0562c02dcb5d1618b3a316c4c36e4757f4729adf99b8ac748ed52c1bdcad6b65bc9fdb98462375e80f6898d699c6e237e4aa5057631434235166ca616de7d2e6 SHA512 2108eed0a0723c743d86eee9f517a9c8505faf8f55a32eb60ee9da04ae53221b00520ca9e422397617d1bde6f1047ba2ebdf6d45211df052b9b2cfa2d3ea12fe
 DIST phoc-0.38.0.tar.xz 694784 BLAKE2B 51aef1cb1a4e753278727c8311b7aadfb9c18cbdf820725487c837bd0f943e6c7a0420a502e0316ba4ba96cb861a13d1f6a8cdcd9d1a5b51e75e5ecb9bdcf6f7 SHA512 739fb382336885b78ca3f50f8c5f6ddf3bc308a2158663c49c84ce506d2edf0c8d0dcd412e634eccf848d420bb5923d42ebc02044f7acf322b3ab621ffa4cd23
 DIST phoc-0.38.0.tar.xz.asc 833 BLAKE2B 63dd885cda46b90f5edd56289b9114d31726a543608f5a3f02f52848713a01d06e7e8a8660797c98c3504c3c59fe485ab92e58eaf7689c185d26e41027b96b30 SHA512 f69533ed5d1bce220ea66ae4f6307620178609b6c4d9ed743d0cd62f9944faf3dd76e7fce242e722b6912246e268b466ee0bf52326b39907c78d7f6c8eceabda
+DIST phoc-0.40.0.tar.xz 682564 BLAKE2B 97c04902d51118e4d08ce7d9ac7aa04d0e513cf6c3d20dc0e9812c4a9cf97292600a1d5e8205373b67739b829940ea17a2ee9f1e4cb0c72ce9f3651d9fbe9dff SHA512 3d3223ca7f2d3e865c3aa7924447d638b9dd7fef054f71ce667d545d1eeb5d13082e87093adc654426e7dec44e28df41858ef03bb3bb7d0c6c815e1bc958c855
+DIST phoc-0.40.0.tar.xz.asc 833 BLAKE2B 102b5c8405b0393330afb6c5e33df2a41e8ce7fea11eae8c959ef4fd7a9183bf4ec94743241bb8d8c8e07071484d8d831022b1858a43b5db11e2d8785cbc88be SHA512 df8abb534374bdc4af1849e3bf7ecbb4ff5d6bc57226a52cfdb0a95d349e167674cd0e7ee0eb223229c7a37c29eb17a7913d613f0bf1bd93451168cba94ca602
diff --git a/gui-wm/phoc/phoc-0.40.0.ebuild b/gui-wm/phoc/phoc-0.40.0.ebuild
new file mode 100644
index 000000000..5feb85ee8
--- /dev/null
+++ b/gui-wm/phoc/phoc-0.40.0.ebuild
@@ -0,0 +1,114 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2-utils meson verify-sig virtualx xdg
+
+DESCRIPTION="Wayland compositor for mobile phones"
+HOMEPAGE="https://gitlab.gnome.org/World/Phosh/phoc"
+SRC_URI="https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz
+	verify-sig? ( https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz.asc )
+"
+
+LICENSE="|| ( GPL-3+ MIT ) GPL-3+ LGPL-2.1+ MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="gtk-doc man test"
+RESTRICT="!test? ( test )"
+
+WLROOTS_DEPEND="
+	>=dev-libs/libinput-1.14.0:=
+	>=dev-libs/wayland-1.22.0
+	media-libs/libdisplay-info
+	media-libs/libglvnd
+	|| (
+		>=media-libs/mesa-24.1.0_rc1[opengl]
+		<media-libs/mesa-24.1.0_rc1[egl(+),gles2]
+	)
+	sys-apps/hwdata
+	sys-auth/seatd:=
+	x11-base/xwayland
+	x11-libs/cairo
+	>=x11-libs/libdrm-2.4.114
+	x11-libs/libxcb:=
+	x11-libs/libxkbcommon
+	>=x11-libs/pixman-0.42.0
+	x11-libs/xcb-util-errors
+	x11-libs/xcb-util-renderutil
+	x11-libs/xcb-util-wm
+	virtual/libudev
+	amd64? ( >=dev-libs/libliftoff-0.4 )
+"
+COMMON_DEPEND="${WLROOTS_DEPEND}
+	>=dev-libs/glib-2.74:2
+	dev-libs/gmobile
+	dev-libs/libinput:=
+	dev-libs/wayland
+	>=gnome-base/gnome-desktop-3.26:3
+	gnome-base/gsettings-desktop-schemas
+	x11-libs/pixman
+	x11-libs/libxcb:=
+	x11-libs/libxkbcommon
+"
+DEPEND="${COMMON_DEPEND}
+	test? ( x11-wm/mutter )
+"
+RDEPEND="${COMMON_DEPEND}"
+BDEPEND="
+	dev-libs/glib:2
+	dev-libs/wayland-protocols
+	dev-util/wayland-scanner
+	sys-devel/gettext
+	gtk-doc? ( dev-util/gi-docgen )
+	man? ( dev-python/docutils )
+	verify-sig? ( sec-keys/openpgp-keys-phosh )
+"
+
+VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/phosh.asc"
+
+src_prepare() {
+	default
+
+	cd subprojects/wlroots || die
+	eapply "${S}"/subprojects/packagefiles/wlroots
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use man)
+		$(meson_use test tests)
+		-Ddefault_library=static
+		-Dembed-wlroots=enabled
+		-Dxwayland=enabled
+	)
+	meson_src_configure
+}
+
+src_test() {
+	local -x LC_ALL="C.UTF-8"
+	virtx meson_src_test
+}
+
+src_install() {
+	meson_src_install --skip-subprojects wlroots
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/${PN}-${SLOT} "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+
+	newbin helpers/auto-maximize phoc-auto-maximize
+	newbin helpers/scale-to-fit phoc-scale-to-fit
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}