Add live ebuild

Package-Manager: portage-2.2.0_alpha45/cvs/Linux x86_64

3 files changed, 196 insertions, 8 deletions

diff --git a/media-sound/mpd/ChangeLog b/media-sound/mpd/ChangeLog
index d18fcde00f7d..3f5ef0a0aead 100644
--- a/media-sound/mpd/ChangeLog
+++ b/media-sound/mpd/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/mpd
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/mpd/ChangeLog,v 1.258 2011/07/17 10:18:06 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mpd/ChangeLog,v 1.259 2011/07/17 15:37:10 angelos Exp $
+
+*mpd-9999 (17 Jul 2011)
+
+  17 Jul 2011; Christoph Mende <angelos@gentoo.org> +mpd-9999.ebuild:
+  Add live ebuild
 
   17 Jul 2011; Kacper Kowalik <xarthisius@gentoo.org> mpd-0.16.2.ebuild:
   ppc/ppc64 stable wrt #364469
diff --git a/media-sound/mpd/Manifest b/media-sound/mpd/Manifest
index 65c205f5355d..989c7d3be031 100644
--- a/media-sound/mpd/Manifest
+++ b/media-sound/mpd/Manifest
@@ -1,5 +1,5 @@
 -----BEGIN PGP SIGNED MESSAGE-----
-Hash: SHA1
+Hash: SHA256
 
 AUX 0.15.1-mpdconf.patch 2912 RMD160 6683618151f0f10dc94b5563a48be3729919ef08 SHA1 fc67f59f808d77332a20261525ca74bf1d67b228 SHA256 cacecca8580bce38f998a9f3fa867c274bb112a9af8c59b8dfcbd23a45d34523
 AUX mpd-0.16.3-ffmpeg.patch 800 RMD160 984a98f5f7bd6a412ebb993ac2be6765f94424c9 SHA1 802ee8a3f598d82538b68674af0f82150bf1c52d SHA256 b3958db44146f11bc1f99410284c30a2739915591e92704ed83ea389c222a121
@@ -18,14 +18,13 @@ EBUILD mpd-0.15.8.ebuild 4882 RMD160 406585c67e2abbfcd9382bf8003e986b3cab4ad9 SH
 EBUILD mpd-0.16.2.ebuild 5444 RMD160 77829190d17229581eb24160e68022eee2ce406e SHA1 7da1a25b2fc88481dcdcefe58ddb3767ca3035ea SHA256 4209d85caa04c3cebe852fab143c43d2a2f5e7e36577bdb75ecd665aebc16f59
 EBUILD mpd-0.16.3-r1.ebuild 5485 RMD160 f1456787e5fed6270b2cb44481bd9b20f07a1b32 SHA1 01290c08339d8d8d4db55042e2d4c03e6b0042d1 SHA256 2ab974d9933879c3b175afd8297677464919b8072f98421e87af393d805cf2d2
 EBUILD mpd-0.16.3.ebuild 5446 RMD160 f31ce378c915eecb19ce8a02e746a57963743401 SHA1 2fad6efa07b61a02c177c26a1d89caf6a367636d SHA256 8d1154dd89a9d97917e1b12efe93e10d8f74419dd31175c4eb246784dbd53bc3
-MISC ChangeLog 37509 RMD160 54cb843ca640a873e28f5ea755df23048c4fd84b SHA1 2a6f707c9a38f8b8d18a0ec4b7aa5a534d1915f2 SHA256 23ab27dc6753386c623ff1e0e228f37bfa1d8f7af659988cb731d4c0384a5496
+EBUILD mpd-9999.ebuild 5505 RMD160 ee8f9d04d6ac489d90c18fe05db4dff9ee7f6600 SHA1 0525b84bb196f4b1980351612d22c6481c02b78f SHA256 58e14b69de185bf62d3efc98eadea69fd5a891beaff7c3166777fc5006538dfb
+MISC ChangeLog 37620 RMD160 13b3e2b23b561af8fc4afa9f6d8aa6bb52f80cee SHA1 9a6e0f6ea7bcda07cd6d9d84c9ba7b90dc7c8413 SHA256 aae70b84389b9f234bcc254883d5c3b10c21b53a6b1991003ab3e5fa2f6bbee5
 MISC metadata.xml 1522 RMD160 b201defb9a09c68c1754c0babddfffd2eb1e090a SHA1 14f708cab1e2802912802e8bd74fc68ecdc39b7f SHA256 5e148274f669b966cf88e9b5f99cd7a6db55b4f8f2e42c3c1128e394f33d6652
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.17 (GNU/Linux)
 
