bump to newer upstream. Fix DVD audio/video issues. Updates to DVD path handling

Package-Manager: portage-2.2_rc1/cvs/Linux 2.6.25-gentoo-r5 x86_64

3 files changed, 322 insertions, 5 deletions

diff --git a/media-tv/mythtv/ChangeLog b/media-tv/mythtv/ChangeLog
index afa59db56d32..245b015912e1 100644
--- a/media-tv/mythtv/ChangeLog
+++ b/media-tv/mythtv/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-tv/mythtv
 # Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-tv/mythtv/ChangeLog,v 1.245 2008/06/26 21:40:21 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-tv/mythtv/ChangeLog,v 1.246 2008/06/28 01:25:56 cardoe Exp $
+
+*mythtv-0.21_p17637 (28 Jun 2008)
+
+  28 Jun 2008; Doug Goldstein <cardoe@gentoo.org>
+  +mythtv-0.21_p17637.ebuild:
+  bump to newer upstream. Fix DVD audio/video issues. Updates to DVD path
+  handling
 
   26 Jun 2008; Doug Goldstein <cardoe@gentoo.org> mythtv-0.21_p16867.ebuild,
   mythtv-0.21_p16926.ebuild, mythtv-0.21_p16944.ebuild,
diff --git a/media-tv/mythtv/Manifest b/media-tv/mythtv/Manifest
index 179b8c37f9e9..c6fa8b58a272 100644
--- a/media-tv/mythtv/Manifest
+++ b/media-tv/mythtv/Manifest
@@ -16,14 +16,15 @@ EBUILD mythtv-0.21_p16926.ebuild 9396 RMD160 220508a20d8f53d4f8a06b88064853c425d
 EBUILD mythtv-0.21_p16944.ebuild 9423 RMD160 c1741042267a485c291751ddf250de52c1682c2d SHA1 5a6970cb20019928c2ecbc17ade3ccdb3fbff902 SHA256 705f8e132d7f0c075fd46ef68fcce31425657b4b77824b941e74f450a1447398
 EBUILD mythtv-0.21_p17100.ebuild 9423 RMD160 2f7ebcfb1462d49e9a6865472d3748b687309cdf SHA1 a841a594b65a0b06ffafe7bdc073d54f1c64cca9 SHA256 427c2f66967ffcf5be387f4853c9b66c51401f6164885fb65e221232859b3b0a
 EBUILD mythtv-0.21_p17435.ebuild 9075 RMD160 0ce098f87f0b50a1fd7eb1fe5a692f6139473669 SHA1 34b031a73e3b22388173d1e323c74dddd79648b7 SHA256 a179a848eb53fa34ae90c9fdd7b6236d7150cc3f158e8f90e7e11bb92b04a5f0
+EBUILD mythtv-0.21_p17637.ebuild 9075 RMD160 bd222f505493769817d395cf185d40947025a8ff SHA1 8c4672337a7138f1c93e4e8afec56815ca98554b SHA256 b60666a5d69ffd6d63931eeadb034d350c11ddcfecb43739dc200cbddf14be61
 EBUILD mythtv-0.22_alpha17132.ebuild 9540 RMD160 bef9b84805a220314711c06b7907418537ee4361 SHA1 93a93e3312cb6e819b64752412ba5e2c6a82f876 SHA256 0ff664dcd55d3f7c6a649f91172530b671087f8f242ed312a525c00d2e360b4d
 EBUILD mythtv-0.22_alpha17449.ebuild 8704 RMD160 9dafe5b7f850e59f8493893c44f99130b7922085 SHA1 618643aa4b97b0b0d64f07238e27ca547af4c237 SHA256 c6c825ef2c41bf7d4bf885ac4191983a5885ca8d7be868e67eed849ba24b07a7
-MISC ChangeLog 47362 RMD160 924387b19fbf6c0207faf590833b0fd41a7128c5 SHA1 31b1f861f9e0d608e650b981c2d27ee11a092b6a SHA256 622a50f813d3ead0f7e07cac995bf573e7052d8fcbe3e1295725eec70d9ec016
+MISC ChangeLog 47563 RMD160 08da50b2c70828551c36e1f3f46831819fd4d618 SHA1 3d96edc74dff80cdf92cdd3f817c602428cd7d91 SHA256 f6ae52f5198ee240930f0585d0d0ffb1f51e712f950fb1de53b1e47f27994996
 MISC metadata.xml 4714 RMD160 c65d058e83e36342d6a49b63a6e9609e11242b66 SHA1 0de80f93ca1adfede5783d30a45953ec4cd27c9b SHA256 7501a841c218dd17bee56aeefcfc60194241b3a5468898850c5bedf5dafd28e5
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.9 (GNU/Linux)
 
