Version bump; thanks to Rafał Mużyło in bug #284785 for letting me notice.

Package-Manager: portage-2.2_rc40/cvs/Linux x86_64

3 files changed, 97 insertions, 3 deletions

diff --git a/media-libs/libcanberra/ChangeLog b/media-libs/libcanberra/ChangeLog
index 09925e8a7b81..afafa2cc0cd6 100644
--- a/media-libs/libcanberra/ChangeLog
+++ b/media-libs/libcanberra/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-libs/libcanberra
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libcanberra/ChangeLog,v 1.27 2009/08/24 13:27:31 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libcanberra/ChangeLog,v 1.28 2009/09/13 18:11:27 flameeyes Exp $
+
+*libcanberra-0.16 (13 Sep 2009)
+
+  13 Sep 2009; Diego E. Pettenò <flameeyes@gentoo.org>
+  +libcanberra-0.16.ebuild:
+  Version bump; thanks to Rafał Mużyło in bug #284785 for letting me
+  notice.
 
 *libcanberra-0.15-r1 (24 Aug 2009)
 
diff --git a/media-libs/libcanberra/libcanberra-0.16.ebuild b/media-libs/libcanberra/libcanberra-0.16.ebuild
new file mode 100644
index 000000000000..aef42a784e04
--- /dev/null
+++ b/media-libs/libcanberra/libcanberra-0.16.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libcanberra/libcanberra-0.16.ebuild,v 1.1 2009/09/13 18:11:27 flameeyes Exp $
+
+EAPI="1"
+
+inherit eutils gnome2-utils autotools
+
+DESCRIPTION="Portable Sound Event Library"
+HOMEPAGE="http://0pointer.de/lennart/projects/libcanberra/"
+SRC_URI="http://0pointer.de/lennart/projects/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="alsa doc gstreamer +gtk oss pulseaudio"
+
+RDEPEND="media-libs/libvorbis
+	sys-devel/libtool
+	alsa? ( media-libs/alsa-lib )
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.11 )
+	gstreamer? ( >=media-libs/gstreamer-0.10.15 )
+	gtk? ( dev-libs/glib:2
+		>=x11-libs/gtk+-2.13.4:2
+		>=gnome-base/gconf-2 )"
+DEPEND="${RDEPEND}
+	>=dev-util/pkgconfig-0.17
+	dev-util/gtk-doc-am
+	doc? ( >=dev-util/gtk-doc-1.9 )"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	# Fix bug 277739, replace LT_PREREQ and LT_INIT by AC_LIBTOOL*
+	# macros (equivalent for earlier version), preserve backward
+	# compatibility with libtool-1
+	epatch "${FILESDIR}/${PN}-0.14-backward-compatibility-libtool.patch"
+
+	# Fix bug 278354, Backport AM_GCONF_SOURCE_2 macro to m4/ dir
+	# in case where gconf isn't installed on the system
+	# (eautoconf could fail)
+	epatch "${FILESDIR}/${PN}-0.14-am-gconf-source-2-m4.patch"
+
+	rm lt*    || die "clean-up ltmain.sh failed"
+	rm m4/lt* || die "clean-up lt scripts failed"
+	rm m4/libtool* || die "clean-up libtool script failed"
+
+	eautoreconf
+}
+
+src_compile() {
+	econf --disable-static \
+		--docdir=/usr/share/doc/${PF} \
+		$(use_enable alsa) \
+		$(use_enable gstreamer) \
+		$(use_enable gtk) \
+		$(use_enable oss) \
+		$(use_enable pulseaudio pulse) \
+		$(use_enable doc gtk-doc) \
+		--disable-tdb \
+		--disable-lynx
+	# tdb support would need a split-out from samba before we can use it
+
+	emake || die "emake failed."
+}
+
+src_install() {
+	# we must delay gconf schema installation due to sandbox
+	#export GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL="1"
+
+	emake DESTDIR="${D}" install || die "emake install failed."
+
+	#unset GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL
+}
+
+pkg_preinst() {
+	gnome2_gconf_savelist
+}
+
+pkg_postinst() {
+	gnome2_gconf_install
+}
+
+#pkg_prerm() {
+#	gnome2_gconf_uninstall
+#}
diff --git a/media-libs/libmtp/Manifest b/media-libs/libmtp/Manifest
index 7cd2338d0915..2f3f2e16fbf0 100644
--- a/media-libs/libmtp/Manifest
+++ b/media-libs/libmtp/Manifest
@@ -6,6 +6,6 @@ DIST libmtp-1.0.1.tar.gz 587559 RMD160 2fde6e57a07757e15d3d47992c9930395226e014
 EBUILD libmtp-0.2.6.1.ebuild 1010 RMD160 6f1e93d3999fb6fb3bb92158932f59c01e158e33 SHA1 0e84df1a24e243ce5bdae223f74dbae403fff970 SHA256 30ad53a24911a17dcbe257d334028475e937d4020d11803eb24dfd0781002b0a
 EBUILD libmtp-0.3.7.ebuild 1076 RMD160 e05944cde4761462adb85c6d6ecfef2051e2581b SHA1 5ef127db13c097a5d425d0d45656b322f77a3f0d SHA256 a4d4e2d110abc8a8a1a771dd19c17642b7416aaf45c97974d243c56987cc36aa
 EBUILD libmtp-1.0.0.ebuild 1083 RMD160 aec34adcf5b3725e02ac4e230340a6e54f99b966 SHA1 37a84358173042a38cc254b0771486688c54bac8 SHA256 bba337946766f78dbeef9a948e490715ac9b72aca9dc816c747921fafbca8732
-EBUILD libmtp-1.0.1.ebuild 1083 RMD160 aec34adcf5b3725e02ac4e230340a6e54f99b966 SHA1 37a84358173042a38cc254b0771486688c54bac8 SHA256 bba337946766f78dbeef9a948e490715ac9b72aca9dc816c747921fafbca8732
-MISC ChangeLog 9285 RMD160 a6d99d8b6354a3709c9751fa13752bb529a8b42d SHA1 f85505c2a2c93cc1a39d8297a81b9f1c2ffb8693 SHA256 b4b6a552d11007016a6f4c3fef86a8ff74b9d30901141fd2021e7be43b4240f0
+EBUILD libmtp-1.0.1.ebuild 1083 RMD160 d805d530b34af29e6fc9bf1a420b70463a4d6387 SHA1 9b4ff863c1588b90e7bc1a9a411f20389ead515c SHA256 8e0ef484103fccd4871a32167e7245256849591327a7728a5510923335e539de
+MISC ChangeLog 9403 RMD160 6f523a4a85c2ce2b4de45f837a43d0fdc9b09680 SHA1 3721389de0366057ea7779a83657738e7747d482 SHA256 6c94ccc2fe0a7eb1efefc0f77a953ac3bd8d09182ed8e71e329cc94a954edcbf
 MISC metadata.xml 326 RMD160 2517b86f6d57dad69701aa3a870d84261209c5ab SHA1 d4e6f31289429188743fc9d7aeb4e92dcf42194c SHA256 18e553c8ecc062379070fdcbbd3568e6e0ef63f36f0f3b4a3d7d3038daa9ad9c