-iJwEAQECAAYFAk4itugACgkQIiMqcbOVdxQN5gP/bk17kcdw2n8DliT0lU5MaWui
-mLBkYatn85GBvUiaTOgyX/QrAUn9Suw++12ov+3YQTjsfRBU0ki9n+RK65lxb3LW
-UETJXZEIu/cwgbDC/jyA97G3Y6UMyQIP6lrVUnmK3PAzW3gIe8kY7rg2MTz94kIj
-XPOl6XujmZ57rrsJxms=
-=X7S5
+iF4EAREIAAYFAk4jAaoACgkQmWq1bYTyC0NMywD7BLM17tUnB1qBMazUCP+KKZnX
+JLWk1NDDoagrEElTgbYBAJNnyES8ecc8bDmR5pue8+k0BNFtgBNcYWKoZMztUnmj
+=/dgZ
 -----END PGP SIGNATURE-----
diff --git a/media-sound/mpd/mpd-9999.ebuild b/media-sound/mpd/mpd-9999.ebuild
new file mode 100644
index 000000000000..03660b1896ac
--- /dev/null
+++ b/media-sound/mpd/mpd-9999.ebuild
@@ -0,0 +1,184 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mpd/mpd-9999.ebuild,v 1.1 2011/07/17 15:37:10 angelos Exp $
+
+EAPI=4
+inherit autotools eutils flag-o-matic linux-info multilib git-2
+
+DESCRIPTION="The Music Player Daemon (mpd)"
+HOMEPAGE="http://www.musicpd.org"
+EGIT_REPO_URI="git://git.musicpd.org/master/${PN}.git"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS=""
+IUSE="aac +alsa ao audiofile bzip2 cdio cue +curl debug +fifo +ffmpeg flac
+fluidsynth profile +id3tag inotify ipv6 jack lame lastfmradio libmms libsamplerate
++mad mikmod modplug mpg123 musepack +network ogg openal oss pipe pulseaudio sid
+sndfile sqlite tcpd twolame unicode vorbis wavpack wildmidi zeroconf zip"
+
+REQUIRED_USE="|| ( alsa ao fifo jack network openal oss pipe pulseaudio )
+	|| ( aac audiofile ffmpeg flac fluidsynth mad mikmod modplug mpg123 musepack
+			ogg flac sid vorbis wavpack wildmidi )
+	network? ( || ( audiofile flac lame twolame vorbis ) )
+	lastfmradio? ( curl )"
+
+RDEPEND="!<sys-cluster/mpich2-1.4_rc2
+	dev-libs/glib:2
+	aac? ( media-libs/faad2 )
+	alsa? ( media-sound/alsa-utils )
+	ao? ( media-libs/libao[alsa?,pulseaudio?] )
+	audiofile? ( media-libs/audiofile )
+	bzip2? ( app-arch/bzip2 )
+	cdio? ( dev-libs/libcdio
+		virtual/cdrtools )
+	cue? ( media-libs/libcue )
+	curl? ( net-misc/curl )
+	ffmpeg? ( virtual/ffmpeg )
+	flac? ( media-libs/flac[ogg?] )
+	fluidsynth? ( media-sound/fluidsynth )
+	network? ( >=media-libs/libshout-2 )
+	id3tag? ( media-libs/libid3tag )
+	jack? ( media-sound/jack-audio-connection-kit )
+	lame? ( network? ( media-sound/lame ) )
+	libmms? ( media-libs/libmms )
+	libsamplerate? ( media-libs/libsamplerate )
+	mad? ( media-libs/libmad )
+	mikmod? ( media-libs/libmikmod )
+	modplug? ( media-libs/libmodplug )
+	mpg123? ( >=media-sound/mpg123-1.12.2 )
+	musepack? ( media-sound/musepack-tools )
+	ogg? ( media-libs/libogg )
+	openal? ( media-libs/openal )
+	pulseaudio? ( media-sound/pulseaudio )
+	sid? ( media-libs/libsidplay:2 )
+	sndfile? ( media-libs/libsndfile )
+	sqlite? ( dev-db/sqlite:3 )
+	tcpd? ( sys-apps/tcp-wrappers )
+	twolame? ( media-sound/twolame )
+	vorbis? ( media-libs/libvorbis )
+	wavpack? ( media-sound/wavpack )
+	wildmidi? ( media-sound/wildmidi )
+	zeroconf? ( net-dns/avahi[dbus] )
+	zip? ( dev-libs/zziplib )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+pkg_setup() {
+	use network || ewarn "Icecast and Shoutcast streaming needs networking."
+	use fluidsynth && ewarn "Using fluidsynth is discouraged by upstream."
+
+	enewuser mpd "" "" "/var/lib/mpd" audio
+
+	if use inotify; then
+		CONFIG_CHECK="~INOTIFY_USER"
+		ERROR_INOTIFY_USER="${P} requires inotify in-kernel support."
+		linux-info_pkg_setup
+	fi
+}
+
+src_prepare() {
+	cp -f doc/mpdconf.example doc/mpdconf.dist || die "cp failed"
+	epatch "${FILESDIR}"/${PN}-0.16.conf.patch
+	eautoreconf
+}
+
+src_configure() {
+	local mpdconf="--disable-despotify --disable-documentation --disable-ffado
+		--disable-gme --disable-mvp --disable-roar --enable-largefile
+		--enable-raop-output --enable-recorder-output --enable-tcp --enable-un
+		--docdir=${EPREFIX}/usr/share/doc/${PF}"
+
+	if use network; then
+		mpdconf+=" --enable-shout $(use_enable vorbis vorbis-encoder)
+			--enable-httpd-output $(use_enable lame lame-encoder)
+			$(use_enable twolame twolame-encoder)
+			$(use_enable audiofile wave-encoder)"
+	else
+		mpdconf+=" --disable-shout --disable-vorbis-encoder
+			--disable-httpd-output --disable-lame-encoder
+			--disable-twolame-encoder --disable-wave-encoder"
+	fi
+
+	if use flac && use ogg; then
+		mpdconf+=" --enable-oggflac"
+	else
+		mpdconf+=" --disable-oggflac"
+	fi
+
+	append-lfs-flags
+	append-ldflags "-L/usr/$(get_libdir)/sidplay/builders"
+
+	econf \
+		$(use_enable aac) \
+		$(use_enable alsa) \
+		$(use_enable ao) \
+		$(use_enable audiofile) \
+		$(use_enable bzip2) \
+		$(use_enable cdio iso9660) \
+		$(use_enable cdio cdio-paranoia) \
+		$(use_enable cue) \
+		$(use_enable curl) \
+		$(use_enable debug) \
+		$(use_enable ffmpeg) \
+		$(use_enable fifo) \
+		$(use_enable flac) \
+		$(use_enable fluidsynth) \
+		$(use_enable id3tag id3) \
+		$(use_enable inotify) \
+		$(use_enable ipv6) \
+		$(use_enable jack) \
+		$(use_enable lastfmradio lastfm) \
+		$(use_enable libmms mms) \
+		$(use_enable libsamplerate lsr) \
+		$(use_enable mad) \
+		$(use_enable mikmod) \
+		$(use_enable modplug) \
+		$(use_enable mpg123) \
+		$(use_enable musepack mpc) \
+		$(use_enable openal) \
+		$(use_enable oss) \
+		$(use_enable pipe pipe-output) \
+		$(use_enable profile gprof) \
+		$(use_enable pulseaudio pulse) \
+		$(use_enable sid sidplay) \
+		$(use_enable sndfile) \
+		$(use_enable sqlite) \
+		$(use_enable tcpd libwrap) \
+		$(use_enable vorbis) \
+		$(use_enable wavpack) \
+		$(use_enable wildmidi) \
+		$(use_enable zip zzip) \
+		$(use_with zeroconf zeroconf avahi) \
+		${mpdconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	insinto /etc
+	newins doc/mpdconf.dist mpd.conf
+
+	newinitd "${FILESDIR}"/mpd.init mpd
+
+	if use unicode; then
+		sed -i -e 's:^#filesystem_charset.*$:filesystem_charset "UTF-8":' \
+			"${D}"/etc/mpd.conf || die "sed failed"
+	fi
+
+	diropts -m0755 -o mpd -g audio
+	dodir /var/lib/mpd
+	keepdir /var/lib/mpd
+	dodir /var/lib/mpd/music
+	keepdir /var/lib/mpd/music
+	dodir /var/lib/mpd/playlists
+	keepdir /var/lib/mpd/playlists
+}
+
+pkg_postinst() {
+	elog "If you will be starting mpd via /etc/init.d/mpd, please make"
+	elog "sure that MPD's pid_file is unset."
+
+	# also change the homedir if the user has existed before
+	usermod -d "/var/lib/mpd" mpd
+}