-iEYEARECAAYFAkhkDM4ACgkQoeSe8B0zEfzyQgCfWj+D2dFlPnoqyjFO1vTRs4Cb
-UuoAn28AuXN4whWsAf7KCRWK6DWquxPL
-=Mcrl
+iEYEARECAAYFAkhlky4ACgkQoeSe8B0zEfwGsQCgh2h/yn3cvpKXrJTJaXiy4yAn
+DmgAnjL+LeZc0R3kFnaz0pGjDAcucLte
+=oP1W
 -----END PGP SIGNATURE-----
diff --git a/media-tv/mythtv/mythtv-0.21_p17637.ebuild b/media-tv/mythtv/mythtv-0.21_p17637.ebuild
new file mode 100644
index 000000000000..bfc9b34b8d54
--- /dev/null
+++ b/media-tv/mythtv/mythtv-0.21_p17637.ebuild
@@ -0,0 +1,309 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-tv/mythtv/mythtv-0.21_p17637.ebuild,v 1.1 2008/06/28 01:25:56 cardoe Exp $
+
+EAPI=1
+inherit flag-o-matic multilib eutils qt3 mythtv toolchain-funcs python confutils
+
+DESCRIPTION="Homebrew PVR project"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+IUSE_VIDEO_CARDS="video_cards_nvidia"
+IUSE="aac alsa altivec autostart debug directv dvb fftw ieee1394 jack lcd \
+lirc mmx opengl perl python x264 xvid xvmc ${IUSE_VIDEO_CARDS}"
+
+RDEPEND=">=media-libs/freetype-2.0
+	>=media-sound/lame-3.93.1
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXinerama
+	x11-libs/libXv
+	x11-libs/libXrandr
+	x11-libs/libXxf86vm
+	>=x11-libs/qt-3.3:3
+	virtual/mysql
+	virtual/opengl
+	virtual/glu
+	|| ( >=net-misc/wget-1.9.1 >=media-tv/xmltv-0.5.43 )
+	aac? ( media-libs/faac
+			media-libs/faad2 )
+	alsa? ( >=media-libs/alsa-lib-0.9 )
+	autostart? ( net-dialup/mingetty
+				x11-wm/evilwm
+				x11-apps/xset )
+	directv? ( virtual/perl-Time-HiRes )
+	dvb? ( media-libs/libdvb media-tv/linuxtv-dvb-headers )
+	fftw? ( sci-libs/fftw:3.0 )
+	ieee1394? (	>=sys-libs/libraw1394-1.2.0
+			>=sys-libs/libavc1394-0.5.3
+			>=media-libs/libiec61883-1.0.0 )
+	jack? ( media-sound/jack-audio-connection-kit )
+	lcd? ( app-misc/lcdproc )
+	lirc? ( app-misc/lirc )
+	perl? ( dev-perl/DBD-mysql )
+	python? ( dev-python/mysql-python )
+	x264? ( media-libs/x264 )
+	xvid? ( media-libs/xvid )
+	xvmc? ( x11-libs/libXvMC
+		app-admin/eselect-xvmc )"
+
+DEPEND="${RDEPEND}
+	x11-proto/xineramaproto
+	x11-proto/xf86vidmodeproto
+	x11-apps/xinit"
+
+PDEPEND="=x11-themes/mythtv-themes-${MY_PV}*"
+
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+MYTHTV_GROUPS="video,audio,tty,uucp"
+
+pkg_setup() {
+
+	confutils_require_built_with_all =x11-libs/qt-3* mysql opengl
+
+	elog "This ebuild now uses a heavily stripped down version of your CFLAGS"
+
+	if use xvmc && use video_cards_nvidia; then
+		elog
+		elog "For NVIDIA based cards, the XvMC renderer only works on"
+		elog "the NVIDIA 4, 5, 6 & 7 series cards."
+	fi
+
+	enewuser mythtv -1 /bin/bash /home/mythtv ${MYTHTV_GROUPS} \
+		|| die "Problem adding mythtv user"
+	usermod -a -G ${MYTHTV_GROUPS} mythtv
+}
+
+src_unpack() {
+	subversion_src_unpack
+
+	# upstream wants the revision number in their version.cpp
+	# since the subversion.eclass strips out the .svn directory
+	# svnversion in MythTV's build doesn't work
+	sed -e "s:\`(svnversion \$\${SVNTREEDIR} 2>\/dev\/null) || echo Unknown\`:${MYTHTV_REV}:" \
+		-i "${S}"/version.pro || die "svnversion sed failed"
+
+	# Perl bits need to go into vender_perl and not site_perl
+	sed -e "s:pure_install:pure_install INSTALLDIRS=vendor:" \
+		-i "${S}"/bindings/perl/perl.pro
+}
+
+src_compile() {
+	local myconf="--prefix=/usr
+		--mandir=/usr/share/man
+		--libdir-name=$(get_libdir)"
+	use aac && myconf="${myconf} --enable-libfaad --enable-libfaac"
+	use alsa || myconf="${myconf} --disable-audio-alsa"
+	use altivec || myconf="${myconf} --disable-altivec"
+	use fftw && myconf="${myconf} --enable-libfftw3"
+	use jack || myconf="${myconf} --disable-audio-jack"
+	use x264 && myconf="${myconf} --enable-libx264"
+	use xvid && myconf="${myconf} --enable-libxvid"
+	# let's give this a whirl from bug #220857
+	use xvmc && myconf="${myconf} --enable-xvmc --enable-xvmcw \
+		--disable-xvmc-vld"
+	#use xvmc && ! use video_cards_via && \
+	#	myconf="${myconf} --enable-xvmc"
+	#use xvmc && use video_cards_via && myconf="${myconf} --enable-xvmc \
+	#	--enable-xvmc-pro --disable-xvmcw"
+	# nvidia-drivers-71 don't support GLX 1.4
+	#use video_cards_nvidia && has_version =x11-drivers/nvidia-drivers-71* \
+	#	&& myconf="${myconf} --enable-glx-procaddrarb"
+	# according to the Ubuntu guys, this works better always on
+	myconf="${myconf} --enable-glx-procaddrarb"
+
+	myconf="${myconf}
+		$(use_enable dvb)
+		$(use_enable ieee1394 firewire)
+		$(use_enable lirc)
+		--disable-audio-arts
+		--disable-directfb
+		--dvb-path=/usr/include
+		--enable-opengl-vsync
+		--enable-libmp3lame
+		--enable-xrandr
+		--enable-xv
+		--enable-x11"
+
+	if use mmx || use amd64; then
+		myconf="${myconf} --enable-mmx"
+	else
+		myconf="${myconf} --disable-mmx"
+	fi
+
+	if use perl && use python; then
+		myconf="${myconf} --with-bindings=perl,python"
+	elif use perl; then
+		myconf="${myconf} --with-bindings=perl"
+	elif use python; then
+		myconf="${myconf} --with-bindings=python"
+	else
+		myconf="${myconf} --without-bindings=perl,python"
+	fi
+
+	if use debug; then
+		myconf="${myconf} --compile-type=debug"
+	else
+		myconf="${myconf} --compile-type=profile"
+	fi
+
+	## CFLAG cleaning so it compiles
+	MARCH=$(get-flag "march")
+	MTUNE=$(get-flag "mtune")
+	strip-flags
+	filter-flags "-march=*" "-mtune=*" "-mcpu=*"
+	filter-flags "-O" "-O?"
+
+	if [[ -n "${MARCH}" ]]; then
+		myconf="${myconf} --cpu=${MARCH}"
+	fi
+	if [[ -n "${MTUNE}" ]]; then
+		myconf="${myconf} --tune=${MTUNE}"
+	fi
+
+#	myconf="${myconf} --extra-cxxflags=\"${CXXFLAGS}\" --extra-cflags=\"${CFLAGS}\""
+	hasq distcc ${FEATURES} || myconf="${myconf} --disable-distcc"
+	hasq ccache ${FEATURES} || myconf="${myconf} --disable-ccache"
+
+	# let MythTV come up with our CFLAGS. Upstream will support this
+	CFLAGS=""
+	CXXFLAGS=""
+	einfo "Running ./configure ${myconf}"
+	./configure ${myconf} || die "configure died"
+
+	eqmake3 mythtv.pro -o "Makefile" || die "eqmake3 failed"
+	emake || die "emake failed"
+
+	# firewire support should build the tester
+	if use ieee1394; then
+		cd contrib
+		$(tc-getCC) ${CFLAGS} ${CPPFLAGS} -o ../firewire_tester firewire_tester.c \
+			${LDFLAGS} -liec61883 -lraw1394 || \
+			die "failed to compile firewire_tester"
+
+		cd channel_changers
+		$(tc-getCC) ${CFLAGS} ${CPPFLAGS} -std=gnu99 -o ../../6200ch 6200ch.c \
+			${LDFLAGS} -lrom1394 -lavc1394 -lraw1394 || \
+			die "failed to compile 6200ch"
+		$(tc-getCC) ${CFLAGS} ${CPPFLAGS} -o ../../sa3250ch sa3250ch.c \
+			${LDFLAGS} -lrom1394 -lavc1394 -lraw1394 || \
+			die "failed to compile sa3250ch"
+	fi
+
+	cd "${S}"/contrib/channel_changers
+	$(tc-getCC) ${CFLAGS} ${CPPFLAGS} -o ../../red_eye red_eye.c ${LDFLAGS} || \
+		die "failed to compile red_eye"
+}
+
+src_install() {
+
+	einstall INSTALL_ROOT="${D}" || die "install failed"
+	dodoc AUTHORS FAQ UPGRADING  README
+
+	insinto /usr/share/mythtv/database
+	doins database/*
+
+	exeinto /usr/share/mythtv
+	doexe "${FILESDIR}/mythfilldatabase.cron"
+
+	newinitd "${FILESDIR}"/mythbackend-0.18.2.rc mythbackend
+	newconfd "${FILESDIR}"/mythbackend-0.18.2.conf mythbackend
+
+	dodoc keys.txt docs/*.{txt,pdf}
+	dohtml docs/*.html
+
+	keepdir /etc/mythtv
+	chown -R mythtv "${D}"/etc/mythtv
+	keepdir /var/log/mythtv
+	chown -R mythtv "${D}"/var/log/mythtv
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/mythtv.logrotate.d mythtv
+
+	insinto /usr/share/mythtv/contrib
+	doins -r contrib/*
+
+	dobin "${FILESDIR}"/runmythfe
+
+	if use autostart; then
+		dodir /etc/env.d/
+		echo 'CONFIG_PROTECT="/home/mythtv/"' > "${D}"/etc/env.d/95mythtv
+
+		insinto /home/mythtv
+		newins "${FILESDIR}"/bash_profile .bash_profile
+		newins "${FILESDIR}"/xinitrc .xinitrc
+	fi
+
+	if use ieee1394; then
+		dobin firewire_tester || die "failed to install firewire_tester"
+		dodoc contrib/firewire_tester-README
+
+		dobin 6200ch || die "failed to install 6200ch"
+		dodoc contrib/channel_changers/6200ch-README
+
+		dobin sa3250ch || die "failed to install sa3250ch"
+		dodoc contrib/channel_changers/sa3250ch-README
+	fi
+
+	dobin red_eye || die "failed to install red_eye"
+	dodoc contrib/channel_changers/red_eye-README
+
+	if use directv; then
+		dobin contrib/channel_changers/d10control.pl || die "failed to install d10control"
+		dodoc contrib/channel_changers/d10control-README
+	fi
+}
+
+pkg_preinst() {
+	export CONFIG_PROTECT="${CONFIG_PROTECT} ${ROOT}/home/mythtv/"
+}
+
+pkg_postinst() {
+	python_version
+	python_mod_optimize /usr/$(get_libdir)/python${PYVER}/site-packages/MythTV
+
+	echo
+	elog "Want mythfrontend to start automatically?"
+	elog "Set USE=autostart. Details can be found at:"
+	elog "http://dev.gentoo.org/~cardoe/mythtv/autostart.html"
+
+	elog
+	elog "To always have MythBackend running and available run the following:"
+	elog "rc-update add mythbackend default"
+	elog
+	ewarn "Your recordings folder must be owned by the user 'mythtv' now"
+	ewarn "chown -R mythtv /path/to/store"
+
+	if use xvmc && [[ ! -s "${ROOT}/etc/X11/XvMCConfig" ]]; then
+		ewarn
+		ewarn "No XvMC implementation has been selected yet"
+		ewarn "Use 'eselect xvmc list' for a list of available choices"
+		ewarn "Then use 'eselect xvmc set <choice>' to choose"
+		ewarn "'eselect xvmc set nvidia' for example"
+	fi
+
+	if use autostart; then
+		elog
+		elog "Please add the following to your /etc/inittab file at the end of"
+		elog "the TERMINALS section"
+		elog "c8:2345:respawn:/sbin/mingetty --autologin mythtv tty8"
+	fi
+
+}
+
+pkg_postrm()
+{
+	python_mod_cleanup /usr/$(get_libdir)/python*/site-packages/MythTV
+}
+
+pkg_info() {
+	"${ROOT}"/usr/bin/mythfrontend --version
+}
+
+pkg_config() {
+	echo "Creating mythtv MySQL user and mythconverg database if it does not"
+	echo "already exist. You will be prompted for your MySQL root password."
+	"${ROOT}"/usr/bin/mysql -u root -p < "${ROOT}"/usr/share/mythtv/database/mc.sql
+}