net-misc/putty/putty-20040313-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72

# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/putty/putty-20040313-r1.ebuild,v 1.1 2004/05/06 09:10:12 taviso Exp $

inherit eutils

DESCRIPTION="UNIX port of the famous Telnet and SSH client"

HOMEPAGE="http://www.chiark.greenend.org.uk/~sgtatham/putty/"
SRC_URI="mirror://gentoo/putty-cvs-${PV}.tar.bz2"
LICENSE="MIT"

SLOT="0"
KEYWORDS="~x86 ~alpha ~ppc ~sparc"
IUSE="doc"

RDEPEND="=x11-libs/gtk+-1.2* virtual/x11"

DEPEND="${RDEPEND} dev-lang/perl sys-apps/sed"

S=${WORKDIR}/${PN}

src_unpack() {
	# unpack the tarball...
	unpack ${A}

	# generate the makefiles
	ebegin "Generating Makefiles"
	cd ${S}; ${S}/mkfiles.pl
	eend $?

	# change the CFLAGS to those requested by user.
	ebegin "Setting CFLAGS"
	sed -i "s!-O2!${CFLAGS}!g" ${S}/unix/Makefile.gtk
	eend $?
}

src_compile() {
	# build putty.
	einfo "Building putty..."
	cd ${S}/unix; emake -f Makefile.gtk || die
}

src_install() {

	cd ${S}/unix

	# man pages...
	doman plink.1 pterm.1 putty.1 puttytel.1

	# binaries...
	dobin plink pterm putty puttytel psftp pscp

	cd ${S}

	# docs...
	dodoc README README.txt LICENCE CHECKLST.txt LATEST.VER website.url MODULE
	use doc && dodoc doc/*

	prepallman

	# install desktop file provided by Gustav Schaffter in #49577
	dodir /usr/share/applications
	insinto /usr/share/applications
	doins ${FILESDIR}/putty.desktop

	if test ! -c /dev/ptmx; then
		ewarn
		ewarn "The pterm application requires kernel UNIX98 PTY support to operate."
		ewarn
	fi
}