blob: 1ec445c23993dc015f24482c6cdbcd49cb5dc020 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
|
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-libs/nlopt/nlopt-2.3-r1.ebuild,v 1.1 2012/08/03 17:43:29 bicatali Exp $
EAPI=4
SUPPORT_PYTHON_ABIS="1"
PYTHON_DEPEND="python? *"
RESTRICT_PYTHON_ABIS="3.* 2.7-pypy-* *-jython"
AUTOTOOLS_AUTORECONF=1
inherit autotools-utils python
DESCRIPTION="Non-linear optimization library"
HOMEPAGE="http://ab-initio.mit.edu/nlopt/"
SRC_URI="${HOMEPAGE}/${P}.tar.gz"
LICENSE="LGPL-2.1 MIT"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
SLOT="0"
IUSE="cxx guile octave python static-libs"
DEPEND="
guile? ( dev-scheme/guile )
octave? ( sci-mathematics/octave )
python? ( dev-python/numpy )"
RDEPEND="${DEPEND}"
PATCHES=(
"${FILESDIR}"/${PN}-2.2.4-fix-nlopt_hpp-location.patch
"${FILESDIR}"/${PN}-2.3-pkgconfig.patch
"${FILESDIR}"/${PN}-2.3-as-needed.patch
)
src_prepare() {
autotools-utils_src_prepare
if use python; then
sed -i \
-e '/^LTLIBRARIES/s:$(pyexec_LTLIBRARIES)::g' \
swig/Makefile.in || die
echo '#!/bin/sh' > py-compile
fi
use python && python_src_prepare
}
src_configure() {
if use octave; then
export OCT_INSTALL_DIR="${EPREFIX}"/usr/libexec/octave/site/oct/${CHOST}
export M_INSTALL_DIR="${EPREFIX}"/usr/share/octave/site/m
else
export MKOCTFILE=None
fi
local myeconfargs=(
$(use_with cxx)
$(use_with guile)
$(use_with octave)
$(use_with python)
)
autotools-utils_src_configure
}
src_compile() {
autotools-utils_src_compile
if use python; then
python_copy_sources swig
compilation() {
autotools-utils_src_compile \
PYTHON_CPPFLAGS="-I${EPREFIX}$(python_get_includedir)" \
PYTHON_LDFLAGS="${EPREFIX}$(python_get_library -l)" \
PYTHON_SITE_PKG="${EPREFIX}$(python_get_sitedir)" \
PYTHON_VERSION="${EPREFIX}$(python_get_version)" \
PYTHON_INCLUDES="${EPREFIX}$(python_get_includedir)" \
pythondir="${EPREFIX}$(python_get_sitedir)" \
pyexecdir="${EPREFIX}$(python_get_sitedir)"
}
python_execute_function -s --source-dir swig compilation
fi
}
src_test() {
cd "${AUTOTOOLS_BUILD_DIR}"/test
local a f
for a in {1..9}; do
for f in {5..9}; do
./testopt -a $a -o $f || die "algorithm $a function $f failed"
done
done
}
src_install() {
autotools-utils_src_install
if use python; then
installation() {
cd "${AUTOTOOLS_BUILD_DIR}"
rm *.la
emake DESTDIR=${D} install \
pyexecdir="${EPREFIX}$(python_get_sitedir)" \
pythondir="${EPREFIX}$(python_get_sitedir)"
}
python_execute_function -s --source-dir swig installation
python_clean_installation_image
fi
local r
for r in */README; do newdoc ${r} README.$(dirname ${r}); done
}
pkg_postinst() {
use python && python_mod_optimize ${PN}.py
}
pkg_postrm() {
use python && python_mod_cleanup ${PN}.py
}
|
GitWeb