Initial commit, based on ebuild in enlightenment overlay

Package-Manager: portage-2.2.0_alpha2-r1/cvs/Linux x86_64

1 files changed, 78 insertions, 0 deletions

diff --git a/dev-libs/eet/eet-1.4.0_beta2.ebuild b/dev-libs/eet/eet-1.4.0_beta2.ebuild
new file mode 100644
index 000000000000..0c169bd993b4
--- /dev/null
+++ b/dev-libs/eet/eet-1.4.0_beta2.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/eet/eet-1.4.0_beta2.ebuild,v 1.1 2010/11/18 13:26:19 tommy Exp $
+
+EAPI=2
+
+MY_P=${P/_beta/.beta}
+
+inherit enlightenment
+
+DESCRIPTION="E file chunk reading/writing library"
+HOMEPAGE="http://trac.enlightenment.org/e/wiki/Eet"
+SRC_URI="http://download.enlightenment.org/releases/${MY_P}.tar.bz2"
+
+KEYWORDS="~amd64 ~x86"
+IUSE="debug examples gnutls ssl static-libs +threads"
+
+RDEPEND=">=dev-libs/eina-1.0.0_beta
+	media-libs/jpeg
+	sys-libs/zlib
+	gnutls? ( net-libs/gnutls )
+	!gnutls? ( ssl? ( dev-libs/openssl ) )"
+DEPEND="${RDEPEND}
+	test? ( dev-libs/check
+		dev-util/lcov )"
+
+S=${WORKDIR}/${MY_P}
+
+#the tarball is missing pem files for the crypto tests
+#reported upstream, will be included in the next release
+RESTRICT="test"
+
+src_configure() {
+	local SSL_FLAGS=""
+
+	if use gnutls; then
+		if use ssl; then
+			ewarn "You have enabled both 'ssl' and 'gnutls', so we will use"
+			ewarn "gnutls and not openssl for cipher and signature support"
+		fi
+		SSL_FLAGS="
+			--enable-cipher
+			--enable-signature
+			--disable-openssl
+			--enable-gnutls"
+	elif use ssl; then
+		SSL_FLAGS="
+			--enable-cipher
+			--enable-signature
+			--enable-openssl
+			--disable-gnutls"
+	else
+		SSL_FLAGS="
+			--disable-cipher
+			--disable-signature
+			--disable-openssl
+			--disable-gnutls"
+	fi
+
+	export MY_ECONF="
+		$(use_enable !debug amalgamation)
+		$(use_enable debug assert)
+		$(use_enable doc)
+		$(use_enable test tests)
+		$(use_enable test coverage)
+		$(use_enable threads posix-threads)
+		${SSL_FLAGS}
+		${MY_ECONF}"
+
+	enlightenment_src_configure
+}
+
+src_install() {
+	enlightenment_src_install
+	rm -r src/examples/Makefile* || die
+	docinto examples
+	dodoc src/examples/* || die
+}