1 files changed, 60 insertions, 0 deletions
diff --git a/media-sound/qtractor/qtractor-0.2.1.ebuild b/media-sound/qtractor/qtractor-0.2.1.ebuild
new file mode 100644
index 000000000000..e515ba47b158
--- /dev/null
+++ b/media-sound/qtractor/qtractor-0.2.1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/qtractor/qtractor-0.2.1.ebuild,v 1.1 2008/08/29 20:33:19 aballier Exp $
+
+EAPI=1
+
+inherit eutils qt4
+
+DESCRIPTION="Qtractor is an Audio/MIDI multi-track sequencer."
+HOMEPAGE="http://qtractor.sourceforge.net/"
+SRC_URI="mirror://sourceforge/qtractor/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="debug dssi libsamplerate mad osc rubberband vorbis sse"
+
+DEPEND="|| ( ( x11-libs/qt-core x11-libs/qt-gui )
+			=x11-libs/qt-4.3*:4 )
+	media-libs/alsa-lib
+	media-libs/libsndfile
+	media-sound/jack-audio-connection-kit
+	media-libs/ladspa-sdk
+	dssi? ( media-libs/dssi )
+	mad? ( media-libs/libmad )
+	libsamplerate? ( media-libs/libsamplerate )
+	osc? ( media-libs/liblo )
+	rubberband? ( media-libs/rubberband )
+	vorbis? ( media-libs/libvorbis )"
+
+pkg_setup() {
+	if ! built_with_use --missing true media-libs/alsa-lib midi; then
+		eerror ""
+		eerror "To be able to build ${CATEGORY}/${PN} with ALSA support you"
+		eerror "need to have built media-libs/alsa-lib with midi USE flag."
+		die "Missing midi USE flag on media-libs/alsa-lib"
+	fi
+}
+
+src_compile() {
+	econf \
+		$(use_enable mad libmad) \
+		$(use_enable libsamplerate) \
+		$(use_enable vorbis libvorbis) \
+		$(use_enable osc liblo) \
+		--enable-ladspa \
+		$(use_enable dssi) \
+		$(use_enable rubberband librubberband) \
+		$(use_enable sse) \
+		$(use_enable debug) \
+		|| die "econf failed"
+	eqmake4 qtractor.pro -o qtractor.mak
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake -j1 DESTDIR="${D}" install || die "make install failed"
+	dodoc README ChangeLog TODO AUTHORS
+}