blob: 927499c58bb96a8fa45b76e878eb0e221723e691 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
|
# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/screen/screen-4.0.2-r4.ebuild,v 1.15 2005/09/16 22:20:56 spb Exp $
inherit eutils flag-o-matic toolchain-funcs pam
DESCRIPTION="Screen is a full-screen window manager that multiplexes a physical terminal between several processes"
HOMEPAGE="http://www.gnu.org/software/screen/"
SRC_URI="mirror://gnu/screen/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="alpha amd64 arm hppa ia64 mips ppc ppc64 s390 sh sparc x86"
IUSE="debug nethack pam"
RDEPEND=">=sys-libs/ncurses-5.2
pam? ( virtual/pam )
selinux? (
sec-policy/selinux-screen
>=sec-policy/selinux-base-policy-20050821
)"
DEPEND="${RDEPEND}
>=sys-devel/autoconf-2.58"
src_unpack() {
unpack ${A}
cd "${S}"
# Bug 34599: integer overflow in 4.0.1
# (Nov 29 2003 -solar)
epatch "${FILESDIR}"/screen-4.0.1-int-overflow-fix.patch
# Bug 31070: configure problem which affects alpha
# (13 Jan 2004 agriffis)
epatch "${FILESDIR}"/screen-4.0.1-vsprintf.patch
# uclibc doesnt have sys/stropts.h
if ! (echo '#include <sys/stropts.h>' | $(tc-getCC) -E - >& /dev/null) ; then
epatch "${FILESDIR}"/${PV}-no-pty.patch
fi
# Don't use utempter even if it is found on the system
epatch "${FILESDIR}"/${PV}-no-utempter.patch
# Don't link against libelf even if it is found on the system
epatch "${FILESDIR}"/${PV}-no-libelf.patch
# Patch for time function on 64bit systems
epatch "${FILESDIR}"/${PV}-64bit-time.patch
# Patch that makes %u work for windowlist -b formats
epatch "${FILESDIR}"/${PV}-windowlist-multiuser-fix.patch
# Fix manpage.
sed -i \
-e "s:/usr/local/etc/screenrc:/etc/screenrc:g" \
-e "s:/usr/local/screens:/var/run/screen:g" \
-e "s:/local/etc/screenrc:/etc/screenrc:g" \
-e "s:/etc/utmp:/var/run/utmp:g" \
-e "s:/local/screens/S-:/var/run/screen/S-:g" \
doc/screen.1 \
|| die "sed doc/screen.1 failed"
# configure as delivered with screen is made with autoconf-2.5
WANT_AUTOCONF=2.5 autoconf || die "autoconf failed"
}
src_compile() {
addpredict "$(tty)"
addpredict "${SSH_TTY}"
# check config.h for other settings such as the
# max-number of windows allowed by screen.
append-flags "-DPTYMODE=0620 -DPTYGROUP=5"
append-ldflags -Wl,-z,now
use pam && append-flags "-DUSE_PAM"
use nethack || append-flags "-DNONETHACK"
use debug && append-flags "-DDEBUG"
econf \
--with-socket-dir=/var/run/screen \
--with-sys-screenrc=/etc/screenrc \
--enable-rxvt_osc \
--enable-telnet \
--enable-colors256 \
$(use_enable pam) \
|| die "econf failed"
# Second try to fix bug 12683, this time without changing term.h
# The last try seemed to break screen at run-time.
# (16 Jan 2003 agriffis)
LC_ALL=POSIX make term.h || die "Failed making term.h"
emake || die "emake failed"
}
src_install() {
dobin screen || die "dobin failed"
keepdir /var/run/screen || die "keepdir failed"
fowners root:utmp /{usr/bin,var/run}/screen || die "fowners failed"
fperms 2755 /usr/bin/screen || die "fperms failed"
insinto /usr/share/terminfo
doins terminfo/screencap || die "doins failed"
insinto /usr/share/screen/utf8encodings
doins utf8encodings/?? || die "doins failed"
insinto /etc
doins "${FILESDIR}"/screenrc || die "doins failed"
pamd_mimic_system screen auth || die "pamd_mimic_system failed"
dodoc \
README ChangeLog INSTALL TODO NEWS* patchlevel.h \
doc/{FAQ,README.DOTSCREEN,fdpat.ps,window_to_display.ps} \
|| die "dodoc failed"
doman doc/screen.1 || die "doman failed"
doinfo doc/screen.info* || die "doinfo failed"
}
pkg_postinst() {
chmod 0775 "${ROOT}"/var/run/screen
einfo "Some dangerous key bindings have been removed or changed to more safe values."
einfo "For more info, please check /etc/screenrc"
einfo
einfo "screen is not installed as setuid root, which effectively disables multi-user"
einfo "mode. To enable it, run:"
einfo
einfo "\tchmod u+s /usr/bin/screen"
einfo "\tchmod go-w /var/run/screen"
}
|
GitWeb