Minor QA fixes, add epatch_user, add USE="static-libs". Drop old revision

Package-Manager: portage-2.2.0_alpha188/cvs/Linux x86_64
Manifest-Sign-Key: 0x1F357D42

1 files changed, 51 insertions, 0 deletions

diff --git a/dev-libs/libcoyotl/libcoyotl-3.1.0-r2.ebuild b/dev-libs/libcoyotl/libcoyotl-3.1.0-r2.ebuild
new file mode 100644
index 000000000000..f073206436e6
--- /dev/null
+++ b/dev-libs/libcoyotl/libcoyotl-3.1.0-r2.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libcoyotl/libcoyotl-3.1.0-r2.ebuild,v 1.1 2013/07/17 09:48:08 pinkbyte Exp $
+
+EAPI="5"
+
+inherit eutils autotools
+
+DESCRIPTION="A collection of portable C++ classes."
+HOMEPAGE="http://www.coyotegulch.com/products/libcoyotl/"
+SRC_URI="http://www.coyotegulch.com/distfiles/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+IUSE="doc static-libs"
+
+RDEPEND="media-libs/libpng:0="
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )"
+
+DOCS=( AUTHORS ChangeLog NEWS README )
+
+src_prepare() {
+	epatch "${FILESDIR}/${PV}-gcc-4.3.patch"
+	epatch "${FILESDIR}/${PV}-gcc-4.7.patch"
+	epatch_user
+	eautoreconf
+}
+
+src_configure() {
+	ac_cv_prog_HAVE_DOXYGEN="false" econf $(use_enable static-libs static)
+}
+
+src_compile() {
+	emake
+
+	if use doc ; then
+		cd docs
+		doxygen libcoyotl.doxygen || die "generating docs failed"
+	fi
+}
+
+src_install() {
+	default
+	prune_libtool_files
+	if use doc ; then
+		dohtml docs/html/*
+	fi
+}